Moyenne, Min, Max en formule matricielle

[Goodparts]

Hello à tous les gens du forum,


J'aurai besoin de faire la moyenne, etc... sur 5000 lignes mais compris entre 2 valeurs, les colonnes peuvent contenir des messages d'erreurs comme "#Valeurs" et les 5000 lignes ne sont pas forcement remplies, mais il y a des formules dans les colonnes, je dois absolument laisser sur 5000 lignes car l'utilisateur peux très bien en avoir besoin (ce qui entre nous est très rare...).

Mon prob. est que ma formule ne tient pas compte des messages d'erreurs(un bon point), mais fait la moyenne sans tenir compte des 2 valeurs inférieur et supérieur(un mauvais point, je me retrouve presque au point de départ...lol)

{=MOYENNE(SI(ESTNUM((F11:F5000>F7)*(F11:F5000<F8));F11:F5000))}

Si quelqu'un pouvait m'éclairer et me montrer le chemin.

Merci

Goodparts

 

[chris]

Bonjour,
En matriciel je ne sais pas mais y a aussi BDMOYENNE qui fonctionne selon le même principe que les filtres élaborés : on crée une zone de critère pour indiquer les conditions et on s'y réfère dans la formule.
Il faut donc mettre 2 fois l'en-tête de la colonne F et indiquer les valeurs de F7 et F8 ainsi
>=valeur f7 dans l'une et <= valeur f8 dans l'autre.
Sinon tu peux aussi mettre une formule pour garder la réfréence à f7 et F8 mais c'est plus compliqué : il faut mettre un autre en-tête et mettre je crois
= ET(F1>=F7;F1<=F8)
Dans le formule BDMOYENNE tu indiqueras la plage où figurent ces critères.
chris

 

[Goodparts]

Hello Crhis et le forum,

Merci pour ton aide Crhis, mais je n'y suis pas arrivé comme ça non plus, de plus j'avais toujours mon prob. pour Min et Max. J'y suis arrivé, en passant par un colonne intermédiaire. Voilà la formule que j'ai utilisé :

=SI(B11<>"";SI(OU(ESTERREUR(E11));"";(SI(OU(F11<$F$7;F11>$F$8);"";F11)));"")

Bonne fin d'après-midi à tous

Goodparts

 

[Jean-Marie]

Bonjour

Peut-être qu'avec cette formule matricielle, tu auras plus de chance :
=SOMME(SI(ESTNUM(F11:F5000);(F11:F5000>F7)*(F11:F5000<F8)*F11:F5000;0))/SOMME(SI(ESTNUM(F11:F5000);(F11:F5000>F7)*(F11:F5000<F8);0))

Formule à valider par Ctrl+Shift+Entrer

Bonne journée

@+Jean-Marie

 

[Jean-Marie]

Re...

Formule allégée : =MOYENNE(SI(ESTNUM(A$1:A$32);SI((A$1:A$32>D$2)*(A$1:A$32<D$3)=1;A1:A32;"");"")), toujours à valider par Crtl+Shift+Entrer

@+Jean-Marie

 

[Jean-Marie]

Flûte, Oups !

J'ai oublié de faire correspondre les références en fonction des tes plages.

=MOYENNE(SI(ESTNUM(F11:F5000);SI((F11:F5000>F7)*(F11:F5000<F8)=1;F11:F5000;"");""))

Voilà

Bonne soirée

@+Jean-Marie

 

[Goodparts]

Re bonjour à tous,

Merci Jean-Marie, c'est excatement ce que je voulais, mais dans ma formule, il me manquait un SI

Goodparts