Fonction SOMMEPROD(SOMME.SI(INDIRECT ne fonctionne pas

cedana

XLDnaute Nouveau
Bonsoir.

J' ai un classeur 13 feuilles ( une pour chaque mois et une récap )

Je souhaite sommer dans la feuille récap les montants totaux qui correspondent par exemple à 2 critères " 2130 " et " 6700 "

La formule suivante fonctionne bien pour un seul critère mais je n' y arrive pas pour 2 critères.

SOMMEPROD(SOMME.SI(INDIRECT(Feuilles&"!C7:C100");2130;INDIRECT(Feuilles&"!G7:G100"))
Comment modifier cette fonction.

Je vous remercie par avance de votre aide.
 

Pièces jointes

  • Suivicptes6.xls
    126 KB · Affichages: 133
Dernière édition:

Amilo

XLDnaute Accro
Re : Fonction SOMMEPROD(SOMME.SI(INDIRECT ne fonctionne pas

Bonjour le forum, Rachid, Cedana,

Avec 2 critères, essayez voir avec somme.si.ens

En C5 :

=SOMMEPROD(SOMME.SI.ENS(INDIRECT(Feuilles&"!G7:G100");INDIRECT(Feuilles&"!C7:C100");A5;INDIRECT(Feuilles&"!E7:E100");B5))

Cordialement
 
Dernière édition:

cedana

XLDnaute Nouveau
Re : Fonction SOMMEPROD(SOMME.SI(INDIRECT ne fonctionne pas

Bonjour Amilo ,R@chid et le forum.

Merci pour vos réponses.

La formule d' Amilo prend bien en compte les 2 critères " 2130" et "6700" mais j'ai le résultat suivant:

Code:
#NOM?

Est-ce que EXCEL 2003 prend bien en charge ?

Code:
SOMME.SI.ENS

Bien cordialement.
 

cedana

XLDnaute Nouveau
Re : Fonction SOMMEPROD(SOMME.SI(INDIRECT ne fonctionne pas

Bonjour gosselien et le forum.

Merci de ta réponse.

Effectivement je viens de tester la formule avec SOMME.SI.ENS sous EXCEL 2007 et ça fonctionne.

Comment peut-on faire avec SOMMEPROD(SOMME.SI(INDIRECT sous EXCEL 2003 ?

Si un membre a la réponse merci d'avance.

Cordialement.
 

cedana

XLDnaute Nouveau
Re : Fonction SOMMEPROD(SOMME.SI(INDIRECT ne fonctionne pas

Bonjour Gosselien.

Merci pour ton aide.

Effectivement la formule de R@chid fonctionne mais avec un seul critère et je cherche une solution pour sommer des cellules
des 12 feuilles mais avec 2 critères.
J' ai modifié la formule mais j' obtiens un 0.00.

Code:
SOMMEPROD(SOMME.SI(INDIRECT(Feuilles&"!C7:C100";A9);INDIRECT(Feuilles&"!E7:E100";B9);INDIRECT(Feuilles&"!G7:G100")))

Si vous avez la solution je prends.

Cordialement
 

R@chid

XLDnaute Barbatruc
Re : Fonction SOMMEPROD(SOMME.SI(INDIRECT ne fonctionne pas

Bonjour @ tous,
Vraiment je ne vois pas de solutions pour Excel2003, sauf d'ajouter une colonne intermédiaire sur chaque mois où l'on concatène ces 2 colonnes C et E.


@ + +
 

R@chid

XLDnaute Barbatruc
Re : Fonction SOMMEPROD(SOMME.SI(INDIRECT ne fonctionne pas

Re,
La colonne intermédiaire on peut l'ajouter facilement, il suffit de sélectionner tous les onglets et l'ajouter sur n'importe quel onglet du Groupe De Dravail.

Voir PJ


@ + +
 

Pièces jointes

  • Suivicptes6_4.xls
    159.5 KB · Affichages: 108

Amilo

XLDnaute Accro
Re : Fonction SOMMEPROD(SOMME.SI(INDIRECT ne fonctionne pas

Bonsoir à tous,

Désolé pour ma formule avec la fonction somme.si.ens, je n'ai effectivement pas fait attention à la version d'Excel,
Sinon, je me suis inspiré d'une formule matricielle 3D trouvée sur le site de Boisgontier et voici la proposition :

Vous n'avez plus besoin de la plage nommée avec les mois de la colonne F

Code:
=SOMMEPROD((N(DECALER(INDIRECT(TEXTE(DATE(;COLONNE(A:L);1);"mmmm")&"!C7");LIGNE($1:$100)-1;0))=A5)*(N(DECALER(INDIRECT(TEXTE(DATE(;COLONNE(A:L);1);"mmmm")&"!E7");LIGNE($1:$100)-1;0))=B5)*N(DECALER(INDIRECT(TEXTE(DATE(;COLONNE(A:L);1);"mmmm")&"!G7");LIGNE($1:$100)-1;0)))
Cordialement
 
Dernière édition:

cedana

XLDnaute Nouveau
Re : Fonction SOMMEPROD(SOMME.SI(INDIRECT ne fonctionne pas

Bonsoir à tous.
Je remercie R@chid , Amilo et tous les intervenants.
Je vais finalement utiliser la formule de R@chid en ajoutant une colonne intermédiaire.
Je viens de tester la formule d' Amilo mais j'ai cette erreur #NOM?. Je vais essayer de savoir d' où vient cette erreur.
Bonne nuit.
Bien cordialement.
 

Amilo

XLDnaute Accro
Re : Fonction SOMMEPROD(SOMME.SI(INDIRECT ne fonctionne pas

Bonsoir cedana,

Sauf erreur de ma part, la formule devrait fonctionner avec toutes les versions,
Avez-vous "copier coller" la formule dans le fichier que Rachid a ajouté dans son dernier message ?
Dans celui-ci, je ne rencontre aucun souci,
A moins que d'autres ne viennent confirmer que cette formule ne fonctionne pas avec les versions antérieures à 2007,

Cordialement
 
Dernière édition:

cedana

XLDnaute Nouveau
Re : Fonction SOMMEPROD(SOMME.SI(INDIRECT ne fonctionne pas

Bonsoir Amilo.

Il n' y a pas d'erreurs de ta part, je viens de refaire un copier-coller et ta formule fonctionne correctement.
Je te remercie beaucoup pour toutes tes recherches et avec toutes mes excuses.
Je te souhaite une bonne soirée.
A bientôt.
Bien cordialement.
 

Discussions similaires

Statistiques des forums

Discussions
311 725
Messages
2 081 943
Membres
101 849
dernier inscrit
florentMIG