Compter une seule fois une présence multiple sur les mêmes jours du mois

quiproko

XLDnaute Nouveau
Bonjour,

Je reviens vers vous pour finaliser mon tableau qui a bien avancé grâce à vous.

J'ai parcouru le forum longuement mais je n'ai pas trouvé ce que je cherchais...

J'ai un tableau de présences mensuelles pour des salariés et cette présence est indiquée par un nombre d'heures.

J'aimerais, dans un tableau récapitulatif, compter le nombre de présences, sur le mois, des salariés par jour (lundi, mardi, mercredi,etc...) sachant que les présences d'un salarié sur le même jour du mois (tous les mercredis du mois par ex) ne doivent compter que pour une seule fois.

En espérant avoir été clair, je vous joins un fichier pour imager ma demande.

Merci d'avance pour votre aide!
 

Pièces jointes

  • quiproko.xls
    23.5 KB · Affichages: 53
  • quiproko.xls
    23.5 KB · Affichages: 54
  • quiproko.xls
    23.5 KB · Affichages: 75

R@chid

XLDnaute Barbatruc
Re : Compter une seule fois une présence multiple sur les mêmes jours du mois

Bonjour,
Avec cette structure de ton tableau on va surement se compliquer la vie, il faut essayer de changer la structure en essayant de mettre tous les jours en une seul ligne et les noms en une colonne, ou bien l'inverse les noms en une ligne et les jours en une colonne, j'ai vu ce tableau sur une autre discussion et j'ai pas aimé répondre..

@ te relire
 

quiproko

XLDnaute Nouveau
Re : Compter une seule fois une présence multiple sur les mêmes jours du mois

Bonjour R@chid,

Merci de t'être une nouvelle fois arrêté sur mon tableau.

J'ai modifié ce dernier : tous les jours en une seul ligne et les noms en une colonne (fichier joint)

Ma question sera peut-être naïve (au vu de mes compétences) mais si c'est faisable pour les jours en une seule ligne, pourquoi c'est plus compliqué de le faire sur 3 ?

A te lire.
 

Pièces jointes

  • quiproko(1).xls
    21.5 KB · Affichages: 42

R@chid

XLDnaute Barbatruc
Re : Compter une seule fois une présence multiple sur les mêmes jours du mois

Re,
Si j'ai bien compris, en D18,
Code:
=MAX(SOUS.TOTAL(2;DECALER($D5:$D11;;EQUIV(D17;TEXTE($E4:$AH4;"jjjj");0)+{0;7;14;21;28})))

Ou,
Code:
=MAX(NB.SI(DECALER($D5:$D11;;EQUIV(D17;TEXTE($E4:$AH4;"jjjj");0)+{0;7;14;21;28});">0"))



@ valider par Ctrl+Maj+Entree
@ tirer vers la droite


@ + +
 
Dernière édition:

R@chid

XLDnaute Barbatruc
Re : Compter une seule fois une présence multiple sur les mêmes jours du mois

Re,
Une autre puisque la question n’était pas claire,
en D18,
Code:
=NB(1/FREQUENCE(SI((TEXTE($E4:$AH4;"jjjj")=D17)*($E5:$AH11<>"");EQUIV(LIGNE(E5:E11);LIGNE(E5:E11);0));LIGNE(E5:E11)-4))
@ valider par Ctrl+Maj+Entree
@ tirer vers la droite

Voir le fichier récapitulatif


@ + +
 

Pièces jointes

  • Recapitulatif.xls
    38 KB · Affichages: 52
  • Recapitulatif.xls
    38 KB · Affichages: 56
  • Recapitulatif.xls
    38 KB · Affichages: 51

mapomme

XLDnaute Barbatruc
Supporter XLD
Re : Compter une seule fois une présence multiple sur les mêmes jours du mois

Bonjour quiproko,R@chid, gosselien,

Comme j'ai travaillé dessus, je le mets en ligne. J'ai compris la même chose que R@chid avec sa 3ième interprétation.

la formule en D18 à tirer vers la droite est:
Code:
=SOMME(--(PRODUITMAT(N((JOURSEM($E$4:$AH$4;2)=COLONNES($A:A))*($E$5:$AH$11>0)>0); LIGNE(INDIRECT("1:30")) /LIGNE(INDIRECT("1:30")))>0))
 

Pièces jointes

  • Compter une seule fois une présence multiple v1.xls
    32 KB · Affichages: 42
Dernière édition:

quiproko

XLDnaute Nouveau
Re : Compter une seule fois une présence multiple sur les mêmes jours du mois

Bonsoir R@chid, mapomme, gosselien

La dernière formule de R@chid ( les 2 premières ne donnaient pas le résultat attendu) et celle de mapomme fonctionnent parfaitement ! :D

Encore merci pour votre aide !!

Bonne soirée !
 

mapomme

XLDnaute Barbatruc
Supporter XLD
Re : Compter une seule fois une présence multiple sur les mêmes jours du mois

Bonjour à tous,

Comme me l'a suggéré avec pertinence R@chid :) , la formule peut se simplifier en ne comptant que les valeurs finales strictement positives et en ne mettant pas les valeurs intermédiaires à 0 ou 1.

On aboutit à la formule suivante en D18 à tirer/copier vers la droite:
Code:
=SOMME(--(PRODUITMAT((JOURSEM($E4:$AH4;2)=COLONNES($A:A))*($E5:$AH11);LIGNE(1:30)) >0))

nota: Une illustration de la formule (pour le jour du lundi) a été insérée dans le fichier v2

Edit: et deux autres suggestions de R@chid ! ->v2a
 

Pièces jointes

  • Compter une seule fois une présence multiple v2a.xls
    55 KB · Affichages: 56
Dernière édition:

quiproko

XLDnaute Nouveau
Re : Compter une seule fois une présence multiple sur les mêmes jours du mois

Bonjour mapomme, R@chid,

Merci encore pour votre aide et pour avoir passé de votre temps à réfléchir à mon problème.

On aboutit à la formule suivante en D18 à tirer/copier vers la droite:
Code:
=SOMME(--(PRODUITMAT((JOURSEM($E4:$AH4;2)=COLONNES($A:A))*($E5:$AH11);LIGNE(1:30)) >0))

Pourrais-tu m'expliquer les termes (pas à pas si possible) de cette formule car je patauge complétement..?

Je suppose que si on considère 31 jours dans le mois, on doit noter "LIGNE(1:31)" dans la formule ?
Je ne comprends pas non plus que l'on évoque dans la formule la colonne A alors qu'elle est vide...

Désolé de poser peut-être des questions débiles mais comme je vais avoir besoin de ce type de formule pour faire autre chose, j'aimerais la comprendre un minimum.

Merci d'avance !
 

mapomme

XLDnaute Barbatruc
Supporter XLD
Re : Compter une seule fois une présence multiple sur les mêmes jours du mois

Bonjour quiproko, à tous,

(...) Je suppose que si on considère 31 jours dans le mois, on doit noter "LIGNE(1:31)" dans la formule ? (...)
Oui.

(...) Pourrais-tu m'expliquer les termes (pas à pas si possible) de cette formule (...)
Voir le fichier joint (hé ben, j'ferai pas ça tous les jours :p )
 

Pièces jointes

  • Compter une seule fois une présence multiple.pdf
    190 KB · Affichages: 66
Dernière édition:

Discussions similaires

Réponses
306
Affichages
25 K

Statistiques des forums

Discussions
311 733
Messages
2 082 011
Membres
101 866
dernier inscrit
XFPRO