XL 2013 Copier un feuille avec les valeurs dans un autre classeur

[These38]

Bonjour
Voilà j'ai créer un bouton pour que quand une personne clique dessus çà enregistre la feuille dans un nouveau fichier avec la date dans le nom du fichier. Jusque là tout va bien. Mon seul problème c'est que ça copie aussi les formules au lieu des valeurs. Je suis pas un expert en vba j'ai un peu rechercher mais je ne trouve pas ou alors ne comprend pas la methode.

Sub Wks2Wbk()
Dim NWBK As Workbook
Sheets("Fax").Copy: Set NWBK = ActiveWorkbook
NWBK.SaveAS "c:\temp\" & "Fax du " & Format(Now - 1, "dd-mm-yyyy") & ".xlsx", FileFormat:=51: NWBK.Close False
End Sub

Si quelqu'un pouvait m'aider merci d'avance
Cordialement

 

[Staple1600]

Bonjour

Je suis tout ému de relire mon bout de code de 2015

https://www.excel-downloads.com/thr...m-specifique-sous-vba.20001558/#post-20012917

 

[These38]

Bonjour
Oui merci à toi en cherchant j'ai trouver ça et ça marche bien a part pour la partie valeur à la place des formules

 

[Staple1600]

Re

Alors pour le valeurs seules, j'ai aussi cela en magasin
(Mais là nous étions en 2014)

Sub cvalseul()
With ActiveSheet
    .UsedRange.Value = .UsedRange.Value
End With
End Sub

 

[Staple1600]

Re

Donc en mixant les deux, on peut obtenir un truc du genre

Sub Wks2Wbk_VS()
Dim NWBK As Workbook
Sheets("Fax").Copy: Set NWBK = ActiveWorkbook
With NWBK.Sheets(1)
.UsedRange.Value = .UsedRange.Value
End With
NWBK.SaveAs "c:\temp\" & "Fax du " & Format(Now - 1, "dd-mm-yyyy") & ".xlsx", FileFormat:=51: NWBK.Close False
End Sub

Je te laisse tester sur ton PC.

 

[These38]

Merci c'est nickel me reste plus qu'a chercher comment copier un module vba automatiquement vers le nouveau classeur . Je vais faire mes petites recherche

 

[Staple1600]

Re

Si tu veux copier un module, il faut enregistrer la copie en *.xlsm et non pas en *.xlsx

 

[These38]

Merci pour tout j'ai modifier 2 ou 3 truc tout marche à 100%

 

[Staple1600]

Re

Tout marche à 100%

Rien ne t’empêche alors de poster tes modifications pour en faire profiter la communauté.

 

[These38]

Voila 2 version que j'ai faite pour 2 feuille differente
Sur le premier je copie juste les valeurs, sauvegarde le fichier et imprime

Sub Wks2Wbk()
Dim NWBK As Workbook
Sheets("FAX").Unprotect ("Password01")
Sheets("FAX").Copy: Set NWBK = ActiveWorkbook
With NWBK.Sheets(1)
    .UsedRange.Value = .UsedRange.Value
End With
NWBK.SaveAs "c:\Fax minuit\" & "Fax du " & Format(Now - 1, "dd-mm-yyyy") & ".xlsm", FileFormat:=52: NWBK.Close False
Application.ActivePrinter = "**** sur Ne03:"
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, _
        IgnorePrintAreas:=False
Sheets("FAX").Protect ("Password01")
End Sub

Sur le deuxième je copie les formules du coup je suis obliger de copier le module1 en même temps car c'est la ou il y a la fonction pour les calculs

Sub Wks3Wbk()
Dim NWBK As Workbook
Dim NewM As Object, NewCode As String
With ThisWorkbook.VBProject.VBComponents("Module1").CodeModule
    NewCode = .Lines(1, .CountOfLines)
End With
Sheets("reception FOS").Unprotect ("Password01")
Sheets("reception FOS").Copy: Set NWBK = ActiveWorkbook
Set NewM = ActiveWorkbook.VBProject.VBComponents.Add(1)
With ActiveWorkbook.VBProject.VBComponents(NewM.Name).CodeModule
    .AddFromString NewCode
End With
NWBK.SaveAs "c:\\Reception\" & A4 & B4 & " du " & Format(Now - 1, "dd-mm-yyyy") & ".xlsm", FileFormat:=52: NWBK.Close False
Application.ActivePrinter = "***** sur Ne03:"
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, _
        IgnorePrintAreas:=False
Sheets("reception FOS").Protect ("Password01")
End Sub

 

[Staple1600]

Re

Merci pour ton retour