Macro pour supprimer colonne sous condition

[karinette]

Bonjour au expert Excel.
Je vous explique mon problème :
J'aimerais supprimer par le biais d'une macro toute les colonnes d'une feuille qui débute par "300".
Si en B1 j'ai 300, la colonne B est supprimé, idem pour toute les autres colonnes.
Merci d'avance ...

 

[job75]

Re : Macro pour supprimer colonne sous condition

Bonsoir karinette,

Par exemple :

Sub SupprimeColonnes()
Dim v, c As Range, sup As Range
v = 300 'modifiable
For Each c In ActiveSheet.UsedRange.Rows(1).Cells
  If c = v Then Set sup = Union(c, IIf(sup Is Nothing, c, sup))
Next
If Not sup Is Nothing Then sup.EntireColumn.Delete
End Sub

A+

 

[john]

Re : Macro pour supprimer colonne sous condition

Bonjour,
En plus clair sir tu ne comprends pas il y a comme ça
Sub ctrl_col()
Range("A1").Select
Selection.End(xlToRight).Select 'je sélectionne la dernière colonne pour connaitre le num de la colonne
der_col = ActiveCell.Column
For x = der_col To 1 Step -1 'je pars de la fin pour contrôler la valeur (mieux en cas de suppression de colonnes)
If Cells(1, x) = 300 Then 'si = 300
Columns(x).Select 'je sélectionne la colonne à supprimer
Selection.Delete Shift:=xlToLeft 'je supprime
End If
Next x
End Sub

Bonne fin de journée.
John

 

[phlaurent55]

Re : Macro pour supprimer colonne sous condition

Bonjour à tous,

Sub supression()
For i = Range("IV1").End(xlToLeft).Column To 1 Step -1
If Cells(1, i) = 300 Then Columns(i).Delete Shift:=xlToLeft
Next i
End Sub

à+
Philippe

 

[karinette]

Re : Macro pour supprimer colonne sous condition

Merci @ tous pour vos réponses ...