EXCEL 2003 > fonction ajouter jours ouvrés et tenir compte liste de jours fériés

[rems]

Bonsoir,

Sauriez-vous comment "traduire" la fonction SERIE.JOUR.OUVRE.INTL() qui ne semble pas fonctionner sous EXCEL 2003 ... ?

En effet, je cherche à ajouter à une date 5 jours ouvrés (2 jours weekend) en tenant compte par ailleurs d'une liste de jours fériés (cellules S2 à S53).
SERIE.JOUR.OUVRE.INTL(V10;5;2;Base!$S$2:$S$53)

Merci d'avance pour votre aide.
Bonne soirée.

 

[Regueiro]

Re : EXCEL 2003 > fonction ajouter jours ouvrés et tenir compte liste de jours fériés

Bonsoir
Je crois que sur Excel 2003 tu dois activer : Utilitaires d'analyse = Analysis ToolPak
Autrement une formule matricielle :

=PETITE.VALEUR(SI((JOURSEM(B77+LIGNE($1:$50);2)={1\2\3\4\5})*(NB.SI(FER;B77+LIGNE($1:$50))=0);B77+LIGNE($1:$50));C77)

Valider avec Maj+Ctrl+entrée




A+

 

[job75]

Re : EXCEL 2003 > fonction ajouter jours ouvrés et tenir compte liste de jours fériés

Bonsoir rems, Regueiro,

Avec la date en A1, formule matricielle à valider par Ctrl+Maj+Entrée :

=A1+EQUIV(PETITE.VALEUR(SI((JOURSEM(A1+LIGNE($1:$12);2)<6)*NON(NB.SI(Base!$S$2:$S$53;A1+LIGNE($1:$12)));A1+LIGNE($1:$12));5);SI((JOURSEM(A1+LIGNE($1:$12);2)<6)*NON(NB.SI(Base!$S$2:$S$53;A1+LIGNE($1:$12)));A1+LIGNE($1:$12));0)

La formule de Regueiro, que je n'ai pas testée, est plus simple.

A+

 

[Staple1600]

Re : EXCEL 2003 > fonction ajouter jours ouvrés et tenir compte liste de jours fériés

Bonsoir à tous

Bonsoir
Je crois que sur Excel 2003 tu dois activer : Utilitaires d'analyse = Analysis ToolPak

Sauf erreur de ma part, cette fonction n'est disponible qu'à partir d'Excel 2010
SERIE.JOUR.OUVRE.INTL, fonction - Excel - Office.com

 

[job75]

Re : EXCEL 2003 > fonction ajouter jours ouvrés et tenir compte liste de jours fériés

Bonjour le fil,

Je viens de regarder la formule de Regueiro du post #2.

Et en effet je vois que j'ai été chercher midi à 14 heures.

Il suffit d'écrire, toujours en matriciel :

=PETITE.VALEUR(SI((JOURSEM(A1+LIGNE($1:$12);2)<6)*NON(NB.SI(Base!$S$2:$S$53;A1+LIGNE($1:$12)));A1+LIGNE($1:$12));5)

A+

 

[rems]

Re : EXCEL 2003 > fonction ajouter jours ouvrés et tenir compte liste de jours fériés

Bonjour le fil,

Je viens de regarder la formule de Regueiro du post #2.

Et en effet je vois que j'ai été chercher midi à 14 heures.

Il suffit d'écrire, toujours en matriciel :

=PETITE.VALEUR(SI((JOURSEM(A1+LIGNE($1:$12);2)<6)*NON(NB.SI(Base!$S$2:$S$53;A1+LIGNE($1:$12)));A1+LIGNE($1:$12));5)

A+

Bonjour et merci pour votre aide.
Désolé de poser la question (je suis vraiment novice ...), mais je ne comprends pas le "LIGNE($1;$12)" : à quoi cela correspond-il ?
Merci encore,

 

[job75]

Re : EXCEL 2003 > fonction ajouter jours ouvrés et tenir compte liste de jours fériés

Re,

LIGNE($1:$12) car 5 (jours ouvrés) + 4 (2 week-ends) + 3 (jours fériés).

En effet, en France, il ne peut pas y avoir plus de 3 jours fériés sur une période de 12 jours.

On pourrait mettre LIGNE($1:$50) mais c'est inutile avec un décalage de 5 jours ouvrés.

A+

 

[rems]

Re : EXCEL 2003 > fonction ajouter jours ouvrés et tenir compte liste de jours fériés

Re,

LIGNE($1:$12) car 5 (jours ouvrés) + 4 (2 week-ends) + 3 (jours fériés).

En effet, en France, il ne peut pas y avoir plus de 3 jours fériés sur une période de 12 jours.

On pourrait mettre LIGNE($1:$50) mais c'est inutile avec un décalage de 5 jours ouvrés.

A+

Bonsoir,
Merci beaucoup pour l'explication, c'est très clair.
Bonne soirée,
Rems

 

[job75]

Re : EXCEL 2003 > fonction ajouter jours ouvrés et tenir compte liste de jours fériés

Re,

Un petit bémol à cette affaire des 12 jours.

En 2285 et 2353 Pâques tombera le 22 mars (cette fête ne peut pas être plus tôt).

Le jeudi de l'Ascension sera donc le 30 avril.

Si les vendredis 1er mai et 8 mai sont toujours fériés, il y aura 4 jours fériés entre le jeudi de l'Ascension et le lundi de Pentecôte.

Et seulement 4 jours ouvrés sur cette période de 12 jours.

Il faudra donc utiliser LIGNE(1:13)... Mais d'ici là...

A+