Créer des fichiers à partir d'une liste de données

[battijo]

Bonjour,

j'ai été déconnecté un moment du milieu excel et je dois dire qu'un peu plus d'un an sans toucher au VBA j'ai l'impression de ne l'avoir jamais pratiqué.

j'ai essayé par mes propres moyens mais sans succès alors je reviens vers ce forum où je passais des heures il y a pas si longtemps (je ne retrouvais même plus mes codes).

Mon problème (professionnel) est le suivant :
- à partir d'une liste de noms je voudais créer des fichiers excel individuels à ces mêmes noms.
En détail, j'ai un fichier execl où se trouve la liste des noms et un fichier "modèle" à incrémenter et à nommer. (ci joint comme doc de travail)

je pense qu'il faut une boucle, pour l'enregistrement des fichiers je coince... en bref c'est le point mort au démarrage.

en espérant avoir été assez clair

Fichier 1 : liste des bénéficiaires
Fichier 2 : "modèle" à créer pour chaque individu et à enregistrer à son nom

Dors et déja merci !

 

[Efgé]

Re : Créer des fichiers à partir d'une liste de données

Bonjour battijo et (re) bienvenu sur le forum
Une proposition
Le code est à mettre dans le classeur Liste.
Le modèle doit être dans le même répertoire que Liste.
Les fichiers seront crées dans le même répertoire.

Sub test()
Dim I&, Wkb As Workbook, Benef$
Application.ScreenUpdating = False
Application.DisplayAlerts = False
Workbooks.Open Filename:=ThisWorkbook.Path & "\Modèle.xlsx"
Set Wkb = ActiveWorkbook
With ThisWorkbook.Sheets("Feuil1")
    For I = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
        Benef = .Cells(I, 1).Value
        Wkb.Sheets(1).Range("$B$2").Value = Benef
        Wkb.SaveAs ThisWorkbook.Path & "\" & Benef & ".xlsx"
    Next I
End With
Wkb.Close False
Application.DisplayAlerts = True
Application.ScreenUpdating = True
End Sub

Cordialement

 

[battijo]

Re : Créer des fichiers à partir d'une liste de données

Bonjour

quelle rapidité et ça marche nickel.

Je dois dire que je n'ai pas tout saisi dans le code mais je vais m'y atteler. Je l'ai déja adapté à un autre fichier.

Un grand bravo et un tres grand merci !