Formule avec INDEX EQUIV PETITE.VALEUR

[BChaly]

Bonsoir à tous,

Avec de nombreuses discussions concernant ce sujet, je suis presque arrivé
à ce que je voulais. Malheureusement, ma formule ne fonctionne que pour la
première valeur.

Formule en G2:

{=INDEX($D$2:$D$16;SMALL(INDEX(($C$2:$C$16=F2)*(MATCH(ROW($D$2:$D$16);ROW($D$2:$D$16)))+($C$2:$C$16<>F2)*65000;0;0);ROW(A$1)))}

Que dois-je modifier?

Cordialement,

BChaly

 

[job75]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Bonsoir BChaly,

A priori il y a incohérence entre votre 1er tableau et le 3ème (J1:K16).

Formule version française en G2 :

=INDEX(D:D;PETITE.VALEUR(SI(C$1:C$16=F2;LIGNE(C$1:C$16));NB.SI(F$2:F2;F2)))

et pour votre version :

=INDEX(D:D;SMALL(IF(C$1:C$16=F2;ROW(C$1:C$16));COUNTIF(F$2:F2;F2)))

A valider bien sûr par Ctrl+Maj+Entrée.

Bonne soirée.

 

[BChaly]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Bonsoir job75,

Bravo et Merci!!! Ceci me convient parfaitement.

En effet, je me suis trop précipité et le 3eme tableau donne un résultat erroné.

Par contre, votre formule donne exactement le résultat que je souhaite.

Bonne soirée.

Cordialement,

BChaly

 

[R@chid]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Bonjour @ tous,
une autre non matricielle :

=SMALL(OFFSET(D$1,MATCH(F2,C$2:C$16,0),,COUNTIF(C$2:C$16,F2)),COUNTIF(F$2:F2,F2))

@ + +

 

[job75]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Bonjour R@chid

Ta formule fonctionne si les items identiques sont groupés en colonne C (comme c'est le cas sur le fichier).

Sinon il faut ma formule.

PS : apparemment la version Excel de notre ami utilise le point-virgule comme séparateur des arguments.

A+

 

[R@chid]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Salut Job75,
Oui l'ami, je vois, je voulais juste proposer cette variante pour te croiser.
Sinon, je ne vois pas l’intérêt de le faire par formules, alors qu'un tri croissant sur les 2 colonnes fera l'affaire.


@ + +

 

[job75]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Re,

Bon alors R@chid toujours avec les items groupés en colonne C :

=DECALER(D$1;EQUIV(F2;C$2:C$16;0)+NB.SI(F$2:F2;F2)-1;)

=OFFSET(D$1;MATCH(F2;C$2:C$16;0)+COUNTIF(F$2:F2;F2)-1;)

A+

 

[R@chid]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Re,
, oui pourquoi pas du fait que la base de données est déjà triée par ordre croissant, j'ai pas vu , tu m'as eu sur ce coup là.


@ + +

 

[R@chid]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Re,
partant du fait que la base n'est pas triée.
voir PJ.



@ + +

 

[job75]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Re,

C'est une excellente manière de trier le tableau (sur la colonne T2) par formule.

A+

 

[R@chid]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Re,
On peut réduire la matricielle en colonne T2 :

=INDEX(C2:C16;EQUIV(PETITE.VALEUR(NB.SI(C2:C16;"<"&C2:C16);LIGNE()-1);NB.SI(C2:C16;"<"&C2:C16);0))

@ + +

 

[R@chid]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Re,
une matricielle directement en T3 sans passer par T2 :

=INDEX(D2:D16;EQUIV(PETITE.VALEUR(NB.SI(C2:C16;"<"&C2:C16)*9^9+D2:D16;LIGNE()-1);NB.SI(C2:C16;"<"&C2:C16)*9^9+D2:D16;0))

@ + +

 

[BChaly]

Re : Formule avec INDEX EQUIV PETITE.VALEUR

Bonsoir à tous les deux,

Vous êtes impressionnant!!!

Bravo et Merci encore pour votre aide.

Cordialement,

BChaly