importer donnee saisie dans une textbox vers un classeur fermé

[lydiiee]

Bonjour a tous,

Je souhaiterai importer le code saisi dans une textbox d'un classeur A vers un autre classeur B fermé ainsi que la date et l'heure de la saisie de ce code. N'étant pas une experte Excel, je fais appel a votre aide!

Voici ma derniere tentative sans succes :

Dim numlignevide As Integer
Dim classeurB As String

classeurB = "D:\docs\classeurB.xls"

numlignevide = Workbooks("classeurB.xls").Sheets("sheet1").Columns(2).Find("").Row

classeurB.Sheets("sheet1").Cells(numlignevide, 2) = TextBox1.Text

Si quelqu'un peut m'aider!!

Merci d'avance!

 

[Staple1600]

Re : importer donnee saisie dans une textbox vers un classeur fermé

Bonjour

Test OK sur mon PC
Pré-requis
Un userform avec un TextBox1 et un CommandButton1 dans le classeurA
Le classeurB est fermé
Mettre ce code dans l'userform (classeurA)

Private Sub CommandButton1_Click()
Dim ChCLASSEURB$, MAJ$
ChCLASSEURB = "C:\Temp\ClasseurB.xls" 'ici adapter selon vos besoins
MAJ = TextBox1
Application.ScreenUpdating = False
With Workbooks.Open(ChCLASSEURB) 'on ouvre
    With .Worksheets(1)'dans la feuille 1 du classeurB, on copie
        .Range("A65536").End(xlUp)(2).Resize(, 3) = Array(MAJ, Date, Time)'ceci
    End With
    .Close True'on ferme le classuer B en enregistrant les données qui viennent d'être ajoutées
End With
Unload Me'on décharge l'userform du classeurA
End Sub

EDITION: C'est bien de joindre une PJ
Tu le fais dans ce fil
https://www.excel-downloads.com/thr...la-date-lheure-et-les-donnees-saisies.188547/
Mais pas dans celui-là
Va comprendre, Charles !

 

[lydiiee]

Re : importer donnee saisie dans une textbox vers un classeur fermé

Bonsoir JM

Un grand merci pour ton aide!! C'est juste parfait!

Désolée pour la piece jointe mais dans un de mes derniers postes on m'a reproché que mon fichier n'était pas assez clair et puis comme ca ca m'aide aussi a mieux comprendre le code, etant débutante j'aime pouvoir comprendre le code et savoir l'adapter et ne pas avoir mon fichier tout pret ;-)

Encore merci beaucoup!
Lydiiee