XL 2016 Macro mail excel

[youpi457032]

Bonjour,
Je suis néophyte en programmation.
Je souhaite par vba récupérer les adresses mail de toute une colonne Excel après qu'elle ait été filtrée, et envoyer un mail via Outlook à l'ensemble des destinataires apparaissant dans cette colonne filtrée. J'ai pu le faire avec l'ensemble des mails de la base non filtrée, mais je ne parviens pas à récupérer les adresses mail une fois le filtre actif.
Si l'un d'entre vous à une solution ? Je câle…..
Merci

 

[Compte Supprimé 979]

Bonjour,

Il faut tester si ta ligne est masqué, si elle l'est alors sauter la procédure

 

[youpi457032]

merci de la réponse. Ca fonctionne sur une colonne non filtrée. J'arrive a récupérer l'intégralité des champs d'une colonne
mais dès que je filtre ça ne me renvoie rien. Le code fonctionne si la fonction est sur la feuille active, mais moi je voudrais qu'elle fonctionne sur une autre feuille sur laquelle je filtre les données.
voici mon code à tout hasard :

Sheets("base_PDV").Activate

For i = 2 To Range("B" & Rows.Count).End(xlUp).Row
Destinataire = Destinataire & ";" & Range("B" & i).Value
Next i

With oBjMail
.BCC = Destinataire 'le destinataire
.Subject = ""
.Body = "Bonjour,"
'.Attachments.Add ActiveWorkbook.FullName
.Display
'.Send ' I
End With
Set oBjMail = Nothing
Set ObjOutlook = Nothing

End Sub

******
mon tableau de bord est en feuille 3
j'aimerai depuis cette feuille après filtrage de la colonne B en "base_PDV" récupérer uniquement les adresses mail filtrées, pour les expédier dans Outlook. La feuille FILTRAGE ne me servirait plus, je la supprimerai.
Ps : existe t-il une macro pour récupérer ces mails filtrés sans doublon ! au passage !
un grand merci d'avance !!

 

[youpi457032]

Je reposte mon fichier, mais cette fois ci vierge de toute donnée.
Merci de m'avoir fait la remarque.
Je reprends l'idée.
Ma macro mail en Feuille FILTRAGE fonctionne très bien. Elle ne récupère que les adresses mails des lignes non vides. Mais la fonction de tri est trop laborieuse et longue. J'ai amélioré ce tri en Feuille TABLEAU DE BORD. Je voudrais que ma fonction de mail qui fonctionne très bien en feuille Filtrage opère de de la même manière depuis mon TABLEAU de BORD. Mais ca ne fonctionne pas avec ma macro (mail_liste_filtrée). Si vous avez l'astuce, merci !
avec le petit plus, la récupération du champ mail sans doublon ! Merci

 

[Compte Supprimé 979]

Re,

As-tu vu mon MP avec un lien vers le fichier d'origine modifié ?

A+

 

[youpi457032]

oui je l'ai en copie, j'ai vu la macro. mais les mails ne sont pas récupérés dans le champ Bcc d'Outlook. Outlook s'ouvre bien, pas de soucis, mais les adresses mails ne sont pas rapatriées. Le champ Bcc reste vide.

 

[Compte Supprimé 979]

Re,

Désolé, il manque un POINT

Destinataire = Destinataire & .Range("B" & Lig).Value & ";"

Sinon tu ne fais pas référence à l'objet conteneur qui est ta feuille "base_PDV"

Ça ira mieux comme ça

 

[youpi457032]

Un grand merci ca marche Nickel !!!
Trop content !!

Et pour supprimer les doublons mail après filtrage et avant export dans Outlook vous avez une solution ?

 

[Compte Supprimé 979]

Re,

Un grand merci ca marche Nickel !!!
Trop content !!

De rien et tant mieux

Et pour supprimer les doublons mail après filtrage et avant export dans Outlook vous avez une solution ?

Tu peux répéter la questionnnnn

 

[youpi457032]

Je souhaiterais que les adresses mail une fois filtrée ne soient pas rapatriées en double ou triple dans Outlook. De façon à éviter d'envoyer deux ou trois fois le même message sur une même adresse mail. Merci

 

[Compte Supprimé 979]

Re,

Effectivement en regardant de plus près, j'ai finalement compris ta demande
Voici le code complet

Attention ! Il faut activer la référence indiqué dans le code

Sub Envoyer_Mail_liste_filtrée_Outlook()
  Dim DLig As Long, Lig As Long
  Dim ObjOutlook As New Outlook.Application
  Dim oBjMail As Outlook.MailItem
  Dim Nom_Fichier As String
  Dim Destinataire As String
  ' Activer la référence : Microsoft Scripting Runtime
  ' Définir l'Objet Dictionnaire
  Dim MonDico As New Scripting.Dictionary
  ' Ou définir Mondico comme objet et Créer l'instance du dictionnaire
  ' Dim MonDico As Object
  'Set MonDico = CreateObject("Scripting.Dictionary")
 
  ' Initialiser l'instance Outlook
  Set ObjOutlook = New Outlook.Application
  Set oBjMail = ObjOutlook.CreateItem(olMailItem)
  ' Avec la base
  With Sheets("base_PDV")
    ' Dernière ligne de la feuille
    DLig = .Range("B" & Rows.Count).End(xlUp).Row
    ' Pour chaque ligne
    For Lig = 2 To DLig
      ' Vérifier si ligne affichée
      If .Range("B" & Lig).EntireRow.Hidden = False Then
        ' En cas d'erreur on continue le code
        On Error Resume Next
        ' Tenter d'ajouter le mail au dictionnaire : doublon impossible
        MonDico.Add .Range("B" & Lig).Value, ""
        ' Si pas d'erreur, ajouter l'adresse
        If Err.Number = 0 Then
          Destinataire = Destinataire & .Range("B" & Lig).Value & ";"
        End If
        On Error GoTo 0
      End If
    Next Lig
  End With
  ' Envoyer le mail
  With oBjMail
    .BCC = Destinataire  'le destinataire
    .Subject = ""
    .Body = "Bonjour,"
    '.Attachments.Add ActiveWorkbook.FullName
    .Display
    '.Send '  Ici tu peux l'activer si tu ne veux pas vérifier le mail
  End With
  ' Effacer les variables objet pour libérer la mémoire
  Set oBjMail = Nothing
  Set ObjOutlook = Nothing
  Set MonDico = Nothing
End Sub

A+

 

[youpi457032]

c est super Nickel ! Juste hallucinant ! ca vous pris un rien de temps !!! Je suis bluffé …. c'est médusant ! donc un grand merci !

 

[youpi457032]

Idéalement, pour finaliser ce fichier dans sa partie filtrage et mail, j'aimerai optimiser la fonction de filtre.
pour essayer de faire simple. j'aimerai une boite de dialogue ou chaque cours est référencé avec la possibilité de l'activer ou non par une case à cocher. En activant la case on activerait une fonction de filtre (en VBA) qui afficherait l'ensemble des élèves qui se sont inscrits dans ce cours ( dans le classeur ils peuvent apparaître dans plusieurs colonnes du tableau. L'idée serait par des cases à cocher (en VBA dans une boite de dialogue ) de reproduire la fonction slicer ( qui est très pratique, mais ne permet pas de travailler sur plusieurs colonnes à la fois ).
Si le cœur vous en dit …..de vous pencher sur ce problème..