XL 2010 nompropre vba

[matoupitou]

bonjour

peut-être que qq1 peut m'aider
j'aimerai créer un bouton dans ma barre d'outils qui me permettrait de passer au format 1ère lettre en maj de chaque mot et sinon minuscule ; écrasant les anciens texte et figeant les nouvelles valeurs
je sais que la fonction nompropre permet cela ; en enregistrant une macro je n'arrive pas à écrire que cela fonctionne pour n'importe quelle cellule. parfois ça efface

en pj un exemple avec mon texte VBA

par avance merci pour votre aide

 

[matoupitou]

Hello à tous,
Matoupitou, si tu veux par la selection
Selectionner les noms et hop la macro
Bruno

Sub NomPropre()
Selection.Value = Application.Proper(Selection.Value)
End Sub

OUIIIIIIIIIIIIII c'est cela !!! oh lala TROP BIEN!!!!!!!! merci bcp bcp bcp

 

[Staple1600]

Bonsoir le fil

Pour faire plaisir à patricktoulon qui adore évaluer à tout va

Sub ProperYoupLaBoum()
Selection = Evaluate("index(proper(" & Selection.Address & "),)")
End Sub

 

[patricktoulon]

re
joli!!joli!!joli!!
a la j'adore tu me fait la plage sans la matricielle
je dis respect Monsieur ++++++++++
je la met tout de suite dans mes archives
mais pourquoi j'ai pas pensé a index suis je bète
c'est un délice.... le pain d’épice de la marque bien sur

 

[Eric C]

Bonsoir le fil

Puisé dans mes archives (moins concis que le code de Staple) :

Sub MajusculePlageA1A10()
Dim cell As Range
For Each cell In Range("A1:A10")
cell = Evaluate("PROPER(""" + cell + """)")
Next cell
End Sub

@+ Eric c

 

[job75]

Bonsoir tout le monde,

Les solutions des posts #15 et #17 ne vont pas si Selection n'est pas une plage rectangulaire (cellules non jointives).

Bonne nuit.

 

[patricktoulon]

re
bonjour job75
oui a la base cette formule est fait pour une plage contiguë un colonne ,une ligne ou une plage contiguë

 

[job75]

oui a la base cette formule est fait pour une plage contiguë un colonne ,une ligne ou une plage contiguë

C'est ce que j'ai dit donc à la base utiliser :

Sub NomPropre()
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection.Areas
    a = Application.Proper(a)
Next
End Sub

 

[patricktoulon]

re
Bonjour job75
je regarderais ce soir pour faire avec evaluate histoire de m'amuser un peu

 

[job75]

Quant à Evaluate INDEX est inutile :

Sub NomPropre()
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection.Areas
    a = Evaluate("PROPER(" & a.Address & ")")
Next
End Sub

 

[patricktoulon]

re
oui dans une boucle c'est en matricielle que c'est intéressant
je regarderais ce soir la je vais partir pour la journée

 

[job75]

oui dans une boucle c'est en matricielle que c'est intéressant

Une formule matricielle ? Pas sûr que ce soit bien intéressant mais bon :

Sub NomPropre()
Dim a As Range, f$, c As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection.Areas
    f = "=PROPER({"
    For Each c In a.Cells
        f = f & """" & c & """" & ";"
    Next c
    f = Left(f, Len(f) - 1) & "})"
    a.FormulaArray = f 'formule matricielle
Next a
End Sub

Chaque formule ne doit pas dépasser 8192 caractères...

 

[Emile63]

Bonjour à tous,
Je me permets de m'insérer dans ce fil car j'ai une petite question.
Au cas ou je souhaiterais tout mettre en majuscules ou minuscules, je remplace Proper par quoi ?
Merci de votre aide.

 

[patricktoulon]

re bonjour
PROPER c'est nom propre en formule
majuscule c'est quoi selon toi ?
regarde ce que j'ai mis en commentaire

https://www.excel-downloads.com/threads/nompropre-vba.20038138/#post-20272253

 

[Emile63]

Bonjour Patrick, merci pour ton suivi.
Oui, j'ai bien vu les option possibles, malheureusement "UPPER" et "LOWER" ne fonctionnent pas chez moi (Office 365 Business):
Selection.Value = Application.Upper(Selection.Value)
--> Erreur '438' Propriété ou méthode non gérée par cet objet.

Dans le doute j'ai essayé avec "Uppercase" et "vbUpperCase", mais non.... Pas de succès.

 

[job75]

Bonjour Emile63, le forum,

jAu cas ou je souhaiterais tout mettre en majuscules ou minuscules, je remplace Proper par quoi ?

Sans fioriture :

Sub Majuscules()
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection.Areas
    a = UCase(a)
Next
End Sub

Sub Minuscules()
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection.Areas
    a = LCase(a)
Next
End Sub

Bonne journée.