XL 2016 Fonction LIEN_HYPERTEXTE pour pointer vers un onglet du fichier actif

David Aubert

XLDnaute Barbatruc
Administrateur
Modérateur
Bonjour à tous,

Je suis en train de finaliser un programme dans lequel je souhaite utiliser la fonction LIEN_HYPERTEXTE pour pointer vers un onglet du classeur actif.
Je souhaite faire cela sans VBA. :)
Le cas concret se trouve dans mon fichier joint et dans l'onglet "CLASSEMENT".
C'est dans la colonne E de E5 à E204 que je souhaite intégrer cette fonction.
Malheureusement tout ce que j'ai essayé ne fonctionne pas.

Si vous voyez une solution, je suis preneur.

Merci d'avance

David
 

Pièces jointes

  • FICHIER TESTS.xlsm
    1.7 MB · Affichages: 71

job75

XLDnaute Barbatruc
Bonjour David, Modeste,

Oui c'est bien ça, pour toute version Excel.

Plus simplement :
Code:
=SI(ESTERREUR(LIEN_HYPERTEXTE("#'"&D5&"'!A1"));"";LIEN_HYPERTEXTE("#'"&D5&"'!J31";D5))
Et à partir d'Excel 2007 :
Code:
=SIERREUR(LIEN_HYPERTEXTE("#'"&D5&"'!J31";D5);"")
A+
 

job75

XLDnaute Barbatruc
Re,

Ah mais non, on était à côté de la plaque Modeste.

Il faut utiliser INDIRECT, comme David essayait de le faire, pour vérifier que la feuille existe :
Code:
=SI(ESTREF(INDIRECT("'"&D5&"'!A1"));LIEN_HYPERTEXTE("#'"&D5&"'!J31";D5);"")
A+
 

job75

XLDnaute Barbatruc
Bonjour David, Modeste, le forum,

La fonction SI "pèse" lourd en mémoire, il vaut mieux utiliser REPT :
Code:
=LIEN_HYPERTEXTE("#'"&D5&"'!J31";REPT(D5;ESTREF(INDIRECT("'"&D5&"'!A1"))))
En plus de cette manière les cellules des liens se formatent correctement.

Bonne journée.
 

David Aubert

XLDnaute Barbatruc
Administrateur
Modérateur
Bonjour,

Merci beaucoup Job et Modeste, vous êtes au top, ça marche. :)
J'avais déjà passé un bon moment sur le sujet à tourner en rond et je suis sûr que je n'aurais jamais trouvé cette syntaxe!
Je vais pouvoir mettre le fichier à jour aujourd'hui.
Merci encore.

Bonne journée

David
 

Discussions similaires

Statistiques des forums

Discussions
311 725
Messages
2 081 947
Membres
101 849
dernier inscrit
florentMIG