Copie valeur Textbox dnas feuilles excel spécifiée

[erileo]

Bonjour,
A tous, meilleurs vœux pour cette nouvelle année, qu'elle vous apporte joie, bonheur, réussite et prospérité.

Je construit un fichier Excel comprenant plusieurs feuilles et plusieurs UserForms. Aucune feuille n'est accessible, mis à part la feuille de lancement des userforms. Ces userforms contiennent des textboxs que je veux sauvegarder sur différentes feuilles afin de créer une base archive servant à de futures recherches.
J'ai écrit une macro qui est :

Private Sub CommandButton2_Click() 'Sauvergarde données Textboxs de Us1 dans Feuille Feuil11 BaseFormeUs1
Dim PremLigVid As Long 'déclare variable
With Feuil11 'valeur dans Feuil11
PremLigVid = Range("A" & Rows.Count).End(xlUp).Row + 1 'Cherche ligne vide
Range("A" & PremLigVid).Value = TextBox1
Range("B" & PremLigVid).Value = TextBox2
Range("C" & PremLigVid).Value = TextBox3
Range("D" & PremLigVid).Value = TextBox4
Range("E" & PremLigVid).Value = TextBox5
Range("F" & PremLigVid).Value = TextBox6
Range("G" & PremLigVid).Value = TextBox7
Range("H" & PremLigVid).Value = TextBox8
Range("I" & PremLigVid).Value = TextBox9
Range("J" & PremLigVid).Value = TextBox10
End With
End Sub

Le problème est le suivant : lorsque je remplis mes textbox et que je valide avec mon bouton, les valeurs vont se sauvegardées sur n'importe quelle feuille active au moment du click et non sur la "feuil11" comme demandé. Avez-vous une solution pour mettre les valeurs dans les bonnes feuilles ?

Cordialement,

Erileo

 

[phlaurent55]

Re : Copie valeur Textbox dnas feuilles excel spécifiée

bonjour erileo, et bienvenue sur le forum

Sans ouvrir le fichier, je suppose que tu as oublié les (.) devant chaque "Range"

Private Sub CommandButton2_Click() 'Sauvergarde données Textboxs de Us1 dans Feuille Feuil11 BaseFormeUs1
    Dim PremLigVid As Long 'déclare variable
        With Feuil11 'valeur dans Feuil11
            PremLigVid = .Range("A" & Rows.Count).End(xlUp).Row + 1 'Cherche ligne vide
                .Range("A" & PremLigVid).Value = TextBox1
                .Range("B" & PremLigVid).Value = TextBox2
                .Range("C" & PremLigVid).Value = TextBox3
                .Range("D" & PremLigVid).Value = TextBox4
                .Range("E" & PremLigVid).Value = TextBox5
                .Range("F" & PremLigVid).Value = TextBox6
                .Range("G" & PremLigVid).Value = TextBox7
                .Range("H" & PremLigVid).Value = TextBox8
                .Range("I" & PremLigVid).Value = TextBox9
                .Range("J" & PremLigVid).Value = TextBox10
        End With
End Sub

à+
Philippe

 

[erileo]

Re : Copie valeur Textbox dnas feuilles excel spécifiée

Bonjour phlaurent55,

Merci pour ta réponse rapide. Je viens de rajouter les points devant "range". Les valeurs textbox se placent bien dans la feuille "Feuil11" mais à chaque clic avec des données différentes, les données les plus récentes écrasent les plus anciennes au lieu de s'incrémenter à la suite. Sans les points devant "range", j'ai bien les données qui se rajoutent à la dernière ligne vide. QUID?

@+ Eric

 

[Si...]

Re : Copie valeur Textbox dnas feuilles excel spécifiée

salut

tu as dû oublier le premier

PremLigVid = .Range("A" & Rows.Count).End(xlUp).Row + 1

Un autre code moins plus condensé et qui permet de vider les textes après leur copie

Private Sub CommandButton2_Click()
  Dim L As Long, n As Byte
  With Feuil11 'si l'appel de l'ouverture se fait ailleurs que dans cet onglet 
    L = .Range("A" & Rows.Count).End(xlUp).Row + 1
    For n = 1 To 10
      .Cells(L, n) = Me("TextBox" & n)
      Me("TextBox" & n) = ""  'raz
    Next
  End With
End Sub

 

[erileo]

Re : Copie valeur Textbox dnas feuilles excel spécifiée

Super, j'avais bien oublié ce point. Maintenant ça roule. Ce soir je teste ton autre macro et je te donnes mes commentaires. Merci.
@+

 

[erileo]

Re : Copie valeur Textbox dnas feuilles excel spécifiée

Merci pour votre aide.
Le code condensé proposé marche super bien. J'ai supprimé la fonction "RAZ" pour le moment car elle ne m'ai d'aucune utilité. Mais je la mets de côté pour d'autres codes que je dois créer sur mon applicatif.
@+