FORMULE : rechercher la date plus récente par numéro

[Hervé]

Salut les aminches

je cherche la date la plus récente par numéro unique.

soit une liste de numéro associé à des dates, ben je voudrais la plus récente, ca doit passer par un sommeprod, un max ou un grande.valeur, mais je n'y arrive pas.

dans le fichier joint, les données brutes, le résultat attendu

je vous remercie par avance de votre aide

a plus

 

[Victor21]

Re : FORMULE : rechercher la date plus récente par numéro

Bonjour, Hervé.

Peut-être en G6, puis à tirer vers le bas:

=SI(MAX(SI($C$6:$C$16=F6;$D$6:$D$16))=0;"vide";MAX(SI($C$6:$C$16=F6;$D$6:$D$16)))

A valider en matricielle

 

[CISCO]

Re : FORMULE : rechercher la date plus récente par numéro

Bonjour à tous, bonjour Victor21

On peut aussi faire avec

MAX(SI(C$6:C$16=F6;D$6:D$16))

en matriciel (Ctrl+maj tempo+entrer)

avec le format personnalisé [=0]"";jj/mm/aaaa

@ plus

 

[Hervé]

Re : FORMULE : rechercher la date plus récente par numéro

salut à vous deux

ca fonctionne parfaitement, puis-je vous solliciter pour une autre problématique dans la même veine ? oui ? merci

je recherche toujours la date la plus récente, mais si pour un numéro une date est absente on renvoi vide

exemple en pièce jointe

merci d'avance

a plus

 

[Victor21]

Re : FORMULE : rechercher la date plus récente par numéro

Re, Hervé, CISCO.

Tu es sûr d'avoir testé ma proposition ?

 

[excfl]

Re : FORMULE : rechercher la date plus récente par numéro

Bonjour le forum,

=SI(RECHERCHEV(F6;$C$6:$D$16;2;0)=0;"";MAX($D$6:$D$100*($C$6:$C$100=F6)))

Formule matricielle.

 

[Hervé]

Re : FORMULE : rechercher la date plus récente par numéro

salut à vous trois et merci pour votre aide

oui j'ai essayé victor, les trois formules répondent parfaitement à la première problématique mais pas à la seconde.

voir pièce jointe

en somme, on prend le numéro on vérifie les dates, si un champ vide est trouvé on renvoi "vide" sinon on renvoi la date la plus récente.

pas de souci pour le faire en VBA mais j'ai pas les droits informatiques

merci de m'aider une nouvelle fois

a plus

 

[CISCO]

Re : FORMULE : rechercher la date plus récente par numéro

Bonjour

Est-ce que tes dates sont forcément classées par ordre croissant dans ton fichier réel ?

Si oui, essayes avec

INDEX(D$1:D$16;MAX(SI(C$6:C$16=F6;LIGNE($6:$16))))

en matriciel, toujours avec le format personnalisé que j'ai donné dans mon dernier post (et que tu n'as pas utilisé dans ton dernier fichier exemple) ou avec [=0]"vide";jj/mm/aaaa.

@ plus

 

[david84]

Re : FORMULE : rechercher la date plus récente par numéro

Bonjour,
à tester (validation en matriciel) :

=SI(DECALER(D$1;MAX(SI(C$6:C$16=F6;LIGNE(D$6:D$16)))-1;)=0;"vide";DECALER(C$1;MAX(SI(C$6:C$16=F6;LIGNE(D$6:D$16)))-1;1))

A+

 

[Victor21]

Re : FORMULE : rechercher la date plus récente par numéro

Re, bonjour lézamis

Ca change tout ...
Si on veut "vide" dans le cas ou au moins une date n'est pas renseignée, essaie (toujours en validation matricielle
Essaie :

=SI(SOMMEPROD(($C$6:$C$16=F6)*($D$6:$D$16=""));"vide";MAX(SI($C$6:$C$16=F6;$D$6:$D$16)))

 

[R@chid]

Re : FORMULE : rechercher la date plus récente par numéro

Bonjour @ tous,
les données étant triées, alors une formule classique :

=SIERREUR(CNUM(DECALER(D$5;EQUIV(F6;C$6:C$16;0)+NB.SI(C$6:C$16;F6)-1;)&"");"")

@ tirer vers le bas


@ + +

 

[R@chid]

Re : FORMULE : rechercher la date plus récente par numéro

Re,
au cas où les données sont pas triées comme sur le fichier, une matricielle :

=SIERREUR(CNUM(INDEX(D$6:D$16;MAX(SI(C$6:C$16=F6;LIGNE(INDIRECT("1:"&LIGNES(C$6:C$16))))))&"");"")

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas


@ + +

Edit : J'ai compris par "vide" que tu veux laisser la cellule vide

 

[Hervé]

Re : FORMULE : rechercher la date plus récente par numéro

salut à tous

j'ai tout testé (si si victor) vous êtes toujours au TOP.

je ne sais pas si les dates seront toujours triées, j'ai préféré choisir celle de victor je maitrise plus facilement les sommeprod que les décaler, surtout sur des fichiers de 300 000 lignes .

merci beaucoup pour votre aide

a plus