Formule SI

[Titi]

Bonsoir tout le monde,

Je suis en train de créer un fichier Excel et afin d'éviter de créer 20 feuilles je souhaite en changeant un seul mot que la fiche se mette au nom voulu.

Voici la formule qui me pose problème :

SI($B$1="";"";si($B$1=Tableau général!$AE$2;si(Tableau général!AE3="";"";Tableau général!AE3);si($B$1=Tableau général!$AF$2;si(Tableau général!AF3="";"";Tableau général!AF3);si($B$1=Tableau général!$AG$2;si(Tableau général!AG3="";"";Tableau général!AG3);si($B$1=Tableau général!$AH$2;si(Tableau général!AH3="";"";Tableau général!AH3);si($B$1=Tableau général!$AI$2;si(Tableau général!AI3="";"";Tableau général!AI3);si($B$1=Tableau général!$AJ$2;si(Tableau général!AJ3="";"";Tableau général!AJ3);si($B$1=Tableau général!$AK$2;si(Tableau général!AK3="";"";Tableau général!AK3);si($B$1=Tableau général!$AL$2;si(Tableau général!AL3="";"";Tableau général!AL3);si($B$1=Tableau général!$AM$2;si(Tableau général!AM3="";"";Tableau général!AM3);si($B$1=Tableau général!$AN$2;si(Tableau général!AN3="";"";Tableau général!AN3);si($B$1=Tableau général!$AO$2;si(Tableau général!AO3="";"";Tableau général!AO3);si($B$1=Tableau général!$AP$2;si(Tableau général!AP3="";"";Tableau général!AP3);si($B$1=Tableau général!$AQ$2;si(Tableau général!AQ3="";"";Tableau général!AQ3);si($B$1=Tableau général!$AR$2;si(Tableau général!AR3="";"";Tableau général!AR3);si($B$1=Tableau général!$AS$2;si(Tableau général!AS3="";"";Tableau général!AS3);si($B$1=Tableau général!$AT$2;si(Tableau général!AT3="";"";Tableau général!AT3)))))))))))))))))))

Si je découpe ma formule à la fin de AJ elle fonctionne soit de AE à AJ, soit de AK à AT.

Je pense que c'est parce qu'elle est trop longue.
Pourriez vous m'aider afin de l'abrégé (j'ai essayé tous ce que je connaissais mais je n'y arrive pas).

En vous remerciant par avance.

Cordialement.

Titi

 

[Monique]

Bonjour,

à essayer :
=SI(OU($B$1="";NB.SI('Tableau Général'!AE$2:AT$2;$B$1)=0);"";INDEX('Tableau Général'!AE3:AT3;EQUIV($B$1;'Tableau Général'!AE$2:AT$2;0)))

En nommant Tg la feuille Tableau Général :
=SI(OU($B$1="";NB.SI(Tg!AE$2:AT$2;$B$1)=0);"";INDEX(Tg!AE3:AT3;EQUIV($B$1;Tg!AE$2:AT$2;0)))

 

[Monique]

Re,

La même chose avec Rechercheh() :
=SI(OU($B$1="";NB.SI(Tg!AE$2:AT$2;$B$1)=0);"";RECHERCHEH($B$1;Tg!$AE$2:AT3;2;0))

 

[Titi]

Je vous remercie.

Cordialement

Titi

 

[Titi]

Bonjour


C'est cette formule qui fonctionne

=SI(OU($B$1="";NB.SI(Tg!AE$2:AT$2;$B$1)=0);"";INDEX(Tg!AE3:AT3;EQUIV($B$1;Tg!AE$2:AT$2;0)))

mais je n'arrive pas à lui dire que si le résultat = 0 alors rien""

Comment fait on

et merci encore

Cordialement

Titi

 

[Monique]

Bonjour,

Si c'est l'affichage des 0 qui t'embête,
tu peux utiliser le format personnalisé de nombre [=0]"";Standard
et garder la même formule.

