XL 2016 Macro qui ne fonctionne plus

[Erakmur]

Bonjour,
La macro en pièce jointe ne fonctionne plus.
A l'origine, il fallait cliquer sur la cellule F2 et déclencher la macro et chaque tache de la colonne F créée une ligne au lieu que toutes les taches soient dans la même cellule. A chaque fois qu'un retour à la ligne était détecté, une ligne se créée. Pouvez vous m'aider ?

 

[job75]

Bonjour Erakmur,

Voyez le fichier joint et cette macro affectée au bouton :

Sub Eclater()
Dim i&, s, ub%, j%
Application.ScreenUpdating = False
With ActiveSheet
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
    For i = .Range("F" & .Rows.Count).End(xlUp).Row To 2 Step -1
        s = Split(.Cells(i, 6), vbLf)
        ub = UBound(s)
        If ub > 0 Then
            .Rows(i + 1).Resize(ub).Insert 'insère les lignes
            For j = 0 To ub
                .Cells(i + j, 6) = s(j)
            Next j
            For j = 1 To 5
                .Cells(i, j).Resize(ub + 1).Merge 'fusionne les cellules
            Next j
        End If
    Next i
    .Rows.AutoFit 'ajustement hauteur
End With
End Sub

A+

 

[Erakmur]

Excellent ! Pourrais je te demander une optimisation ? Je souhaiterai que les éléments de la colonne A à E soit répété également pour chaque ligne. Est ce possible ?

 

[job75]

Ce n'est pas une optimisation, on remplace la fusion de cellules par un copier-coller, fichier (2) :

            For j = 1 To 5
                '.Cells(i, j).Resize(ub + 1).Merge 'fusionne les cellules
                .Cells(i, j).Resize(ub + 1) = .Cells(i, j) 'copie-colle la 1ère cellule
            Next j

 

[Erakmur]

C'est impeccable ! Je te remercie. Tu m'as fait gagner un temps précieux !