Formules tableau nb.si avec conditions....

[pilotebien]

Bonjour

Dans le tableau je souhaiterai calculer plusieurs éléments

Dans la colonne A je voudrais avoir le total de logements sans "les communs" qui se trouve dans la colonne D. J'ai pensé a NB.Si mais comment enlever les lignes concernées par les communs.?

Je veux la même chose pour le total de logement dans chaque zone colonne E (corse, sud, nord) toujours en retirant les communs de la colonne D

dans la colonne G je souhaite avoir le nombre de logement visités avec et sans les communs .

Merci de votre aide.

 

[R@chid]

Re : Formules tableau nb.si avec conditions....

Bonsoir,

Sous réserve d'avoir compris,

En A4,

=NB.SI.ENS(A6:A49;"?*";D6:D49;"<>"&"communs")

F2,

=NB.SI.ENS(A$6:A$49;E2;D$6:D$49;"<>"&"communs")

@ tirer vers le bas

En G4,

=NB(G6:G49)

@ + +

 

[Isab]

Re : Formules tableau nb.si avec conditions....

Bonjour le forum

pour completer les réponses proposées ci-dessus:

- ( surtout en cas d'utlisations de filtres) les résultats s'adapteront
- pour contourner la fonction =NB.SI.ENS ( qui helas n'existe pas dans cetraines versions d'excel).

En A4 ( il faut une validation matricielle Ctrl+Maj+Ent)

=SOMME(SI(($A$6:$A$49<>"")*($D$6:$D$49<>"communs"); SOUS.TOTAL(103;INDIRECT("A" & LIGNE($D$6:$D$49)));0))

En F2 ( et tirer la formule vers le bas jusqu'à F4) ( il faut une validation matricielle Ctrl+Maj+Ent)

=SOMME(SI(($A$6:$A$49<>"")*($D$6:$D$49<>"communs")*($A$6:$A$49=$E2); SOUS.TOTAL(103;INDIRECT("A" & LIGNE($A$6:$A$49)));0))

En G4 ( il faut une validation matricielle Ctrl+Maj+Ent)

=SOMME(SI(($G$6:$G$49<>""); SOUS.TOTAL(103;INDIRECT("G" & LIGNE($G$6:$G$49)));0))

Bonne soirée

 

[pilotebien]

Re : Formules tableau nb.si avec conditions....

Super. Ca marche du feu de dieu. Exactement ce que je voulais. Merci bien . Merci