XL 2010 nompropre vba

[matoupitou]

bonjour

peut-être que qq1 peut m'aider
j'aimerai créer un bouton dans ma barre d'outils qui me permettrait de passer au format 1ère lettre en maj de chaque mot et sinon minuscule ; écrasant les anciens texte et figeant les nouvelles valeurs
je sais que la fonction nompropre permet cela ; en enregistrant une macro je n'arrive pas à écrire que cela fonctionne pour n'importe quelle cellule. parfois ça efface

en pj un exemple avec mon texte VBA

par avance merci pour votre aide

 

[job75]

Juste pour info : en VBA Application.Upper et Application.Lower n'existent pas puisqu'il y a UCase et LCase .

Maintenant avec fioriture :

Sub Majuscules2()
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection.Areas
    a = Evaluate("UPPER(" & a.Address & ")")
Next
End Sub

Sub Minuscules2()
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection.Areas
    a = Evaluate("LOWER(" & a.Address & ")")
Next
End Sub

 

[Emile63]

Bonjour Emile63, le forum,

Sans fioriture :

Sub Majuscules()
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection.Areas
    a = UCase(a)
Next
End Sub

Sub Minuscules()
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection.Areas
    a = LCase(a)
Next
End Sub

Bonne journée.

Bonjour Job75,
Je te remercie pour ton aide, j'ai utilisé ton code tel quel (copié/collé) et il ne fonctionne pas chez moi (?!)
Erreur d'exécution N°13 - Incompatibilité de type

 

[Eric C]

Bonjour le fil
Bonjour Emile

Essaie avec ce code qui traite la feuille :

Sub MajusculeFeuille()
Dim cell As Range
For Each cell In ActiveSheet.UsedRange
cell = UCase(cell)
Next
End Sub


Sub MinusculeFeuille()
Dim cell As Range
For Each cell In ActiveSheet.UsedRange
cell = LCase(cell)
Next
End Sub

@+ Eric c

 

[Staple1600]

Bonsoir le fil,

Alors puisque on repasse par une boucle
(mon code dans le post#17 c'était pour éviter la boucle )
Une version avec macro paramétrée .

Private Sub Change_Casse(Casse As VbStrConv)
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection.Areas
a = StrConv(a.Text, Casse)
Next
End Sub

Sub testMinuscule()
Application.ScreenUpdating = False
Change_Casse vbLowerCase
End Sub
Sub testMajuscule()
Application.ScreenUpdating = False
Change_Casse vbUpperCase
End Sub
Sub testNomPropre()
Application.ScreenUpdating = False
Change_Casse vbProperCase
End Sub

 

[job75]

Alors puisque on repasse par une boucle
(mon code dans le post#17 c'était pour éviter la boucle )

Avec les Areas la boucle normalement ne s'exécute qu'une fois sauf si on passe son temps à faire des sélections multiples avec la touche Ctrl.

 

[Staple1600]

Bonsoir job75

Je ne fais que proposer une énième façon de convertir des strings.
Sans préjuger de quelle est la meilleure façon de le faire.
Le demandeur a depuis longtemps de quoi mettre sa sélection en nom propre
(avec la méthode de son choix)

 

[job75]

Bonjour Job75,
Je te remercie pour ton aide, j'ai utilisé ton code tel quel (copié/collé) et il ne fonctionne pas chez moi (?!)
Erreur d'exécution N°13 - Incompatibilité de type

En effet j'ai la même erreur chez moi maintenant.

Alors que sur le fichier où j'ai préparé les 2 macros il n'y avait aucun problème.

J'avoue ne pas comprendre.

 

[Hervé]

salut

37 messages pour changer la casse d'un string (j'aime écrire cette phrase)

je m'incline

a plus

 

[Staple1600]

Bonsoir Hervé

Une dernière pour la route

Private Declare Function CharLower Lib "user32.dll" Alias "CharLowerA" (ByVal lpsz As String) As String
Private Declare Function CharUpper Lib "user32.dll" Alias "CharUpperA" (ByVal lpsz As String) As String
Sub Aquatique()
Dim Phrase As String
Phrase = "37 messages pour changer la casse d'un string" & Chr(13) & "(j'aime écrire cette phrase)"
MsgBox CharUpper(Phrase), vbInformation, "Lol"
End Sub

 

[Staple1600]

En effet j'ai la même erreur chez moi maintenant.

Alors que sur le fichier où j'ai préparé les 2 macros il n'y avait aucun problème.

J'avoue ne pas comprendre.

Pour information , j'ai le même message d'erreur
(Excel 2013 32bits W10 64 bits)

 

[job75]

Par contre avec les macros utilisant Evaluate aucun problème.

 

[Staple1600]

Re,

Avec UsedRange pas de message d'erreur.

Sub Majuscules_B()
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In ActiveSheet.UsedRange
If Not IsEmpty(a) And Not a.HasFormula Then
a = UCase(a)
End If
Next
End Sub

 

[job75]

Bon maintenant chez moi ça c'est remis à marcher en ajoutant .Value :

Sub Majuscules()
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection
    a = UCase(a.Value)
Next
End Sub

Sub Minuscules()
Dim a As Range
ActiveCell.Activate 'au cas où la sélection n'est pas un Range
For Each a In Selection
    a = LCase(a.Value)
Next
End Sub

Ensuite j'ai enlevé les .Value et… ça marche aussi !!! A ne rien y comprendre, je laisse tomber.

PS : au post #42 JM tu traites les cellules une par une, normal que ça marche toujours.

 

[Staple1600]

Re

Idem chez moi.
C'est bizarre cette histoire.

Je me demande si cela ne peut pas être lié la mise à jour Windows que j'ai faite hier avant de fermer le PC.
(Parce qu'avant pas de message d'erreur)

 

[job75]

C'est bizarre cette histoire.

Je me demande si cela ne peut pas être lié la mise à jour Windows que j'ai faite hier avant de fermer le PC.
(Parce qu'avant pas de message d'erreur)

C'est très possible en effet et peut-être qu'elle vient d'être corrigée.

Car tout à l'heure chez moi ça ne marchait pas avec .Value et maintenant ça marche.