XL 2016 Exclure les dates selon l'heure

Heodrene

XLDnaute Occasionnel
Supporter XLD
Bonjour,

Suite à un précédent poste où votre aide m'a été précieuse, j'ai une autre demande un peu exotique ;)
J'ai un fichier Excel avec deux feuillets :
- Un feuillet avec un annuaire de site (code site, ville et différentes dates de mises en service) ;
- Un feuillet Planning.

Les dates de mises en service se caractérisent de la manière suivante :
- Confirmées : jj/mm/aaaa hh:mm ;
- Estimatives : jj/mm/aaaa 00:00

Je souhaite exclure du planning tous les sites ayant une date estimative.

J'ai essayé de jouer avec la fonction DROITE mais je pense m'y prendre comme un manche...

Merci de votre aide,

Jacques
 

Pièces jointes

  • Heodrene-Agenda-Test-2.0.xlsx
    248.9 KB · Affichages: 26
Solution
Bonjour le Forum,
Bonjour Heodrene, Nairolf,

Pour le Fun et pour alléger la formule cette partie

ET(HEURE([@[Date Service Final]])=0;MINUTE([@[Date Service Final]])=0)

peut être remplacer par

MOD([@[Date Service Final]];1)=0

et celle -ci

ET(HEURE([@[Date Service Initial]])=0;MINUTE([@[Date Service Initial]])=0)

par

MOD([@[Date Service Initial]];1)=0

cordialement

Nairolf

XLDnaute Accro
Et dans la formule de la colonne "rang planning":
Code:
=SI(OU(ET(HEURE([@[Date Service Initial]])=0;MINUTE([@[Date Service Initial]])=0);[@[Date Service Initial]]="");"";MAX(Tableau46[@[Date Service Initial]:[Date Service Final]])+LIGNE()/10000000)
 

Nairolf

XLDnaute Accro
N'importe où sur la ligne à tester dans le dashboard.
Cette formule permet uniquement d'indiquer (après rapatriement des dates dans le dashboard) si les dates sont estimatives ou réelles.

Je pense que la seconde formule envoyée répond plus précisément à ton besoin.
 

Heodrene

XLDnaute Occasionnel
Supporter XLD
Je pense que la seconde formule envoyée répond plus précisément à ton besoin.

Oui tout à fait, d'ailleurs je l'ai modifié comme suit et elle fait exactement ce que je souhaite :

Code:
=SI([@[Date Service Initial]]="";"";SI([@[Date Service Final]]<>"";SI(ET(HEURE([@[Date Service Final]])=0;MINUTE([@[Date Service Final]])=0);"";MAX(Tableau46[@[Date Service Initial]:[Date Service Final]])+LIGNE()/10000000);SI(ET(HEURE([@[Date Service Initial]])=0;MINUTE([@[Date Service Initial]])=0);"";MAX(Tableau46[@[Date Service Initial]:[Date Service Final]])+LIGNE()/10000000)))

Merci encore Nairolf, sujet résolu :)
 

Jocelyn

XLDnaute Barbatruc
Bonjour le Forum,
Bonjour Heodrene, Nairolf,

Pour le Fun et pour alléger la formule cette partie

ET(HEURE([@[Date Service Final]])=0;MINUTE([@[Date Service Final]])=0)

peut être remplacer par

MOD([@[Date Service Final]];1)=0

et celle -ci

ET(HEURE([@[Date Service Initial]])=0;MINUTE([@[Date Service Initial]])=0)

par

MOD([@[Date Service Initial]];1)=0

cordialement
 

Statistiques des forums

Discussions
311 721
Messages
2 081 929
Membres
101 843
dernier inscrit
Thaly