Copier le contenu d'une ligne x fois selon x

[bjou]

Bonjour à tous,

je n'arrive pas à trouver comment faire ceci:

dans une ligne de U4 à AF4 j'ai des caractéristiques de palettes avec en AF4 le nombre de palette
dans une ligne de U5 à AF5 j'ai des caractéristiques de palettes avec en AF5 le nombre de palette (cette ligne est totalement différente la premiere)

J'aimerai copier le contenu de la ligne 4 de U4 à AE4 dans la colonne B ligne 4 x fois selon le nombre contenu dans la cellule AF4.
la meme chose à la suite pour le contenue de la ligne 5 de U5 à AE5

Ex.:
U4: ARTicle 1 / V4: cd4512 / W4: of1236 / X4: produitA / Y4: 120 / etc... AF4: 5
U5: ARTicle 2 / V5: cd7302 / W4: of17896 / X4: produitZ / Y4: 450 / etc... AF4: 2

On a :

B4: ARTicle 1 / C4: cd4512 / D4: of1236 / E4: produitA / F4: 120 / etc...
B5: ARTicle 1 / C5: cd4512 / D5: of1236 / E5: produitA / F5: 120 / etc...
B6: ARTicle 1 / C6: cd4512 / D6: of1236 / E6: produitA / F6: 120 / etc...
B7: ARTicle 1 / C7: cd4512 / D7: of1236 / E7: produitA / F7: 120 / etc...
B8: ARTicle 1 / C8: cd4512 / D8: of1236 / E8: produitA / F8: 120 / etc...
B9: ARTicle 2 / C9: cd7302 / D9: of17896 / E9: produitZ / F9: 450 / etc...
B10: ARTicle 2 / C10: cd7302 / D10: of17896 / E10: produitZ / F10: 450 / etc...

J'espère avoir été assez clair....


Merci d'avance

Voici une pièce jointe

 

[camarchepas]

Re : Copier le contenu d'une ligne x fois selon x

Bonjour ,

En appuyant sur le sourire

Sub copie()
Dim Données As Variant
Dim LigneFin As Long, Tourne As Long
Dim Nombre As Long, Ligne As Long, Cible As Long
LigneFin = Range("N" & Rows.Count).End(xlUp).Row
Cible = 3
For Tourne = 3 To LigneFin
 Nombre = Range("Y" & Tourne)
 For Ligne = 1 To Nombre
 Range("A" & Cible) = Cible - 2
 Range("B" & Cible & ":L" & Cible) = Range("N" & Tourne & ":X" & Tourne).Value
 Cible = Cible + 1
 Next
Next Tourne

End Sub

 

[Staple1600]

Re : Copier le contenu d'une ligne x fois selon x

Bonjour à tous

bjou [Bienvenue sur le forum]

Un début de piste avant tout illustratif
(pour tester: des données en colonnes A,B,C et en colonne D le nombre de fois à recopier)

Sub a()
Dim rng As Range, r As Range, n%
Set rng = Range(Cells(1, 1), Cells(Rows.Count, 3).End(3))
For Each r In rng.Rows
For n = 1 To Cells(r.Row, 4).Value
r.Copy Cells(Rows.Count, "E").End(3)(2)
Next
Next
End Sub

Je te laisse faire les adaptations nécessaires pour coller à ta problématique

EDITIONI: Houps pas rafraichi! Bonjour camarchepas
Bon bah bjou, plus la peine de faire des adaptations

EDITIONII: Bonjour ROGER2327
Alors là, bjou tu peux carrément zapper mon message et ne retenir que les propositions de camarchepas ou ROGER2327

 

[ROGER2327]

Re : Copier le contenu d'une ligne x fois selon x

Bonjour à tous.

Un autre petit code simple :​

Sub toto()
Dim i&, l&, m&, Cel As Range
  With Application: .ScreenUpdating = 0: .EnableEvents = 0: .Calculation = -4135: End With
  Set Cel = [A3]
  With [Y3]
    Do While Not IsEmpty(.Offset(l, -11).Value)
      If IsNumeric(.Offset(l).Value) Then
        For i = 1 To .Offset(l).Value
          .Offset(l, -11).Resize(1, 11).Copy Destination:=Cel.Offset(m, 1)
          Cel.Offset(m) = m + 1
          m = m + 1
        Next
      End If
      l = l + 1
    Loop
  End With
  l = m
  Do Until IsEmpty(Cel.Offset(m)): m = m + 1: Loop
  If m <> l Then Cel.Offset(l).Resize(m - l, 12).ClearContents
  With Application: .Calculation = -4105: .EnableEvents = 1: .ScreenUpdating = 1: End With
End Sub

Bonne journée.


ℝOGER2327
#7633

Mardi 17 Haha 142 (Saint Homais d’Aquin, prudhomme - fête Suprême Quarte)
1[SUP]er[/SUP] Brumaire An CCXXIII, 5,9299h - pomme
2014-W43-3T14:13:55Z

 

[bjou]

Re : Copier le contenu d'une ligne x fois selon x

Merci, vraiment merci à vous déjà pour votre participation... et vos réponses....


Vraiment génial cela correspond exactement au besoin.... je donnerais un petit plus à camarchepas en effet, son code proposer de numéroter les palettes en même temps chose que je n'avais pas demandé mais qu'il a su deviner....


merci à tous bonne journéee