Nombre de matricules sans doublons si critère

Vilain

XLDnaute Accro
Bonjour à tous,

J'ai aujourd'hui un souci que j'ai l'impression d'avoir déjà réglé 1000 fois mais qui me pose problème aujourd'hui.
J'ai en colonne A des matricules (avec doublons). En colonne B, le pays.
Je souhaite trouver une formule qui me permet de savoir le nb de matricules différents par pays.
Je joins mon fichier pour plus de clarté.

A plus et merci d'avance
 

Pièces jointes

  • nb sans doublons si critère.xls
    28.5 KB · Affichages: 50

R@chid

XLDnaute Barbatruc
Re : Nombre de matricules sans doublons si critère

Bonjour Gillus,
en E2,
Code:
=NB(1/FREQUENCE(SI($B2:$B32=E1;EQUIV($A2:$A32;$A2:$A32;0));LIGNE(INDIRECT("1:"&LIGNES(A2:A32)))))
@ valider par Ctrl+Maj+Entree
@ tirer vers la droite
@ micalement
 

Vilain

XLDnaute Accro
Re : Nombre de matricules sans doublons si critère

Salut Rachid,
Je me doutais que la réponse viendrait de toi.
Non, en fait, je n'avais surement jamais fait ça, la formule de me dit rien....
Je regarde ça avec attention.

Merci beaucoup :)
 

R@chid

XLDnaute Barbatruc
Re : Nombre de matricules sans doublons si critère

Bonjour Gillus,
une formule d'un prof,
Sélectionner la plage E1:F1, coller cette formule dans la barre des formules,
Code:
=TRANSPOSE(FREQUENCE(SI(FREQUENCE(A2:A32;A2:A32);EQUIV(B2:B32;E1:F1;0));{1;2}))
@ valider toujours par Ctrl+Maj+Entree
@ micalement
 

JHA

XLDnaute Barbatruc
Re : Nombre de matricules sans doublons si critère

Bonjour à tous,

Juste deux autres "matricielle" pour le fun

Code:
=SOMME((FREQUENCE(SI($B$1:$B$38=E$1;EQUIV($A$1:$A$38;$A$1:$A$38;0));LIGNE($A$1:$A$38))>0)*1)

Code:
=SOMME(SI(($B$2:$B$38=E$1);N(FREQUENCE($A$2:$A$38;$A$2:$A$38)>0)))

JHA
 
Dernière édition:

Discussions similaires

Statistiques des forums

Discussions
311 720
Messages
2 081 909
Membres
101 836
dernier inscrit
karmon