Min du mois

sophang

XLDnaute Nouveau
Bonjour le forum,

Comment déterminer le minimum du mois, sans changer la formule manuellement lorsqu'on arrive au mois suivant ?

En remerciant de votre aide.
 

Pièces jointes

  • minimum_mois 25052018.xlsx
    13.2 KB · Affichages: 27

Dugenou

XLDnaute Barbatruc
Bonjour,
entrer la formule suivante : =MIN(SI(MOIS($A$2:$A$92)=MOIS(A2);$B$2:$B$92)) puis au lieu de valider par enter comme habituellement, validez par la combinaison des 3 touches ctrl+maj (provisoire) + enter : des accolades doivent apparaitre au tour de la formule.
Cordialement
 

sophang

XLDnaute Nouveau
Bonjour,
entrer la formule suivante : =MIN(SI(MOIS($A$2:$A$92)=MOIS(A2);$B$2:$B$92)) puis au lieu de valider par enter comme habituellement, validez par la combinaison des 3 touches ctrl+maj (provisoire) + enter : des accolades doivent apparaitre au tour de la formule.
Cordialement

Bonjour,

Merci beaucoup de ta réponse,
J'ai adapté ta formule sur mon fichier de l'exemple, çà marche à la perfection. Mais je trouve que cette formule est très "sensible", il suffit qu'on passe le curseur sur la formule et les accolades disparaissent.
J'ai néanmoins adapté cette formule dans un autre fichier, et çà ne me donne de faux résultats. Je ne comprends pas.
 

Pièces jointes

  • Test min du mois.xlsx
    79.1 KB · Affichages: 26

job75

XLDnaute Barbatruc
Bonjour sophang, Dugenou,

Comme les dates se suivent en colonne A on peut entrer en C2 cette formule normale :
Code:
=MIN(INDEX(B:B;EQUIV(FIN.MOIS(A2;-1)+1;A:A)):INDEX(B:B;EQUIV(FIN.MOIS(A2;0);A:A)))
Durées des calculs sur les 92 lignes du fichier :

- formule matricielle de Dugenou => 2,80 millisecondes

- cette formule => 0,44 milliseconde, c'est donc 6 fois plus rapide.

A+
 

Dugenou

XLDnaute Barbatruc
Bonjour,
je ne comprends pas que les accolades disparaissent au simple survol de souris, par contre oui elles disparaissent quand on édite la formule (quand on clique dedans)
Pour votre probleme : vous avez plusieurs fois le mois dabns ce nouveau fichier qui couvre plusieurs années.
Il faut donc modifier la formule pour tenir compte de l'année :
=MIN(SI((MOIS($B$2:$B$1478)=MOIS(B2))*(ANNEE($B$2:$B$1478)=ANNEE(B2));$C$2:$C$1478))
toujour à valider en matriciel
voir pj
Cordialement

Edit : bonjour Job et bravo pour l'optimisation
 

Pièces jointes

  • sophang.xlsx
    80.2 KB · Affichages: 15

sophang

XLDnaute Nouveau
Bonjour sophang, Dugenou,

Comme les dates se suivent en colonne A on peut entrer en C2 cette formule normale :
Code:
=MIN(INDEX(B:B;EQUIV(FIN.MOIS(A2;-1)+1;A:A)):INDEX(B:B;EQUIV(FIN.MOIS(A2;0);A:A)))
Durées des calculs sur les 92 lignes du fichier :

- formule matricielle de Dugenou => 2,80 millisecondes

- cette formule => 0,44 milliseconde, c'est donc 6 fois plus rapide.

A+

Bonjour Job75,

Elle est vraiment excellente ta formule !! Merci encore.
 

job75

XLDnaute Barbatruc
Re,

Avec le fichier du post #3 il faut compliquer un peu la formule en D2 :
Code:
=MIN(INDEX(C:C;SIERREUR(EQUIV(FIN.MOIS(B2;-1)+1;B:B);2)):INDEX(C:C;EQUIV(FIN.MOIS(B2;0);B:B)))
car la 1ère date (06/05/2014) n'est pas un 1er du mois.

Fichier joint.

A+
 

Pièces jointes

  • Test min du mois(1).xlsx
    76 KB · Affichages: 26

Discussions similaires

Réponses
21
Affichages
331

Statistiques des forums

Discussions
311 733
Messages
2 082 015
Membres
101 868
dernier inscrit
pierreselo33