grouper 2 colonnes de plusieurs pages

fabridi

XLDnaute Nouveau
Bonjour,

je dois mettre à la suite de 2 colonnes d'un tableau (exemple colonnes F et G) qui sont sur plusieurs pages (feuille1, 2 etc...)

Je peux les mettre à la suite en faisant sur chaque page copier les 2 colonnes revenir sur la feuille1 et les coller à la suite, mais c'est très long j'ai 40 feuilles.

J'ai excel 2013

Merci de votre aide
 

Theze

XLDnaute Occasionnel
Bonjour,

Une piste. La feuille qui récupère les valeurs se nomme "Feuil1", si ce n'est pas ça, adapter dans le code :
Code:
Sub Test()
   
    Dim FeRecap As Worksheet
    Dim FeCible As Worksheet
    Dim Plage As Range
    Dim Lig As Long
   
    Set FeRecap = Worksheets("Feuil1")
   
    For Each FeCible In Worksheets
       
        If FeCible.Name <> FeRecap.Name Then
       
            With FeCible: Set Plage = .Range(.Cells(1, 6), .Cells(.Rows.Count, 7).End(xlUp)): End With
           
            With FeRecap
           
                Lig = .Cells(.Rows.Count, 6).End(xlUp).Row + 1
                .Range(.Cells(Lig, 6), .Cells(Lig + Plage.Rows.Count - 1, 7)).Value = Plage.Value
               
            End With
           
           
        End If
       
    Next FeCible
   
End Sub
 

job75

XLDnaute Barbatruc
Bonsoir fabridi, Theze, vmax01, cp4,

Faudrait savoir ce qu'on veut, au post #1 on parlait des colonnes F et G...

Alors ici je copie tout, qui peut le plus peut le moins :
Code:
Private Sub Worksheet_Activate()
Dim w As Worksheet, h&, lig&
Application.ScreenUpdating = False
Rows("2:" & Rows.Count).Delete 'RAZ
For Each w In Worksheets
    If w.Name <> Me.Name Then
        With w.[A1].CurrentRegion
            h = .Rows.Count - 1
            If h Then .Offset(1).Resize(h).EntireRow.Copy Cells(lig + 2, 1): lig = lig + h
        End With
    End If
Next
End Sub
La macro est à placer dans le code de la feuille "Grouper" (clic droit sur l'onglet et Visualiser le code).

Fichier joint.

A+
 

Pièces jointes

  • 1(1).xls
    62 KB · Affichages: 17

Discussions similaires

Statistiques des forums

Discussions
311 720
Messages
2 081 923
Membres
101 840
dernier inscrit
SamynoT