extraire des données d'une colonne selon deux critères

DCN

XLDnaute Nouveau
bonjour,

j'ai parcouru le forum sans résultat, je souhaite pourtant effectuer une formule à mon avis simple. J'ai essayé avec une recherche verticale et une recherche horizontale, mais rien à faire je n'y arrive pas!!!

explication :
Je souhaite extraire dans un autre tableau les renseignements de la colonne 1 à chaque fois qu'il y a un «*R*» dans la colonne correspondant à la date d'aujourdhui
Je joins un piece jointe pour plus de compréhension

Je remercie les personnes qui voudront bien m'aider. Si possible avec une ou des formules car je ne maitrise pas le VBA. (hum! les formules ça va à peu près, et pourtant....).

merci à vous
cordialement
JMD
 

Pièces jointes

  • aide pour jm.xls
    9.5 KB · Affichages: 52

R@chid

XLDnaute Barbatruc
Re : extraire des données d'une colonne selon deux critères

Bonsoir,

Attention aux dates, en A4=07/01/2013 et en C6=07/10/2013
Il faut corriger pour obtenir le résultat décris sur le fichier

En B22,
Code:
=SIERREUR(INDEX(A$7:A$17;PETITE.VALEUR(SI((B$7:E$17=B$21)*(B$6:E$6=A$4);LIGNE(INDIRECT("1:"&LIGNES(A$7:A$17))));LIGNES($22:22)));"")
@ valider par Ctrl+Maj+Entree
@ tirer vers le bas
@ + +
 

DCN

XLDnaute Nouveau
Re : extraire des données d'une colonne selon deux critères

bjr,
merci pour votre aide, effectivement j'ai une petite erreur dans la date.
je ne pensais pas qu'il fallait une formule aussi compliqué!
j'ai essayé, mais sa m'inscrit #valeur!
 

job75

XLDnaute Barbatruc
Re : extraire des données d'une colonne selon deux critères

Bonjour DCN, salut R@chid,

La formule de R@chid convient bien mais elle travaille sur une matrice à 2 dimensions.

De ce fait l'exécution prendra du temps sur un grand tableau avec de nombreuses colonnes.

En travaillant sur un vecteur c'est plus rapide.

Sur Excel 2003, en laissant les valeurs d'erreur :

Code:
=INDEX(A:A;PETITE.VALEUR(SI(DECALER(A$7:A$17;;EQUIV(A$4;$6:$6;0)-1)=B$21;LIGNE(A$7:A$17));LIGNES($22:22)))
Sur Excel 2007/2010 en évitant les valeurs d'erreur :

Code:
=SIERREUR(INDEX(A:A;PETITE.VALEUR(SI(DECALER(A$7:A$17;;EQUIV(A$4;$6:$6;0)-1)=B$21;LIGNE(A$7:A$17));LIGNES($22:22)));"")
Validation matricielle bien sûr dans les deux cas.

Fichier sur Excel 2003 joint.

A+
 

Pièces jointes

  • aide pour jm(1).xls
    25 KB · Affichages: 45
Dernière édition:

DCN

XLDnaute Nouveau
Re : extraire des données d'une colonne selon deux critères

Merci à vous deux pour votre aide.
Effectivement mon tableau possède de nombreuses colonnes. Avec la formule index çà fonctionne mieux.
j'ai plus qu'à mettre en application
encore merci.
cordialement
 

Discussions similaires