Dé doublonnage

[laboriec]

Bonjour à tous,

Après plusieurs minutes passées sur les différents Post... Je me résous à publier ma première question.

J’ai une liste de référence avec parfois des doublons et plusieurs quantités restantes… Je souhaiterai rapidement identifier les lignes ou j’ai les données les plus favorables.

Par exemple, ligne 12 – 13 – 14 : je souhaiterai rapidement identifier la ligne 13 et masquer les deux autres.
Même chose ligne 8 et 9 : Je ne souhaite conserver que la ligne 9.

Pouvez-vous m’aider ?

Merci d'avance

 

[tototiti2008]

Re : Dé doublonnage

Bonjour laboriec,
Bienvenue,

un essai avec formule et filtre

 

[Paf]

Re : Dé doublonnage

bonjour laboriec , tototiti2008

une approche par macro, plus radical: les lignes inutiles sont supprimées:

Sub SupDoublon()
 Dim MonTab, MonDico, MaPlage As Range
 With Worksheets("Feuil1")
 Set MonDico = CreateObject("Scripting.Dictionary")
 Set MaPlage = .Range("A2:B" & .Range("A" & .Rows.Count).End(xlUp).Row)
 MonTab = MaPlage
 For i = LBound(MonTab) To UBound(MonTab)
    If MonDico.exists(MonTab(i, 1)) Then
        If MonTab(i, 2) > MonDico(MonTab(i, 1)) Then MonDico(MonTab(i, 1)) = MonTab(i, 2)
    Else
        MonDico(MonTab(i, 1)) = MonTab(i, 2)
    End If
 Next
 MaPlage.ClearContents
 .[A2].Resize(MonDico.Count, 1) = Application.Transpose(MonDico.keys)
 .[B2].Resize(MonDico.Count, 1) = Application.Transpose(MonDico.items)
 End With
End Sub

A+

 

[laboriec]

Re : Dé doublonnage

Merci beaucoup pour ta réponse rapide @tototiti2008

Par contre... mon fichier ayant plus de 20000 lignes... ça ne fonctionne pas.

Peut-être trop de ligne ?

 

[grisan29]

Re : Dé doublonnage

bonjour laboriec, Paf,tototiti2008 et le forum
peut importe le nombre de lignes que tu as dans ton classeur le code devrait fonctionner car cette ligne le permet

 Set MaPlage = .Range("A2:B" & .Range("A" & .Rows.Count).End(xlUp).Row)

car elle compte a partir du bas

Pascal

 

[laboriec]

Re : Dé doublonnage

Désolé... Mais j'ai tenté plusieurs fois... sans succès.

Merci quand même

Bonne fin de journée

 

[Paf]

Re : Dé doublonnage

re,

Merci beaucoup pour ta réponse rapide @tototiti2008

Par contre... mon fichier ayant plus de 20000 lignes... ça ne fonctionne pas.

Peut-être trop de ligne ?

et ma proposition du post #3 convient-elle ?

A+

 

[grisan29]

Re : Dé doublonnage

bonsoir Paf
j'avais oublier de préciser que c'est de ton code du post #3 dont je faisait allusion

Pascal

 

[klin89]

Re : Dé doublonnage

Bonsoir à tous,

Similaire à Paf :

Option Explicit
Sub test()
Dim a, i As Long, j As Long, n As Long
    Application.ScreenUpdating = False
    With Sheets("Feuil1").Range("a1").CurrentRegion.Columns("a:b")
        a = .Value: n = 1
        With CreateObject("Scripting.Dictionary")
            .CompareMode = 1
            For i = 2 To UBound(a, 1)
                If Not .exists(a(i, 1)) Then
                    n = n + 1
                    .Item(a(i, 1)) = n
                    For j = 1 To UBound(a, 2)
                        a(n, j) = a(i, j)
                    Next
                Else
                    'a(.Item(a(i, 1)), 2) = Application.Max(a(.Item(a(i, 1)), 2), a(i, 2))
                    If a(.Item(a(i, 1)), 2) < a(i, 2) Then
                        a(.Item(a(i, 1)), 2) = a(i, 2)
                    End If
                End If
            Next
        End With
        With .Offset(, .Columns.Count + 2)
            .CurrentRegion.Clear
            .Cells(1).Resize(n, UBound(a, 2)).Value = a
            With .CurrentRegion
                .Font.Name = "calibri"
                .Font.Size = 10
                .HorizontalAlignment = xlCenter
                .VerticalAlignment = xlCenter
                .Borders(xlInsideVertical).Weight = xlThin
                .BorderAround Weight:=xlThin
                With .Rows(1)
                    .Font.Size = 11
                    .Interior.ColorIndex = 38
                    .BorderAround Weight:=xlThin
                End With
                .Columns.AutoFit
            End With
        End With
    End With
    Application.ScreenUpdating = True
End Sub

klin89

 

[laboriec]

Re : Dé doublonnage

Bonjour klin89,

la macro fonctionne parfaitement... seul les valeurs les plus favorables sont conservées.

Merci à tous pour votre aide !

Excellente journée

Christophe

 

[Paf]

Re : Dé doublonnage

Re tous et bonjour klin89,

Bon, tant pis, je ne saurai pas si ma proposition convenait !

Bonne suite