Formule rang sans prendre en compte les #na

RFlo

XLDnaute Nouveau
Bonjour à tous,

J'ai actuellement un souci pour mettre une condition dans ma formule RANG.
En effet, je souhaiterais qu'elle ne prenne pas en compte les #NA qui apparaissent dans ma colonne des sommes.
Si quelqu'un pouvait me donner un coup de main ça serait fort sympathique.

Merci pour votre temps.

ps: ci-joint le fichier pour visualiser mon problème

RF
 

Pièces jointes

  • Classeur1.xlsx
    12 KB · Affichages: 89
  • Classeur1.xlsx
    12 KB · Affichages: 91
  • Classeur1.xlsx
    12 KB · Affichages: 82

ERIC S

XLDnaute Barbatruc
Re : Formule rang sans prendre en compte les #na

Bonjour à tous

je crois comprendre que le problème de Rflo est les #N/A sur toute la colonne E, à cause de ceux de bas de colonne C

dans ce cas, sauf erreur, la solution de papou-net ne fonctionne pas

si en C les #N/A sont en fin de liste, essayer

=RANG(C5;INDIRECT("C5:C"&EQUIV(9^9;C1:C10;1)))

si c'est bien le pb à corriger
 

phlaurent55

Nous a quittés en 2020
Repose en paix
Re : Formule rang sans prendre en compte les #na

Bonjour à tous
Bonjour RFlo, et bienvenue à toi,

Peut-être en modifiant ta formule comme ceci :

Code:
=SI(ESTERREUR(RANG(C5;C$5:C$30;0));"";RANG(C5;C$5:C$30;0))
Cordialement.
@ Papou-Net;
j'avais pensé la même chose mais l'erreur est provoquée pas les #N/A qui se trouvent en C29 et C30

et ceux-là ne semblent pas être arrivés là par formule

on a le même problème avec les cellules F29 et F30

si on efface le contenu des cellules que je viens de citer, tout fonctionne à part le message d'erreur #DIV/0! à quatre endroits
et qui pourront se résoudre en mettant =SI(C5;(F5-C5)/C5;"") en I5 ( à recopier vers le bas)

à+
Philippe

Edit: Salut Eric
 
Dernière édition:

R@chid

XLDnaute Barbatruc
Re : Formule rang sans prendre en compte les #na

Bonjour @ tous,
Salut RFlo et Bienvenu sur XLD,
il vaut mieux de gerer les #N/A sur la formule en colonne C, car il y surement une formule qui renvoie les #N/A...
Amicalement
 

tototiti2008

XLDnaute Barbatruc
Re : Formule rang sans prendre en compte les #na

Bonjour à tous,

Si les #NA pas forcément en fin de liste, peut-être en E5

Code:
=SOMME((SI(ESTNUM($C$5:$C$30);$C$5:$C$30)>=C5)*1)-SOMME((SI(ESTNUM($C$5:$C$30);$C$5:$C$30)=C5)*1)+1-SOMME(NON(ESTNUM($C$5:$C$30))*1)

à valider par Ctrl+Maj+Entrée
puis à recopier vers le bas
 

RFlo

XLDnaute Nouveau
Re : Formule rang sans prendre en compte les #na

Je tiens sincèrement à tous vous remercier pour votre aide.

@ERIC S : La formule fonctionne très bien si le tableau reste figé. Cependant les données ne se suivent pas lorsque je les trie par ordre décroissant.Par curiosité, peux-tu m'expliquer le mécanisme de la formule ?

@tototiti2008: Elle convient parfaitement à mon problème, mille mercis.

Bonne continuation.

RF
 

ERIC S

XLDnaute Barbatruc
Re : Formule rang sans prendre en compte les #na

=RANG(C5;INDIRECT("C5:C"&EQUIV(9^9;C1:C10;1)))

explication : utilisation d'EQUIV avec valeur approchée, on recherche le nombre 9 puissance 9, qu'on estime introuvable car trop grand et donc on obtient la position du dernier nombre dans la liste C1:C10, ce qui correspond à sa ligne. On aurait pu mettre C:C ce qui nous affranchit de de la fin de recherche en C10 si la liste s'allonge). Dans ton exemple on obtient 8

Maintenant qu'on a la ligne cherchée, on utilise indirect pour recomposer l'adresse du tableau de recherche qui devient "C5:C8" dans ton exemple

Voilà pour les explications
 

R@chid

XLDnaute Barbatruc
Re : Formule rang sans prendre en compte les #na

Bonjour @ tous,

Edit :

Celle de Tototiti fonctionne parfaitement...
Mais pourquoi pas faire compliqué quand on peut faire simple ;):eek:???
Code:
=SI(ESTERREUR(C5);"";NB(C$5:C$30)-NB.SI(C$5:C$30;"<="&C5)+1)
Validation Classique,
tu peux la comparer avec celle de Tototiti, voir PJ
Amicalement


 

Pièces jointes

  • RANG.xls
    41.5 KB · Affichages: 76
  • RANG.xls
    41.5 KB · Affichages: 83
  • RANG.xls
    41.5 KB · Affichages: 75
Dernière édition:

Discussions similaires

Statistiques des forums

Discussions
311 725
Messages
2 081 941
Membres
101 846
dernier inscrit
Silhabib