interdire couper coller

  • Initiateur de la discussion jean michel
  • Date de début
J

jean michel

Guest
bonjour et bonne année à tous

Dans un classeur partagé avec plusieurs utilisateurs ,j'ai une feuille destinee à la saisie d'informations,cette feuille possede un format avec des bordures et modifs,comment faire pour eviter que les actions couper coller ou copier coller ne mettent la pagaille ds les formats des cellules non protegees
est il possible de declencher une alerte ou d'interdire les fonctions couper ou copier

merci et bonne journee
 
J

JMG

Guest
bonjour jm

ceci interdira à l'ouverture du classeur le CTRL+C ou X

à toi de varier


Private Sub Workbook_Open()
With Application
.OnKey ("^{c}"), "" 'Combinaison de touches =CTRL+c
.OnKey ("^{x}"), "" 'Combinaison de touches =CTRL+x
End With
End Sub



BONNE ANNEE
 
J

jean michel

Guest
merci JMG

JE me suis mal exprimé ,je souhaiterais interdire ou alerter lorsqu'on utilise la souris pour faire un couper coller ou copier coller ou carrement interdire le clic droit, j'en demande peut etre un peu trop mais c'etant jamais en 2004 tout est possible......

A BIENTOT ET MERCI A TOUS
 
M

Myta

Guest
Salut Le Forum

Empecher le double-Click

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, _
ByVal Target As Range, Cancel As Boolean)
Cancel = True
End Sub

Empecher le click droit

Private Sub Workbook_SheetBeforeRightClick(ByVal Sh As Object, _
ByVal Target As Range, Cancel As Boolean)
Cancel = True
End Sub

Mytå
 
M

Myta

Guest
Re: interdire couper coller (Pour Jean Michel)

Salut Jean-Michel et le forum

J'ai trouvé une macro de Chris Pearson sur le site de
John Walkenbach qui semble repondre en entier à ta demande

Option Explicit

Sub DisableCutAndPaste()
EnableControl 21, False ' cut
EnableControl 19, False ' copy
EnableControl 22, False ' paste
EnableControl 755, False ' pastespecial
Application.OnKey "^c", ""
Application.OnKey "^v", ""
Application.OnKey "+{DEL}", ""
Application.OnKey "+{INSERT}", ""
Application.CellDragAndDrop = False
End Sub

Sub EnableCutAndPaste()
EnableControl 21, True ' cut
EnableControl 19, True ' copy
EnableControl 22, True ' paste
EnableControl 755, True ' pastespecial
Application.OnKey "^c"
Application.OnKey "^v"
Application.OnKey "+{DEL}"
Application.OnKey "+{INSERT}"
Application.CellDragAndDrop = True
End Sub

Sub EnableControl(Id As Integer, Enabled As Boolean)
Dim CB As CommandBar
Dim C As CommandBarControl
On Error Resume Next
For Each CB In Application.CommandBars
Set C = CB.FindControl(Id:=Id, recursive:=True)
If Not C Is Nothing Then C.Enabled = Enabled
Next
End Sub

A+ Mytå
 
J

JEAN MICHEL

Guest
Re: interdire couper coller (Pour Jean Michel)

Bonjour Myta et merci de revenir sur mon probleme
j'ai essaye cette macro mais a vrai dire je ne sais pas trop ou la mettre dans workbook ou ds la feuil, je suis un petit bricoleur de macro ,merci pour ton aide a+
 

Discussions similaires

Statistiques des forums

Discussions
311 721
Messages
2 081 927
Membres
101 842
dernier inscrit
seb0390