Créer un bas de page dans word via excel

[Imperium]

Bonjour,

Je possède déjà une macro, qui me permet d'ouvrir un nouveau document word et de copier le contenu de cellules dedans.

Seulement, j'aimerai qu'une de ces cellules soit reprise dans le bas de page du document word, et, plus compliqué encore, qu'il ne soit appliqué qu'à la premiere page

Est-ce possible ? Voici mon code actuel !
Merci beaucoup d'avance pour votre aide !

Sub Excel_Word()

Dim oWdApp As Object 'Word.Application
Dim oWdDoc As Object 'Word.Document

'Lancer une instance Word
Set oWdApp = CreateObject("Word.Application")

'Ouvrir un nouveau document
Set oWdDoc = oWdApp.Documents.Add

'Rendre Word visible
oWdApp.Visible = True

'Copier une plage depuis Excel
ActiveSheet.Range("A1:A22").Copy

'Coller la plage dans Word
oWdApp.Selection.Paste

'Annuler le mode couper/copier
Application.CutCopyMode = False

End Sub

 

[Hippolite]

Re : Créer un bas de page dans word via excel

Bonjour,
Utilise l'enregistreur de macro de Word.
Il faudra peut-être activer les références Word dans excel :
à partir de VBE : menu Outils / Références…
cocher Microsoft Office (n°) Object Library
A+

 

[Imperium]

Re : Créer un bas de page dans word via excel

Je suis moins à l'aise avec ça. Il n'existe pas une commande à insérer directement dans mon code ?

 

[Hippolite]

Re : Créer un bas de page dans word via excel

Re,
Je ne suis pas habitué aux macros word.
Regarde éventuellement Débutez en VBA Word
A+

 

[Imperium]

Re : Créer un bas de page dans word via excel

Je n'ai malheureusement pas trouvé ma solution sur ce lien... Quelqu'un saurait-il quelquechose :/

 

[Hippolite]

Re : Créer un bas de page dans word via excel

Bonjour,
Regarde si ça convient :

Public Sub AjoutPiedPage()
'nécessite l'activation de la référence Microsoft Word Object Library
    Dim wdApp As New Word.Application
    Dim wdDoc As Word.Document
    Dim Fichier As String
    'ouverture du fichier Word.doc placé dans le même répertoire que ce classeur excel
    Fichier = ThisWorkbook.Path & "\Word.doc"
    wdApp.Visible = True
    Set wdDoc = wdApp.Documents.Open(Fichier)
    'première page différente
    wdDoc.PageSetup.DifferentFirstPageHeaderFooter = True
    'ouverture du pied de page
    With wdDoc.ActiveWindow.View
        .Type = wdPrintView
        .SeekView = wdSeekFirstPageFooter
    End With
    'insertion du texte de pied de page
    wdDoc.ActiveWindow.Selection.TypeText _
            Text:=ThisWorkbook.Sheets("Feuil1").Range("A1").Value
    'quitter l'affichage en-tête/pied de page
    '(utile uniquement si autres actions à mener sur le document)
    wdDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    'fermeture du fichier word
    wdDoc.Close SaveChanges:=True    'ferme et enregistre le doc word
    wdApp.Quit    'fermeture de word
    Set wdDoc = Nothing    'vide la variable
    Set wdApp = Nothing    'vide la variable
End Sub

A+