formule

[moupa]

Bonjour à tous,

Voilà je vais m'occuper de faire le chronométrage d'un raid multisport.Mon logiciel de gestion du chrono me permet d'exporter un fichier csv, que je vais incorporer par une macro dans un fichier excel via l'onglet csv.J'ai donc un onglet bases ou la je vais devoir récupérer certaines donnés qui sont dans l'onglet csv et je bloc sur une formule.Donc voici se que je voudrais faire dans le fichier joint:
Je voudrais récupérer sur l'onglet bases dans la cellule F6, le temps qui correspond au poste de la cellule F4, de l'équipe de la cellule A6, qui se trouve dans l'onglet csv à partir de la colonne "AU".
D'après vous quelle est la meilleur solution?
merci d'avance
Cdlt
moupa

 

[Tibo]

Re : formule

Bonjour,

Un essai avec cette formule en F6 :

=SI(OU(NB.SI(CSV!$A$2:$A$100;$A6)=0;NB.SI(DECALER(CSV!$A$1;
EQUIV($A6;CSV!$A$2:$A$100;0);1;;80);F$4)=0);"";INDEX(CSV!$A$1:$BT$100;
EQUIV($A6;CSV!$A$2:$A$100;0)+1;EQUIV(F$4;DECALER(CSV!$A$1;
EQUIV($A6;CSV!$A$2:$A$100;0);1;;80);0)+2))

à recopier vers le bas et vers la droite.

Plages de cellules à adapter

Essaye et dis nous

@+

 

[moupa]

Re : formule

Bonjour Tibo

Apparemment cela fonction, mais afin de na pas rester bête sur ce coup là,
peux tu me faire une petite explication, se serait sympa
merci
cdlt
moupa

 

[Tibo]

Re : formule

Bonjour,

Petite tentative d'explication :

Le principe consiste d'abord à repérer le n° de ligne de dossard avec cette partie :

EQUIV($A6;CSV!$A$2:$A$100;0)+1

Ensuite, à l'aide de la fonction DECALER, je crée une matrice correspondant à la ligne du dossard :

DECALER(CSV!$A$1;EQUIV($A6;CSV!$A$2:$A$100;0);[COLOR=red]1[/COLOR];;80)

Dans cette matrice, je recherche avec EQUIV l'emplacement du n° de l'épreuve :

EQUIV(F$4;DECALER(CSV!$A$1;EQUIV($A6;CSV!$A$2:$A$100;0);1;;80);0)

Le tout est intégré dans un INDEX qui permet de lire le tableau en fonction des 2 critères (n° de ligne et n° de colonne).

Le début de la formule permet d'éviter les messages d'erreur en cas de dossard non trouvé ou de n° d'épreuve non trouvé également :

L'essentiel pour aborder ce genre de formule est de la décomposer

Petit détail, le 1 que j'ai mis en rouge dans la fonction DECALER est nécessité par le fait que certains n° de dossard se retrouvaient également dans les n° d'épreuve.

N'hésite pas à tester en décomposant chaque partie de la formule.

@+

 

[moupa]

Re : formule raid multisport

Bonjour à vous tous,

J"ai encore besoin d'un petit coup de pouce,ou j'ai un soucis pour récupérer dans l'onglet résultats les pénalités des postes manquant attribués dans chaque section de l'onglet postes.Les postes manquant se retrouve dans une cellule avec la caractère ------.Donc si je résume dans l'onglet résultats,il me faudrait retrouver sur l'équipe de la colonne b6, les postes manquant dans l'onglet poste
qui correspond a la section 1 et qui a une pénalité dans la cellule de la ligne 6 ouf.
de plus est il possible de faire un classement sur chaque section dans l'onglet résultat.
J'espère mettre bien exprimer et je vous joins mon fichier pour info
merci d'avance
cdlt
moupa

 

[moupa]

Re : formule raid multisport

bonjour,
un petit up, car pas de réponse de votre par
svp merci pour votre aide
moupa