XL 2010 Obtenir le nombre de jour auquel un maximum est atteint

[SANDRA2012]

Bonjour à tous ,
Voilà 2 jours que je sèche sur mon problème, après de nombreuse recherches je me rend à l'évidence j'ai besoin de votre aide!
Je cherche à obtenir le jour pour lequel mon maximum (ou minimum) est atteint j'ai trouvé cette formule toute simple :
=INDEX(plage jour;EQUIV(MAX(plage lapin);plage lapin;0))
sauf que les cellules concernées sont en ligne et discontinues j'obtiens donc cette formule.....

=INDEX(C1;G1;K1;O1;S1;W1;AA1;AE1;AI1;AM1;AQ1;AU1;AY1;BC1;BG1;BK1;BO1;BS1;BW1;CA1;CE1;CI1;CM1;CQ1;CU1;CY1;DC1;DG1;DK1;DO1;DS1;EQUIV(MAX(C7;G7;K7;O7;S7;W7;AA7;AE7;AI7;AM7;AQ7;AU7;AY7;BC7;BG7;BK7;BO7;BS7;BW7;CA7;CE7;CI7;CM7;CQ7;CU7;CY7;DC7;DG7;DK7;DO7;DS7);C7;G7;K7;O7;S7;W7;AA7;AE7;AI7;AM7;AQ7;AU7;AY7;BC7;BG7;BK7;BO7;BS7;BW7;CA7;CE7;CI7;CM7;CQ7;CU7;CY7;DC7;DG7;DK7;DO7;DS7;0))

J'ai la même formule pour le minimum

Evidement excel n'en veut pas car nombre d'arguments trop important, Y a t'il d'autre solution pour résoudre mon problème?
j 'ai changé les noms de mon fichier pour des raisons de confidentialité
en pièce jointe mon fichier

Merci d'avance

Bonne journée

 

[Dugenou]

Bonjour,
Ton fichier est peut être trop épuré : comme les chiffres de la ligne 1 sont aussi ceux du N° du jour j'ai pensé que tes quantités étaient sur une ligne 7 que j'ai remplie avec des données bidon. Si ce n'est pas le cas : donnes dans ton fichier un exemple de résultat. (tu veux le chiffre de la ligne 1 ou bien la valeur de la ligne 2 Jxx ?)

Voir pj avec une formule matricielle et un début d'explication.
Cordialement

 

[SANDRA2012]

Bonjour,
C'est exactement ce que je voulais merci beaucoup, juste pour le minimum de "dinde" j'obtiens le maximum comment obtenir le mini?
J'ai du mal à comprendre toute la formule :
=INDEX($A$1:$DT$1;MIN(SI($A$3:$DT$3=DU$1;SI($A$7:$DT$7=MAX(SI($A$3:$DT$3=DU$1;$A$7:$DT$7));COLONNE($A$7:$DT$7)))))
Pourquoi MIN apparait quand je recherche le max?
Encore merci!
Bonne soirée

 

[Dugenou]

Re,
Le premier MIN permet d'afficher la première occurence du résultat attendu (le plus petit N° de colonne).
Pour afficher le jour de la valeur mini il faut remplacer max par min dans la valeur recherchée :

=INDEX($A$1:$DT$1;MIN(SI($A$3:$DT$3=DV$1;SI($A$7:$DT$7=MIN(SI($A$3:$DT$3=DV$1;$A$7:$DT$7));COLONNE($A$7:$DT$7)))))

Toujours à valider en matriciel
Voir pj avec un peu plus d'explications

 

[SANDRA2012]

Bonjour,
Merci bcp pour les explications je comprend mieux! par contre j'ai du oublié quelque chose car en appliquant la formule dans mon fichier final j'obtiens #REF! mon tableau se trouve en CH1:HA7 au lieu de A1T7 je ne comprend pas d'où viens mon erreur
bonne journée

 

[Dugenou]

Bonjour,
peut être peux tu joindre ton tableau avec une seule ligne de données pour que je voie comment il se présente.
Avec ce que tu me dis :

=INDEX($A$1:$HA$1;MIN(SI($CH$3:$HA$3=DV$1;SI($CH$7:$HA$7=MIN(SI($CH$3:$HA$3=DV$1;$CH$7:$HA$7));COLONNE($CH$7:$HA$7)))))

En fait la zone d'index (première plage dans la formule) ne doit pas commencer en CH car la formule retourne un N° de colonne (avec COLONNE($CH$7:$HA$7)) et non un N° d'emplacement dans la zone de recherche. donc INDEX($A$1:$HA$1 ....
Et toujours valider avec ctrl+maj+enter qui fait apparaître les {} autour de la formule.

Cordialement

 

[SANDRA2012]

mon erreur était là : INDEX($A$1 merci beaucoup
Je suis en train d'essayer cette formule en trouvant quand ma valeur devient >=2.5 mais en vain c'est possible ou il faut que je parte sur le fonction recherche?
J'ai essayé comme ça mais j'obtiens 0
=INDEX($A$1:$HA$1;MIN(SI($CH$3:$HA$3=DV$1;SI($CH$7:$HA$7>=2.5;(SI($CH$3:$HA$3=DV$1;$CH$7:$HA$7));COLONNE($CH$7:$HA$7)))))

 

[Dugenou]

Bonjour,
Il y a une partie inutile :

=INDEX($A$1:$HA$1;MIN(SI($CH$3:$HA$3=DV$1;SI($CH$7:$HA$7>=2.5;COLONNE($CH$7:$HA$7)))))

Cordialement

 

[SANDRA2012]

Une dernière question lors que je veux obtenir le temps pour lequel le minimum est atteint ça me prend en compte les cellules vides comme si c'était le minimum , ma ligne peut ne pas être remplie totalement, y a t il une façon de remédier à ce problème?

 

[Dugenou]

Re,
Il faut ajouter une condition dans la partie qui recherche le min :
remplacer

MIN(SI($A$3:$DT$3=DV$1;$A$7:$DT$7)

par

MIN(SI($A$3:$DT$3=DV$1;SI($A$7:$DT$7>0;$A$7:$DT$7))