Fonction =INDEX

GuillaumA

XLDnaute Occasionnel
Bonjour, j'ai un petit trou de mémoire, pouvez-vous m'aider ?

En effet je veux faire une liste réduite de toute les cellules avec du texte dedans dans une colonne U.

=INDEX('Feuil2'!U$7:U$605;0;0)

Problème, je ne sais plus comment adapter ma formule sachant qu'il faut ne pas prendre en compte toutes les cellules vides de l’intervalle U7:U605....


Cette formule sera utilisé sur 10 cellules à la suite pour afficher au maximum les 10 premières valeurs qu'il trouvera dans l’intervalle U7:U605
(Placé en A1, A2, A3, A4,...,A10)

Merci de votre considération,
Guillaume

EDIT: j'ai même essayé:
=INDEX(SI('Action plan'!U$7:U$605<>"";VRAI;FAUX);0;0)
 

job75

XLDnaute Barbatruc
Re : Fonction =INDEX

Bonjour,

Gros trou de mémoire plutôt.

Formule matricielle en A1 :

Code:
=SI(LIGNES(A$1:A1)>NBVAL(Feuil2!U$7:U$605);"";INDEX(Feuil2!U:U;PETITE.VALEUR(SI(Feuil2!U$7:U$605<>"";LIGNE(Feuil2!U$7:U$605));LIGNES(A$1:A1))))

A valider par Ctrl+Maj+Entrée et tirer juqu'en A10.

A+
 

job75

XLDnaute Barbatruc
Re : Fonction =INDEX

Re GuillaumA,

Les valeurs #NOMBRE! viennent du fait que les cellules ne sont pas vides mais contiennent le texte "".

Alors s'il n'y a pas de nombres en Feuil2!U:U, utilisez cette formule matricielle :

Code:
=SI(LIGNES(A$1:A1)>NB.SI(Feuil2!U$7:U$605;"?*");"";INDEX(Feuil2!U:U;PETITE.VALEUR(SI(Feuil2!U$7:U$605<>"";LIGNE(Feuil2!U$7:U$605));LIGNES(A$1:A1))))

Et s'il y a aussi des nombres :

Code:
=SI(LIGNES(A$1:A1)>NB.SI(Feuil2!U$7:U$605;"?*")+NB(Feuil2!U$7:U$605);"";INDEX(Feuil2!U:U;PETITE.VALEUR(SI(Feuil2!U$7:U$605<>"";LIGNE(Feuil2!U$7:U$605));LIGNES(A$1:A1))))

A+
 

GuillaumA

XLDnaute Occasionnel
Re : Fonction =INDEX

Re,
MMMM ça marche mais je n'arrive pas a me dégager de #NOMBRE! . La formule considère qu'il y a 10 résultats dans tous les cas, alors qu'il pourrait y en avoir moins. Et dans ce dernier cas, il faudrait que les cellules soit vides (" ").

Guillaume
 

GuillaumA

XLDnaute Occasionnel
Re : Fonction =INDEX

J'ai mon =NBVAL('Feuil2'!U$7:U$605) = 192
Il faudrait certainement préciser =NB.SI('Feuil2'!U$7:U$605;'Feuil2'!U$7:U$605<>"") ou quelque chose du genre.
Encore une fois... Je suis nul en formule Excel c'est dingue.... Je pense que je n'ai aucune fibres mathématique.

Allez j'y retourne,
Je vous remercie encore une fois pour votre aide!

Amicalement,
Guillaume
 

GuillaumA

XLDnaute Occasionnel
Re : Fonction =INDEX

J'ai trouvé !
EN fait, les cellules en colonne U sont remplis avec des formules.
DU coup le NBVAL considère les cellules comme remplis et en dénombre 192. Car il y a exactement 192 formules cachées sur l'intervalle U7:U605.
Il faut donc que je vois comment faire pour qu'il ne considère uniquement que les cellule ou les formules cachés sont activées et récupère du texte.

Amicalement,
GuiA

PS: Les formules cachées sont du type: =B7 ...

EDIT: =NBVAL(SI('Feuil2'!U$7:U$605<>"";'Feuil2'!U$7:U$605)) m'affiche 1, j'y suis presque je recherche 3 xD
 
Dernière édition:

GuillaumA

XLDnaute Occasionnel
Re : Fonction =INDEX

Re job,
J'ai compris ce que vous m'aviez écrit en post #9.
En revanche, je n'avait pas vu la deuxième formule qui prend en compte mon problème...
Il n'y a donc pas de problème et je vous remercie de votre patience.

Problème résolu.

Bonne journée à vous et encore milles excuses pour ce débat qui n'aurait pas du avoir lieu.

Guillaume
 

Statistiques des forums

Discussions
311 733
Messages
2 082 011
Membres
101 866
dernier inscrit
XFPRO