Sinon,
=SI(OU($B$1="";NB.SI(Tg!AE$2:AT$2;$B$1)=0);"";SI(INDEX(Tg!AE3:AT3;EQUIV($B$1;Tg!AE$2:AT$2;0))=0;"";INDEX(Tg!AE3:AT3;EQUIV($B$1;Tg!AE$2:AT$2;0))))

Pour raccourcir un peu, tu peux donner un nom à la plage Tg!AE$2:AT$2 (Insertion - Nom - Définir)
=SI(OU($B$1="";NB.SI(Ref;$B$1)=0);"";SI(INDEX(Tg!AE3:AT3;EQUIV($B$1;Ref;0))=0;"";INDEX(Tg!AE3:AT3;EQUIV($B$1;Ref;0))))

 

[Titi]

Merci

Tout marche comme je le souhaite.

 

[Titi]

Bonjour à tous et à toutes,

je souhaiterais créer une formule qui me permette de recherche l'élément dans une autre feuille.

Exemple:
dans feuille 1 colonne A j'ai des noms
dans feuille 2 colonne A j'aimerai que ce mette à jour les noms qui se trouve dans la colonne A de la feuille 1

en fait je souhaite travailler sur un seul tableau et que l'autre se mette à jour automatiquement

Ma formule est : =SI(B1="";"";SI(Tg!D3="f";"";Tg!A3))
mais elle ne met pas à jour si je supprime ou ajoute une ligne il me met REF

Vous remerciant par avance

Cordialement

Titi

 

[Monique]

Re,

La fonction Indirect() devrait aller.
Je préfère te joindre un fichier.

 

[Titi]

Merci

En fait voila je désire :

dans la feuille 1 j'ai un tableau avec
colonne A les projets
Colonne B prix
entre des colonnes pour nous qui ne servent à rien
colonne AE à AT janvier mais dans chaque colonne j'ai un nom de personne

dans la feuille 2 j'ai un tableau récapitulatif
dans la cellule B1 quand j'écris un nom je souhaite que le temps du projet s'inscrive (c'est la formule que vous m'avez donné)
dans la colonne A je souhaite que les projets s'inscrive à la suite que ce ou dans la colonne C de la feuille il n' est pas ecrit f
et surtout que je puisse dans la feuille 1 ajouter et supprimer des lignes

Peut on le faire

si vous ne comprennez pas dites le moi

et pour éviter que je vous agasse tout le temps ou peut on trouver l'explication des différentes fonctions.

Vous remerciant par avance

Cordialement
Titi

 

[Monique]

Re,

Là, ça devient du chinois.
Le plus simple serait de poster un mini fichier.
Pas besoin de 100 lignes, une dizaine suffira.
Tu masques les colonnes qui ne servent à rien.

AE:AT ça fait 16 colonnes, mais tu ne parles que de janvier.
Les 16 colonnes suivantes sont février ?
16 personnes peuvent être sur la même ligne par mois pour chaque projet inscrit en colonne A ?

Tu veux que le temps du projet s'inscrive,
mais on sait seulement que, en colonne A, tu as le projet et, en colonne B, le prix.

Dur, dur...

 

[Titi]

Bonjour

Voici le fichier

Sachant que le nombre de projet peut varier entre 200 et 300.

Merci

Cordialement

Titi

 

[Titi]

Bonjour

Voici le fichier

Sachant que le nombre de projet peut varier entre 200 et 300.

Merci

Cordialement

Titi

 

[Monique]

Re,

Titi, tu ne pourrais pas mettre un fichier Excel ?
Comment veux-tu avoir des réponses si on est obligé de recopier ton fichier image dans une feuille Excel ?

 

[Monique]

Re,

A partir de ton fichier, j'ai essayé quelques formules.
Il y a beaucoup de Decaler(), selon le mois choisi + selon le nom choisi.
J'ai été obligée d'insérer une colonne à gauche, tout le reste est donc décalé.
Tu as beaucoup de formats conditionnels pour te repérer plus facilement.