Autres copier coller colonne sans vide step3

[st007]

Pour excel 2007
Bonjour,
Le but est de copier de la feuille 1 vers la 2
On copie par bloc (A1,C1) (A2,C2) ...... (P9,R9)
Sans tenir compte des vides exemple (M3,O3)
il est à considérer qu'il n'y a jamais de vide par bloc, le nombre de lignes et de colonne varient de 10 à 200

J'essaye de boucler, et si je suis ici, c'est que je n'y arrive pas évidement, merci d'avance de m'éclairer

 

[job75]

Bonsoir st007,

Voyez le fichier joint et cette macro dans le code de Feuil2 :

Private Sub Worksheet_Activate()
Dim ncol%, tablo, nlig&, resu(), j%, i&, x, y, z, n&
With Feuil1.UsedRange
    ncol = Application.Ceiling(.Columns.Count, 3) 'PLAFOND
    tablo = .Resize(, ncol) 'matrice, plus rapide
    nlig = .Rows.Count
End With
ReDim resu(1 To nlig * ncol / 3, 1 To 3)
For j = 1 To ncol Step 3
    For i = 2 To nlig
        x = tablo(i, j): y = tablo(i, j + 1): z = tablo(i, j + 2)
        If x <> "" Or y <> "" Or z <> "" Then
            n = n + 1
            resu(n, 1) = x: resu(n, 2) = y: resu(n, 3) = z
        End If
Next i, j
'---restitution---
If FilterMode Then ShowAllData 'si la feuille est filtrée
With [A2] '1ère cellule de destination, à adapter
    If n Then .Resize(n, 3) = resu
    .Offset(n).Resize(Rows.Count - n - .Row + 1, 3).ClearContents 'RAZ en dessous
End With
End Sub

Elle se déclenche quand on active la feuille.

Elle est très rapide car elle utilise des tableaux VBA.

A+

 

[st007]

merci merci merci

 

[st007]

Bonjour,
la macro du célèbre Job75 fonctionne parfaitement, et encore merci,
Cependant, serait-il possible de faire la même chose via power query ?

 

[Hasco]

Bonsoir,

@st007 vous trouverez dans le fichier joint, une requête et son tableau en feuille 2.
Vos données de la feuil1 ont été transformées en tableau structuré pour Power Query.
Si un tableau structuré ne convient pas, on peut simplement nommer une zone.

Si l'étape Pile de la requête vous semble compliquée, j'essaierai de la décomposer demain.

Cordialement

 

[Hasco]

Re,

Et bien j'ai eu le temps de le faire. Voici un fichier avec les deux versions power query.
La version déployée se nomme 'RQ_Datas (2)'

Cordialement

 

[st007]

Grand merci Hasco, je vais essayer de comprendre et surtout savoir pourquoi je n'y arrivais pas . Bonne journée