Obtenir une réponse à une question

[Hervé 06]

Bonjour a vous tous.

Ultra novice avec excel même si je l'utilise de manière simple, j'ai cru comprendre en lisant les post la grande manœuvrabilité de Excel.
Est-il possible de créer un module qui en l'ouvrante et en indiquant une rue ( voir exemple) dans la zone de texte une réponse souhaité s'affiche.

Effectivement j'ai affecté une rue à une réponse. merci de m'indiquer les termes qui correspondent le plus à mon besoin.

Désolé mais Je ne sais pas si un post de ce type est déjà rédiger car je ne connais pas les termes utilisé.

Merci pour vos conseils.

 

[Lone-wolf]

Bonjour Hervé 06 et bienvenue sur XLD.

Une proposition en VBA. À partir de la colonne A, déplace-toi jusqu'à la colonne D à l'aide de TAB du clavier (flèches |<- ->|).

 

[Hervé 06]

Bonjour et merci pour cette réponse rapide, votre accueil et ce module,
J'avoue que j'en espérai pas autant c'est vraiment sympa.
Le principe est parfait, Toutefois AR et AM sont des initiales. et lorsque je tape en D1 le nom de la rue je me retrouve toujours avec la même réponse a savoir le non de la rue en A2.
Pour etre un peu plus precis, j'ai besoin lorsque j'indique une rue avec un numéro paire ou impaire de savoir à quelle initiale il est rattaché.

 

[Lone-wolf]

Re

Bein, dans ce cas pourquoi avoir écrit en lettre paire et impaire

Rue Abbe Ardisson
Rue Auguste Tavel
Rue Casimir Raynaud

Et où sont les numéros de chaque rue??

 

[job75]

Bonjour Hervé 06, Lone-wolf,

Il s'agit d'un problème de recherche tout à fait classique.

Très souvent on utilise pour cela une ComboBox.

Dans le fichier joint elle est pilotée par ces 2 macros dans le code de la feuille :

Option Compare Text 'la casse est ignorée

Private Sub ComboBox1_GotFocus()
Dim r As Range
With ComboBox1
    .Clear
    .Value = ""
    Set r = Range("A2:A" & Rows.Count)
    If Application.CountA(r) = 0 Then Exit Sub 'sécurité
    For Each r In r.SpecialCells(xlCellTypeConstants)
        .AddItem r & IIf(r(1, 3) = "", "", " " & r(1, 3))
    Next
    If .ListCount = 1 Then Exit Sub
    Application.ScreenUpdating = False
    With [D1].Resize(.ListCount) 'colonne auxiliaire
        .Value = ComboBox1.List
        .Sort .Cells, xlAscending, Header:=xlNo 'tri alphabétique
        ComboBox1.List = .Value
        .ClearContents
    End With
End With
End Sub

Private Sub ComboBox1_Change()
Dim r As Range, x As String
[H7] = "" 'RAZ
Set r = Range("A2:A" & Rows.Count)
If ComboBox1.ListIndex = -1 Or Application.CountA(r) = 0 Then ComboBox1 = "": Exit Sub
x = ComboBox1
For Each r In r.SpecialCells(xlCellTypeConstants)
    If r & IIf(r(1, 3) = "", "", " " & r(1, 3)) = x Then [H7] = r(1, 2): Exit For
Next
End Sub

A+

 

[Hervé 06]

Bonsoir,

C'est exactement cela, merci beaucoup à vous deux !

 

[Lone-wolf]

Bonsoir job75

D'après Hervé: j'ai besoin lorsque j'indique une rue avec un numéro paire ou impaire.

Et son fichier ne comporte aucun nombre. Maintenant, si il écrit les rues comme ceci

Rue Abbe Ardisson 1
Rue Auguste Tavel 10
Rue Casimir Raynaud 23

Avec cette macro, c'est différent. Merci à Jacques Boigontier pour la Fonction.

Sub test()
x = DernierNum([A4])
If x Mod 2 = 1 Then
MsgBox "nombre impaire"
Else
MsgBox "nombre paire"
End If
End Sub

Function DernierNum(chaine)
  Set obj = CreateObject("vbscript.regexp")
  obj.Global = True
  obj.Pattern = "\d+"
  Set a = obj.Execute(chaine)
  If a.Count > 0 Then DernierNum = Val(a(a.Count - 1)) Else DernierNum = 0
End Function

En PJ macro modifiée avec la fonction.

 

[job75]

Re Lone-wolf,

Comme je l'ai dit c'est un problème très classique et ma solution l'est aussi.

