XL 2010 Index max

[chris6999]

Bonjour et bonne année le FORUM

Je souhaiterais savoir comment combiner les fonctions INDEX MAX dans le cas suivant :

J'ai un fichier avec en étiquettes ligne 7 ma valeur de référence (Dans mon fichier exemple de A à H)
En colonne B sont affichées la dates de l'année 2017

Je cherche à connaître pour la donnée référencée dans la cellule C3
La date maximale où figure un temps enregistré sur la colonne correspondante

Ex pour la valeur référence A saisie en C3 :
S'affiche en E3 la date max où un temps a été enregistré pour la colonne portant l'étiquette A.
En l'occurrence dans mon fichier test cela sera le 06/01/2007

Merci d'avance pour votre aide

 

[Shakki]

Bonjour,

Essaye avec cette formule en E3 :

INDEX($B$8:$B$258;EQUIV(9^9;E$8:E$258;1))

A+

 

[chris6999]

Merci Shaaki

Votre proposition fonctionne mais ne reste uniquement applicable à la colonne E.
Ce que je recherche c'est faire une recherche sur l'ensemble des colonnes et renvoyer la dernière date saisie pour la valeur recherchée quelle que soit la colonne concernée.

Merci quand même
Cordialement

 

[job75]

Bonjour chris6999, Shakki,

D'abord svp mettez le mode de calcul en Automatique, le Manuel Ce lien n'existe plus

En E3 :

=SIERREUR(INDEX(B:B;EQUIV(9^9;DECALER(A:A;;EQUIV(C3;7:7;0)-1)));"")

Noter que la formule peut créer une référence circulaire s'il n'a pas d'heures sous E7.

Si nécessaire on peut y remédier en compliquant la formule :

=SIERREUR(INDEX(B:B;EQUIV(9^9;DECALER(A8;;EQUIV(C3;7:7;0)-1;EQUIV(9^9;B:B)-7))+7);"")

Edit 1 : pour utiliser sans souci la 1ère formule, la mettre en A4 (fichier joint).

Edit 2 : évidemment sur les versions antérieures à Excel 2007 ne pas utiliser SIERREUR...

A+

 

[Shakki]

Bonjour,

J'étais partie sur Indirect... C'est franchement moins bien pensé que la formule de job75.
Je la mets tout de même.

=SIERREUR(INDEX($B$7:$B$258;EQUIV(9^9;INDIRECT(ADRESSE(7;EQUIV($C$3;$A$7:$Y$7;0))&":"&ADRESSE(258;EQUIV($C$3;$A$7:$Y$7;0)));1));"")

A+

 

[ROGER2327]

Bonjour à tous.

Une autre :​

=SIERREUR(INDEX(B8:B258;1/(1/MAX((DECALER(D8:D258;;EQUIV(C3;E7:X7;0))>0)*LIGNE(1:251))));NA())

À valider par Ctrl Maj Entrée.​

ℝOGER2327
#8443

Mercredi 11 Décervelage 144 (*Saint Eustache, libérateur - fête Suprême Quarte)
19 Nivôse An CCXXV, 7,1712h - marbre
2017-W01-7T17:12:39Z

 

[job75]

Re, bonjour Roger,

A partir d'Excel 2007 le tableau peut être organisé en tableau Excel.

La formule en E3 devient plus homogène :

=SIERREUR(INDEX(Tableau1[Date];EQUIV(9^9;INDEX(Tableau1;;EQUIV(C3;Tableau1[#En-têtes];0))));"")

Fichier joint.

A+

 

[chris6999]

Bonjour

Merci à tous pour ces nombreuses réponses.
Je vais tester tout ça.

Bonne journée