Obtenir un résultat en demandant à excel de faire une recherche croisée

[ameisen]

Bonsoir
Voila j'aimerais avoir de l'aide concernant un fichier excel
En effet je cherche à croiser des données qui me servieront à remplir un publipostage (feuille BDD) avec 1 ligne = 1 document word créé
Pour cela en fonction des corps d'état j'ai des informations à leur demander (CHOIX)
Je veux qu'en fonction du corps d'état que je renseigne sur la feuille BDD ca me replisse automatiquement les colonnes Observations Ligne 1, ligne 2, ligne 3 (cellule ... en fonction du corps d'état que j'ai choisi
Exemple si je choisis le CORPS D'ETAT "charpente (D2) et bien cela me renseigne "K2 à V2" en fonction de ce qui figure dans la feuille "CHOIX"
Ainsi si je choisis la charpente dans la ligne 2, pour la charpente cela devrait me mettre si tout fonctionne...

- Renseignement charpente 1 (cellule E2 de la feuille CHOIX) ==> dans le feuille BDD colonne intitulée "Observations Ligne 1" cellule E2
- Renseignement charpente 2 (cellule E3 de la feuille CHOIX) ==> dans le feuille BDD colonne intitulée "Ligne 2" soit F2
- Renseignement charpente 3 (cellule E4 de la feuille CHOIX) ==> dans le feuille BDD colonne intitulée "Ligne 2" soit G2

J'ai essayé avec une fonction SI mais c'est limité a 7 arguments... et j'y arrive pas avec RECHERCHEV ou RECHERCHEH bref je suis en panne
J'aurais cru qu'il serait possible en indiquant l'intitulé de la colonne à rechercher (dans mon exemple charpente) et en fonction d'une ligne dans laquelle je lui dis de chercher qu'il cherche donc la colonne "charpente" puis m'affiche le résultat de la ligne dans la colonne charpente que je lui ai demandé de renseigner... mais à priori je trouve pas cette fonction...

Merci pour votre aide

 

[Tibo]

Re : Obtenir un résultat en demandant à excel de faire une recherche croisée

Bonsoir,

Pas sûr d'avoir compris ton souhait.

Peut-être ceci en E2 :

=RECHERCHEV($D2;CHOIX!$A$2:$M$14;COLONNES($A:B);0)

à recopier vers la droite et vers le bas

Je te laisse tester

@+

 

[ameisen]

Re : Obtenir un résultat en demandant à excel de faire une recherche croisée

Bien cela m'affiche "renseignement revet sol 4" or moi c'est renseignement charpente 1 que je voudrais afficher
Cela veut dire quoi "colonne A:B" ?
J'ai modifier la feuille pour que ca soit plus claire, la liste en colonne A qui était dans la feuille CHOIX ne servait qu'a créer un menu déroulant pour choisir le corps d'etat, je l'ai transféré dans une nouvelle feuille qui s'appelle Liste

 

[Tibo]

Re : Obtenir un résultat en demandant à excel de faire une recherche croisée

re,

Un autre essai, toujours en E2 :

=INDEX(CHOIX!$B$2:$M$14;COLONNES($A:A);EQUIV(BDD!$D2;CHOIX!$B$1:$M$1;0))&""

à recopier vers la droite et vers le bas

@+

 

[ameisen]

Re : Obtenir un résultat en demandant à excel de faire une recherche croisée

Oui !!!!!!! ca semble fonctionner !!! Merci !!! c'est je pense le résultat que je cherchais à obtenir à premiere vue
J'aurais jamais trouvé une telle formule excel elle veut dire quoi en gros ?

Pourquoi ca m'affiche en sélection bleue la colonne A?

 

[Tibo]

Re : Obtenir un résultat en demandant à excel de faire une recherche croisée

Bonjour,

La fonction INDEX se construit de la façon suivante :

=INDEX(tablo;n°_ligne;n°_colonne)

Pour le n° de ligne, il faut incrémenter de 1 à chaque colonne. La fonction COLONNES($A:A) agit comme un compteur. Le résultat donne 1. Recopiée vers la droite, elle devient COLONNES($A:B) qui donne 2, puis COLONNES($A:C) qui donne 3, etc.

Pour le n° de colonne, la fonction EQUIV permet de repérer le rang de la valeur de la colonne D sur la ligne des titres de l'onglet CHOIX.

D'autres solutions étaient également possibles :

=DECALER(CHOIX!$A$1;COLONNES($A:A);EQUIV(BDD!$D2;CHOIX!$B$1:$M$1;0))&""

ou :

=RECHERCHEH($D2;CHOIX!$B$1:$M$28;COLONNES($A:B);0)&""

Sinon, je ne comprends la fin de ton message :

...Pourquoi ca m'affiche en sélection bleue la colonne A?...

Peux-tu être plus précis ?

A te (re)lire

@+

 

[ameisen]

Re : Obtenir un résultat en demandant à excel de faire une recherche croisée

J'ai utilisé la formule
=INDEX(CHOIX!$B$2:$M$14;COLONNES($A:A);EQUIV(BDD!$D2;CHOIX!$B$1:$M$1;0))&""
et donc comme je disais précédemment on voit que quand on clique sur E2 on a la colonne A en sélection bleue, voir pièce jointe

 

[Tibo]

Re : Obtenir un résultat en demandant à excel de faire une recherche croisée

Bonjour,

La colonne A apparaît en sélection du fait de l'utilisation de la sous-formule COLONNES($A:A).

Ça ne veut pas dire qu'on se réfère aux données de cette colonne, mais simplement, la fonction COLONNES() nécessite comme paramètre une référence à des colonnes, ce qui permet de l'utiliser comme compteur.

@+

 

[ameisen]

Re : Obtenir un résultat en demandant à excel de faire une recherche croisée

Bonsoir j'aurais une autre question avec une autre feuille de calcul dans le même esprit
En fait j'aimerais qu'a partir de 3 critère ca aille chercher la bonne valeur et que ca la renseigne dans la feuille "Calcul" (3 critères qui sont en l'occurence "Voiles" / "BETONNAGE" / "Temps unitaire d'exécution")
Enfin quelle formule utilisée pour que ca aille chercher la bonne valeur du tableau (à partir de 3 critères) figurant dans la feuille de calcul "Choix"
J'ai mis le résultat que je souhaiterais obtenir dans la feuille de calcul (et la capture d'écran)

 

[Tibo]

Re : Obtenir un résultat en demandant à excel de faire une recherche croisée

re,

Une approche avec la fonction DECALER associée à la fonction INDEX :

en H11, onglet Calcul :

=INDEX(DECALER(Choix!$B$3;EQUIV($C$10;Choix!$B$4:$B$9;0);EQUIV($F$10;Choix!$C$2:$AF$2;0);;6);1)

à recopier vers le bas en modifiant le 1 (à la fin) par 3, puis par 5

@+