formule pour compter les jours

[gui59300]

Bonjour

je remplis un tableau dans le quel je rentre des dates après une phase de de test, je recherches une formule pouvant me dire par exemple dans la semaine 27 j'ai fais 2 test, dans la semaine 28 5 test ....
je vous joins un tableau pour expliquer.

merci

 

[Brigitte]

Re : formule pour compter les jours

Bonjour,

Une première tentative, mais il faut trouver la bonne méthode pour récupérer le numéro de semaine, je sais qu'il y a souci parfois avec cette fonction.

Je cherche en attendant.

Sans doute mieux avec :

=1+ENT((D588-DATE(ANNEE(D588+4-JOURSEM(D588+6));1;5)+JOURSEM(DATE(ANNEE(D588+4-JOURSEM(D588+6));1;3)))/7)

En D588 : date, adapter le numéro de cellule (ici un fichier que j'ai)

Je remets le fichier avec plusieurs méthodes pour te montrer les différences. La deuxième est sans doute la plus fiable (je crois que c jeanmarie qui avait donné cette soluce pour trouver le numéro de semaine, sous réserve de bonne mémoire)

 

[ROGER2327]

Re : formule pour compter les jours

Bonjour gui59300

A essayer :

[COLOR="DarkSlateGray"]=SOMME((ENT((10+$C$9:$C$16-JOURSEM($C$9:$C$16;3)-DATE(ANNEE(3+$C$9:$C$16-JOURSEM($C$9:$C$16;3));1;4)+JOURSEM(DATE(ANNEE(3+$C$9:$C$16-JOURSEM($C$9:$C$16;3));1;4);3))/7)=F9)*1)[/COLOR]

en principe conforme à la norme internationale ISO 8601.​

ROGER2327
_
_
Ajout (merci Brigitte) : formule matricielle à valider par Ctrl + Maj + Entrée.

 

[Brigitte]

Re : formule pour compter les jours

Ca me fait : #valeur, Roger, ta formule ... C'est peut être une matricielle ?

Oui c'est cela... Il faut la valider par ctrl/maj/entrée, gui... la formule de Roger... si comme moi tu connais pas trop.

 

[JCGL]

Re : formule pour compter les jours

Bonjour à tous,

Pour avoir le numéro de semaine à la norme ISO :

=ENT(MOD(ENT((A3-2)/7)+0.6;52+5/28))+1

Avec la date en A3

Formule de Monique, je crois...

A+ à tous

 

[Brigitte]

Re : formule pour compter les jours

Re,

Pour avoir le numéro de semaine à la norme ISO :


Code:
=ENT(MOD(ENT((A3-2)/7)+0.6;52+5/28))+1
Avec la date en A3

Tu l'as testée JC ? chez moi ca ne calcule pas et ca bugge sur le 0.6

Il faut mettre une virgule

=ENT(MOD(ENT((A3-2)/7)+0,6;52+5/28))+1

 

[JCGL]

Re : formule pour compter les jours

Re,

Chez moi le séparateur décimal est le point, je sais pas conventionnel, mais tellement plus facile quand on tape beaucoup de chiffres

A+ à tous

 

[Brigitte]

Re : formule pour compter les jours

Tu as bien raison, c'est plus facile... Chez moi la virgule... Et chez gui ???

 

[gui59300]

Re : formule pour compter les jours

bonjour

Je vous remercie tous pour vos réponses, je vais utiliser la formule de ROGER2327 elle corresponds vraiment à ce que je recherche car elle fait la somme d'une série de cellules. Les autres pourront me servir sur autre chose.

J'ai juste un problème c'est lorsque je veux prendre une plus grande série de cellule, par exemple pour la feuille que j'ai envoyé les dates sont comprises entre les cellules C9:C16, si je souhaite étendre cette formule sur C9:C30 la formule me marque #nombre car les cellules entre C17 et C30 ne sont pas encore remplient, comment peut ton faire ?

Je voulais savoir aussi pour ma culture perso pourquoi la formule à ROGER2327 fonctionne que lorsque on fait ctrl/maj/entrée ?

Pour répondre à Brigitte et JCGL moi il faut que j'utilise une virgule.

 

[ROGER2327]

Re : formule pour compter les jours

Bonjour à tous

J'ai juste un problème c'est lorsque je veux prendre une plus grande série de cellule, par exemple pour la feuille que j'ai envoyé les dates sont comprises entre les cellules C9:C16, si je souhaite étendre cette formule sur C9:C30 la formule me marque #nombre car les cellules entre C17 et C30 ne sont pas encore remplient, comment peut ton faire ?

[COLOR="DarkSlateGray"]=SOMME([COLOR="Sienna"]SI(ESTVIDE($C$9:$C$30);0;[/COLOR](ENT((10+$C$9:$C$30-JOURSEM($C$9:$C$30;3)-DATE(ANNEE(3+$C$9:$C$30-JOURSEM($C$9:$C$30;3));1;4)+JOURSEM(DATE(ANNEE(3+$C$9:$C$30-JOURSEM($C$9:$C$30;3));1;4);3))/7)=F9)*1)[COLOR="Sienna"])[/COLOR][/COLOR]

qu'on peut simplifier largement avec la formule de Monique signalée par JCGL :

[COLOR="DarkSlateGray"]=SOMME(SI(ESTVIDE($C$9:$C$30);0;(ENT(MOD(ENT(($C$9:$C$30-2)/7)+[COLOR="Sienna"]3/5[/COLOR];52+5/28))+1=F9)*1))[/COLOR]

J'ai apporté une modification à la formule de Monique pour réconcilier les adeptes du point décimal et les tenants de la virgule décimale.

Je voulais savoir aussi pour ma culture perso pourquoi la formule à ROGER2327 fonctionne que lorsque on fait ctrl/maj/entrée ?

C'est comme ça. Point.
Je plaisante : ce mode de validation est nécessaire pour certaines formules matricielles (certaines seulement, car SOMMEPROD() par exemple se valide classiquement par Entrée.)
Supposons qu'on veuille calculer A1*B1 + A2*B2 + A3*B3.
On met en C1 : =A1*B1,
en C2 : =A2*B2,
en C3 : =A3*B3,
puis, où l'on veut, =C1+C2+C3. Mais on peut faire ça avec une formule matricielle : =SOMME(A1:A3*B1:B3), ce qui signifie "multiplier A1 par B1, multiplier A2 par B2, multiplier A3 par B3, puis sommer le tout". Autrement dit la formule matricielle fait toute seule tous les calculs décrit ci-dessus. Et pour qu'Excel comprenne que c'est cela qu'il doit faire, il faut le lui dire en validant par Ctrl + Maj + Entrée.
Voilà...​

Bonne journée.
ROGER2327

 

[gui59300]

Re : formule pour compter les jours

Bonjour à tous

[COLOR="DarkSlateGray"]=SOMME([COLOR="Sienna"]SI(ESTVIDE($C$9:$C$30);0;[/COLOR](ENT((10+$C$9:$C$30-JOURSEM($C$9:$C$30;3)-DATE(ANNEE(3+$C$9:$C$30-JOURSEM($C$9:$C$30;3));1;4)+JOURSEM(DATE(ANNEE(3+$C$9:$C$30-JOURSEM($C$9:$C$30;3));1;4);3))/7)=F9)*1)[COLOR="Sienna"])[/COLOR][/COLOR]

qu'on peut simplifier largement avec la formule de Monique signalée par JCGL :

[COLOR="DarkSlateGray"]=SOMME(SI(ESTVIDE($C$9:$C$30);0;(ENT(MOD(ENT(($C$9:$C$30-2)/7)+[COLOR="Sienna"]3/5[/COLOR];52+5/28))+1=F9)*1))[/COLOR]

J'ai apporté une modification à la formule de Monique pour réconcilier les adeptes du point décimal et les tenants de la virgule décimale.

C'est comme ça. Point.
Je plaisante : ce mode de validation est nécessaire pour certaines formules matricielles (certaines seulement, car SOMMEPROD() par exemple se valide classiquement par Entrée.)
Supposons qu'on veuille calculer A1*B1 + A2*B2 + A3*B3.
On met en C1 : =A1*B1,
en C2 : =A2*B2,
en C3 : =A3*B3,
puis, où l'on veut, =C1+C2+C3. Mais on peut faire ça avec une formule matricielle : =SOMME(A1:A3*B1;B3), ce qui signifie "multiplier A1 par B1, multiplier A2 par B2, multiplier A3 par B3, puis sommer le tout". Autrement dit la formule matricielle fait toute seule tous les calculs décrit ci-dessus. Et pour qu'Excel comprenne que c'est cela qu'il doit faire, il faut le lui dire en validant par Ctrl + Maj + Entrée.
Voilà...​

Bonne journée.
ROGER2327

c'est parfait merci

 

[ROGER2327]

Re : formule pour compter les jours

Bonjour à tous

Ceci pour signaler la correction d'une faute de frappe dans mon précédent message (#10). Il faut lire

[COLOR="DarkSlateGray"][B]=SOMME(A1:A3*B1:B3)[/B][/COLOR]

et non =SOMME(A1:A3*B1;B3).
Merci à Brigitte de m'avoir signalé cette erreur.​

ROGER2327