Si l'on veut peaufiner on peut faire une recherche intuitive sur le nom de rue, classique aussi.

A+

 

[Lone-wolf]

Re

@job75: OK. Mais(j'ai vu ton exemple), si en colonne C il n'y a rien. Comment fais-tu pour s'avoir si c'est paire ou impaire, puisqu'il parle de numéros?

 

[job75]

Re,

si en colonne C il n'y a rien. Comment fais-tu pour s'avoir si c'est paire ou impaire, puisqu'il parle de numéros?

Je vois que tu as du mal à piger.

S'il n'y a rien en colonne C c'est le texte vide "'' qui est concaténé, mon code est très clair là-dessus.

A+

 

[Lone-wolf]

Re

@job75: dans son fichier, il a bien mis deux formes( paire - impaire) non? Et ceci: Indiquer Rue avec un numéro paire ou impaire.
Moi je me suis basé sur ce qu'il à dit. C'est lui qui doit savoir ce qu'il veux au juste.

 

[job75]

Re,

En effet il fallait comprendre ce que Hervé 06 voulait "au juste" et j'ai même été plus loin, point barre.

Bonne nuit.

 

[Hervé 06]

Bonjour,

Je m'appercoit en vous lisant que ma demande n'est vraiment pas claire. Alors ma démarche est la suivante :
- Dans une ville j'ai des rues qui sont affectées à un distributeur (les initiales AR et AM ). toutefois certaines rues sont partager par deux distributeurs ( un sur les numéros paires et l'autre trottoir sur les numéros impaires)

J'ai besoin de savoir quand je tape la rue a qui est attribuer la rue et donc d'indiquer systématiquement si le numéro de la rue et paire ou impaire.

Je n'ai pas besoin d'indiquer le numéro de rue mais simplement si paire et impaire.

Merci de votre implication et je commence a comprendre le fonctionnement

 

[job75]

Bonjour Hervé, le forum,

Votre demande m'a paru claire.

Pour tester j'ai recopié la plage A1:C23 jusqu'à la ligne 23 000.

Sur le fichier de mon post #5 la ComboBox se charge chez moi en 2,3 secondes (20 000 données).

C'est trop lent à mon goût, pour accélérer utilisez cette macro (nettement plus habile) :

Private Sub ComboBox1_GotFocus()
Dim r As Range
Application.ScreenUpdating = False
If FilterMode Then ShowAllData 'si la feuille est filtrée
ComboBox1.Clear
ComboBox1 = ""
Set r = Range("A2", Range("A" & Rows.Count).End(xlUp)(2))
If Application.CountA(r) = 0 Then Exit Sub
With [D1].Resize(r.Count) 'colonne auxiliaire
    .Formula = "=A2&REPT("" ""&C2,C2<>"""")"
    .Value = .Value 'supprime les formules
    .Sort .Cells, xlAscending, Header:=xlNo 'tri alphabétique
    ComboBox1.List = .Resize(Application.CountA(.Cells), 2).Value 'au moins 2 éléments
    .ClearContents
End With
End Sub

Fichier (2), avec 23 000 lignes la macro s'exécute maintenant en 0,3 seconde.

Edit : Application.CountA(.Cells) mieux que Application.CountA(r)

Bonne journée.

 

[job75]

Re,

Eh non ce n'était pas fini...

Dans ce fichier (3) la ComboBox est dotée d'une 2ème colonne (masquée) pour rendre immédiate la 2ème macro :

Private Sub ComboBox1_GotFocus()
Dim r As Range
Application.ScreenUpdating = False
If FilterMode Then ShowAllData 'si la feuille est filtrée
ComboBox1.Clear
ComboBox1 = ""
Set r = Range("A2", Range("A" & Rows.Count).End(xlUp)(2))
If Application.CountA(r) = 0 Then Exit Sub
With [D1].Resize(r.Count, 2) '2 colonnes auxiliaires
    .Columns(1) = "=A2&REPT("" ""&C2,C2<>"""")"
    .Columns(2) = "=B2"
    .Value = .Value 'supprime les formules
    .Sort .Cells(1), xlAscending, Header:=xlNo 'tri alphabétique
    ComboBox1.List = .Resize(Application.CountA(.Columns(1))).Value
    .ClearContents
End With
End Sub

Private Sub ComboBox1_Change()
[H7] = "" 'RAZ
If ComboBox1.ListIndex = -1 Then ComboBox1 = "": Exit Sub
[H7] = ComboBox1.List(ComboBox1.ListIndex, 1) 'valeur en 2ème colonne
End Sub

A+