Macro - Vérifier validité celulle ayant une formule de type LIEN_HYPERTEXTE()

[camboo]

Bonjour à tous,
J'ai eu beau chercher une solution mais sans succès
J'utilise une formule de type =LIEN_HYPERTEXTE("C:\WINDOWS\Temp"&"\toto.txt";"toto.txt")
--------------
problématique : Comment-vérifier que les cellules sont valides ? (sans cliquer dessus)
--------------
Contraintes :
- le lien hypertexte est créé obligatoirement à partir de la formule (pas de clic gauche --> lien hypertexte)
--------------
J'ai tenté de colorier en rouge les cellules dont le lien est H.S, mais ça ne marche pas quand la cellule a une formule.
Merci pour votre aide =)

 

[tototiti2008]

Re : Macro - Vérifier validité celulle ayant une formule de type LIEN_HYPERTEXTE()

Bonjour camboo,

un essai

Sub TestLiens()
Dim i As Long, Formule As String, Chemin As String
    With Sheets("Feuil1")
    For i = 1 To .Range("A" & .Rows.Count).End(xlUp).Row
        Formule = .Cells(i, 1).Formula
        If Formule Like "=HYPERLINK*" Then
            Formule = Replace(Formule, "=HYPERLINK(", "")
            Chemin = Evaluate(Split(Formule, ",")(0))
            If Dir(Chemin) = "" Then
                .Cells(i, 1).Interior.Color = RGB(255, 0, 0)
            Else
                .Cells(i, 1).Interior.Pattern = xlNone
            End If
        End If
    Next i
    End With
End Sub

Edit : attention, s'il y a une autre fonction (avec plusieurs arguments donc des ";") dans le premier argument de Lien_hypertexte, ça ne fonctionne pas

 

[camboo]

Re : Macro - Vérifier validité celulle ayant une formule de type LIEN_HYPERTEXTE()

Bien vu tototiti2008 ! mais le "If Dir(Chemin)" marcherait-il pour un dossier ?
si toutefois je fais un lien vers un dossier genre =LIEN_HYPERTEXTE("C:\WINDOWS\Temp";"Dossier") ?
Merci pour la précision.

 

[tototiti2008]

Re : Macro - Vérifier validité celulle ayant une formule de type LIEN_HYPERTEXTE()

Re,

"If Dir(Chemin)" marcherait-il pour un dossier ?

si tu mets
If Dir(Chemin, vbdirectory)
alors oui
va voir l'aide sur la fonction Dir si tu veux spécifier

 

[camboo]

Re : Macro - Vérifier validité celulle ayant une formule de type LIEN_HYPERTEXTE()

Parfait ça marche très bien !! Sujet Résolu, et ce, grâce à toi tototiti2008