Extraire tous les évènements ayant le même nom

[zephoenix]

Bonjour à vous tous,

J'en appelle encore une fois à votre science d'Excel
C'est la suite de mon post précèdent où vous m'aviez grandement aidé !!!

Dans le fichier ci-joint il y a 2 onglets :
=> Le 1er (2004-2011) mentionne tous les matchs depuis 7 années d'un championnat
=> Le 2nd (match) devrait faire apparaître à partir d'un match précis, toutes les fois où ce match a eu lieu ces 7 dernières années.

Ça fonctionne bien, quand je mets la formule
=INDEX('2004-2011'!C$1:C$2660;EQUIV($E$1;'2004-2011'!$C$1:$C$2660;0)+LIGNE()-2)

mais quand je recopie vers le bas, il me mentionne le match juste en dessous.
J'ai trouvé la parade en triant la base par ordre alphabétique mais ça coince quand je cherche un autre match


Bref, j'ai fortement besoin de votre aide

Vous en remerciant par avance de m'aider avec autant de gentillesse et de disponibilité

Bonne nuit ou bonne journée

Christophe

 

[Mytå]

Re : Extraire tous les évènements ayant le même nom

Salut le forum

En B2, formule matricielle à valider par Ctrl + Shift + Enter

=SI(LIGNES($1:1)<=NB.SI('2004-2011'!$C$1:$C$2660;$E$1);INDEX('2004-2011'!A$1:A$2660;GRANDE.VALEUR(SI('2004-2011'!$C$1:$C$2660=$E$1;LIGNE(INDIRECT("1:"&LIGNES('2004-2011'!$C$1:$C$2660))));LIGNES($1:1)));"")

Formule à recopier ensuite vers la droite et vers le bas.

Mytå

 

[hbenalia]

Re : Extraire tous les évènements ayant le même nom

Bonjour à tous,

Presque la même formule que celle de Mytå, toujours matricielle elle extrait les résultats par ordre croissant des années

=SI(LIGNE($A1)<=NB.SI('2004-2011'!$C:$C;$E$1);INDEX('2004-2011'!A:A;PETITE.VALEUR(SI('2004-2011'!$C$1:$C$10000=$E$1;LIGNE($1:$10000));LIGNE($A1)));"")

A valider par CTRL+MAJ+ENTRE et à recopier vers la droite et vers le bas...

Cordialement

 

[zephoenix]

Re : Extraire tous les évènements ayant le même nom

Myta et hbenalia : vous êtes juste géniaux !!!
Merci
Merci
Merci

C'est vraiment parfait

 

[zephoenix]

Re : Extraire tous les évènements ayant le même nom

Dernière question :
Comment je pourrais faire pour automatiser cette extraction su rune liste de match ?
Car quand je supprime les $ qui fixe la cellule de référence, j'obtiens cellule vide.

Merci encore

Christophe

 

[hbenalia]

Re : Extraire tous les évènements ayant le même nom

Bonjour le forum, bonjour Christophe

Une petite transformation sur la formule en remplaçant en G2 les deux expressions Lignes($1:1) par NB.SI($B$2:$B2;$B2) puis en recopiant vers la droite et vers le bas tous les résultats seront automatisés...
Le fichier en PJ a été préparé sur la version Office 2003...

Cordialement

 

[zephoenix]

Re : Extraire tous les évènements ayant le même nom

Magnifique !!!

Merci beaucoup du temps consacré à ma demande
Vous êtes bluffant !!!
Bonne nuit