XL 2016 Maximum d'une colonne mais une cellule peut avoir plusieurs valeur

[Andry]

Bonjour à tous,
J'ai besoin de votre aide pour trouver le maximum dans une colonne!
Jusqu'à là vous allez me dire il suffit de faire max()
Sauf que dans une cellule, il peut y avoir plusieurs valeur à la ligne.
Par exemple dans A1 = 200 251 300
dans A2 =152; A3 =128 ; A4 = 99 500 502......
dans cet exemple le résultat doit être la cellule A4.

Merci d'avance

 

[jmfmarques]

Bonjour
Tu peux toujours déterminer la valeur max de celles multiples dans une cellule et te lancer dans des comparaisons en boucle *******, t'éloignant ainsi très significativement tant de l'utilisation de formules Excel que de l'esprit même (une cellule = une seule donnée)
****** ou encore "tricoter" à l'aide de colonnes supplémentaires !

J'ignore si un autre t'encouragera dans la voie d'une telle usine à gaz, mais ce ne sera pas moi.

 

[Andry]

Merci pour la réponse JM,
mais dans mon cas une cellule a plusieurs données et je n'ai pas le choix que de me diriger dans cette voie!
Par contre je n'ai pas bien compris ce que tu as marqué

Tu peux toujours déterminer la valeur max de celles multiples dans une cellule

 

[jmfmarques]

mais dans mon cas une cellule a plusieurs données et je n'ai pas le choix que de me diriger dans cette voie!

je compatis, mais ne te suivrai pas dans ce type de démarche
On a toujours le choix, dont celui de normaliser les données pour travailler sur des bases saines

 

[mapomme]

Bonjour,

Voir cette fonction personnalisée en VBA :

Function Maxi(plage As Range)
Dim t, m, s, i&, j&, x
  
   If plage.Count = 1 Then
      ReDim t(1 To 1, 1 To 1)
      t(1, 1) = plage.Value
   Else
      t = plage.Value
   End If
   m = -1E-99
   For i = 1 To UBound(t)
      For j = 1 To UBound(t, 2)
         s = Split(t(i, j))
         For Each x In s
            If IsNumeric(x) Then If CDbl(x) > m Then m = CDbl(x)
         Next x
      Next j
   Next i
   If m = -1E-99 Then Maxi = "" Else Maxi = m
End Function

 

[Fabinou62]

Bonjour, un truc bcp + simple et rapide,
- tu fais convertir tes données dans Données > Convertir, tu indiques le séparateur comme étant le espace.
- tu fais le max par ligne puis un max par colonne sur ces valeurs.
Tu peux même faire une macro qui enregistre ce que tu fais et c'est bon

 

[mapomme]

Bonjour @Fabinou62 ,

J'y avais pensé mais que faire si la colonne en question n'est pas isolée ?
Dans ce cas, passer par une feuille auxiliaire est sans doute ce qu'il y a de plus simple sauf que ça ne marche dans une fonction.

 

[Andry]

Voir cette fonction personnalisée en VBA

Bonjour, et merci d'avoir répondu
Mon niveau de vba n'est pas assez pour lancer la fonction.
J'ai essayé
set plage =.range("A1:A5")
call maxi (plage)

comment on fait pour lancer le code sur la colonne A par exemple?

 

[Andry]

- tu fais convertir tes données dans Données > Convertir, tu indiques le séparateur comme étant le espace.

Bonjour Fabrice et merci pour la solution,
après conversion, il ne garde que la première valeur! ou passer par une autre feuille comme a indiqué Barbatruc!

 

[Fabinou62]

j'ai fais un test et ca marche
att 2 min je te fais un exemple

 

[JHA]

Bonjour à tous,

Avec une formule matricielle de @mapomme

=MAX(SUBSTITUE(DROITE(SUBSTITUE(A1:A4;" ";REPT(" ";255));255);" ";)*1)

JHA

 

[mapomme]

Re,

La fonction Maxi : Utilisation.

• Sur une feuille Excel : =Maxi(A1:B25)
• En VBA : Resultat = Maxi(Range("A1:B25"))

Tout le code est dans module1 :

Function Maxi(plage As Range)
Dim t, m, s, i&, j&, x
   If plage.Count = 1 Then
      ReDim t(1 To 1, 1 To 1)
      t(1, 1) = plage.Value
   Else
      t = plage.Value
   End If
   m = -1E-99
   For i = 1 To UBound(t)
      For j = 1 To UBound(t, 2)
         s = Split(t(i, j))
         For Each x In s
            If IsNumeric(x) Then If CDbl(x) > m Then m = CDbl(x)
         Next x
      Next j
   Next i
   If m = -1E-99 Then Maxi = "" Else Maxi = m
End Function

Sub Test()
Dim resultat
   resultat = Maxi(Range("A1:B25"))
   MsgBox "Maxi de la plage A1:B25 = " & resultat, vbInformation
End Sub

 

[mapomme]

set plage =.range("A1:A5")
call maxi (plage)

C'est bien. Mais Maxi est une fonction. Maxi retourne une valeur. On écrit :

set plage =.range("A1:A5")
Resultat = Maxi(plage)

ou

set plage =.range("A1:A5")
msgbox Maxi(plage)

ou
...

 

[Andry]

Mais Maxi est une fonction. Maxi retourne une valeur

Merci Mapomme, on apprend tout les jours!