Copier un commentaire dans une cellule

[BLACKHAYES]

bonsoir,

Dans excel quand on rentre une valeur dans une cellule et qu'elle existe deja dans la colonne excel vous copie d'office la valeur a vous de valider ou demodifier cette valeur et elle disparait, ca c'est tres bien c'est bien rapide pour eviter de recopier les meme chose, maismoi je voudrais non seulement copier la valeur de la cellulemais aussi le commentaire inserer, juste en validant par "Entrée".

est ce possible

autrement dit est ce possible de copier une cellule avec son commentaire juste en frappant le debut de la valeur et une fois qu'elle apparait , clic entrée, et hop c'est fait

merci d'avance,

 

[ERIC S]

Re : Copier un commentaire dans une cellule

Bonjour

on peut le faire par vba, mais pourquoi recopier un commentaire ? en général on le met sur un intitulé de colonne, comme le commentaire s'affiche quand on arrive sur la cellule, cela devient vite désagréable

par curiosité, si tu peux mettre un exemple, je regarderai pour la macro

 

[BLACKHAYES]

Re : Copier un commentaire dans une cellule

Bonjour

on peut le faire par vba, mais pourquoi recopier un commentaire ? en général on le met sur un intitulé de colonne, comme le commentaire s'affiche quand on arrive sur la cellule, cela devient vite désagréable

par curiosité, si tu peux mettre un exemple, je regarderai pour la macro

Bonjour,

oui je sais, que lecommentaire s'applique generalement qu'a une cellule, mais dans mon travail on recopie souvent une meme valeur dans plusieurs cellules de la meme colonne et on doit lui associé a chaque fois le commentaire;

Voila pourquoi,

je joint un exemple ou la Cell I7 doit etre recopier plusieurs fois, alors evidemment on peut faire un copier coller de la cellule a la souris, mais ca fais des manip, alors que si, quand excel detecte le doublons on a juste a faire "Entrée" pour validé le doublons et son commentaire.

suis-je clair ???? !!

cordialement,

 

[job75]

Re : Copier un commentaire dans une cellule

Bonjour,

On peut utiliser cette macro, dans le code de la feuille :

Private Sub Worksheet_Change(ByVal Target As Range)
Set Target = Intersect(Target, [I:I])
If Target Is Nothing Then Exit Sub
On Error Resume Next 'si pas de commentaire ou si Target = ""
For Each Target In Target 'pour le cas d'entrées multiples
  Target.AddComment Cells(Application.Match(Target, [I:I], 0), "I").Comment.Text
Next
End Sub

Fichier joint.

A+

 

[job75]

Re : Copier un commentaire dans une cellule

Re,

Une autre solution :

Private Sub Worksheet_Change(ByVal Target As Range)
Set Target = Intersect(Target, [I:I])
If Target Is Nothing Then Exit Sub
Application.EnableEvents = False
On Error Resume Next 'si Target = ""
For Each Target In Target 'pour le cas d'entrées multiples
  Cells(Application.Match(Target, [I:I], 0), "I").Copy Target
Next
Application.EnableEvents = True
End Sub

Avantage : le commentaire est copié avec sa mise en forme.

Fichier (2).

A+

 

[BLACKHAYES]

Re : Copier un commentaire dans une cellule

Merci c'est exactement ce que je cherchais;

je vous remercie grandement, c'est top;

a bientot

 

[BLACKHAYES]

Re : Copier un commentaire dans une cellule

Bonjour le forum,
Encore une petite aide pour mon tableur,
Qui peut modifier le dernier code pour prendre en compte non pas 1 colonne mais plusieurs colonne, si possible les colonnes de "A à AA", ou moins si pas possible autant; car la colonne "I" etait pour exemple

Merci d'avance,

 

[job75]

Re : Copier un commentaire dans une cellule

Bonjour BLACKHAYES,

Les colonnes A à AA ? Autant prendre toute la feuille :

Private Sub Worksheet_Change(ByVal Target As Range)
Set Target = Intersect(Target, Me.UsedRange)
If Target Is Nothing Then Exit Sub
Application.EnableEvents = False
On Error Resume Next 'si Target = ""
For Each Target In Target 'pour le cas d'entrées multiples
  Cells(Application.Match(Target, Target.EntireColumn, 0), Target.Column).Copy Target
Next
Application.EnableEvents = True
End Sub

A+

 

[BLACKHAYES]

Re : Copier un commentaire dans une cellule

oui bien sur si c'est possible, je ne voulais pas etre trop gourmand c'est tout (Sourires)

 

[BLACKHAYES]

Re : Copier un commentaire dans une cellule

Bon et bien c'etait pas plus dur que ca, pffffff, le malin Rires, non serieusement heureusement quevous etes la, vraiment un grand mercia vous tous qui me repondez ultra rapidement, c'est cool

encore merci
a bientot