Comptage du nombre d'heures travaillées dans une période avec des horaires variés

[Riton66]

Bonjour à tous,

Voilà mon problème :
Je dois comptabiliser le nombre d’heures travaillées sur une période donnée en tenant compte des jours fériés, des ponts et des congés de l’entreprise.
Mon problème est que les horaires journaliers de l’entreprise sont 8h00 du lundi au jeudi et 3h00 le vendredi.
Quand j’utilise la fonction « nb.jours.ouvrés » avec une moyenne de 7h00 par jour (5x7=35), les jours retirés dans les semaines fractionnées (jours fériés dans la fonction) sont multipliés par 7 et non par 8 ou 3. Du coup mon compte n’y est pas.

Exemple : Période du 23/06/11 au 21/07/11 totalise 135h avec les 2/07 ; 3/07 ; 13/07 chaumés au lieu de 137h (-3 sem22 ; -3+4 sem24 ; -2 sem25 =-4).

Selon moi, il faudrait extraire les vendredis pour les rajouter en suite, ou retirer les heures excédentaires et ajouter celles qui manquent. A ce sujet j’ai résolue le problème des derniers jours en ajoutant à ma formule le « joursem(fin de période ;2) » (valeur égale au nb d’heures à ajouter) mais pour le reste ???

Au bout de 3 jours de réflexion autour de plusieurs fonctions, je m’aperçois que j’arrive à mes limites, alors quelqu’un pourrait-il m’aider à me faire comprendre correctement d’Excel ?

 

[Guest]

Re : Comptage du nombre d'heures travaillées dans une période avec des horaires varié

Bonjour Riton,

Je ne sais pas si je comprends bien ton problème mais voici une fonction(merci Monique) qui comptera le nombre de vendredi entre deux dates:

=SOMMEPROD((JOURSEM(LIGNE(INDIRECT(A28&":"&B28)))=6)*1)

Où A28= date1 de la période et B28 dateFin de la période

Une idée:

Mutliplier le nombre de jourOuvrés dans la période par 8heures et soustraire le nombre de vendredi*5heures (8-5=3h) dans la périodes.

A+

 

[Monique]

Re : Comptage du nombre d'heures travaillées dans une période avec des horaires varié

Bonjour,

Une proposition avec SommeProd et Indirect

Regarde ici aussi : http://www.excel-downloads.com/forum/167232-connaitre-nombre-de-jours-feries-et-de-vendredi-entre-2-dates.html#post1014312

De rien, Hasco

 

[Guest]

Re : Comptage du nombre d'heures travaillées dans une période avec des horaires varié

Re,

Ben voui! j'avions oublié qu'un vendredi pouvait être férié re Merci Monique

A+++

 

[Riton66]

Re : Comptage du nombre d'heures travaillées dans une période avec des horaires varié

Merci Hasco et Monique de votre rapidité, je vais commencer à travailler la dessus et je vous tiens informé.

Merci encore

 

[Riton66]

Re : Comptage du nombre d'heures travaillées dans une période avec des horaires varié

Re

Je viens de terminer de paramétrer ma cellule et ça donne ça en F74:

=((SOMMEPROD((JOURSEM(LIGNE(INDIRECT($C74&":"&$D74));2)<5)*(NB.SI($D$10:$E$25;LIGNE(INDIRECT($C74&":"&$D74)))=0)))*$D$5)+((SOMMEPROD((JOURSEM(LIGNE(INDIRECT($C74&":"&$D74)))=6)*1)-SOMMEPROD((JOURSEM(LIGNE(INDIRECT($C74&":"&$D74)))=6)*(NB.SI($D$10:$E$25;LIGNE(INDIRECT($C74&":"&$D74)))>0)))*$C$5)

je pense que je pourrais simplifier mais pour le moment ça me va

Merci encore

 

[Monique]

Re : Comptage du nombre d'heures travaillées dans une période avec des horaires varié

Re,

La même :

=SOMMEPROD((JOURSEM(LIGNE(INDIRECT($C74&":"&$D74));2)<5)*(NB.SI($D$10:$E$25;LIGNE(INDIRECT($C74&":"&$D74)))=0))*$D$5+SOMMEPROD((JOURSEM(LIGNE(INDIRECT($C74&":"&$D74)))=6)*(NB.SI($D$10:$E$25;LIGNE(INDIRECT($C74&":"&$D74)))=0))*$C$5

La même encore (tu l’avais en colonne J, sous le titre « Les deux ensemble »)

[/FONT]=SOMMEPROD(((JOURSEM(LIGNE(INDIRECT(C74&":"&D74));2)<5)*$D$5+(JOURSEM(LIGNE(INDIRECT(C74&":"&D74));2)=5)*$C$5)*(NB.SI($D$10:$E$25;LIGNE(INDIRECT(C74&":"&D74)))=0))

 

[Riton66]

Re : Comptage du nombre d'heures travaillées dans une période avec des horaires varié

Merci Monique,

Je suis vraiment une bille !!!
je vais essayer de bien comprendre comment fonctionne cette "formule magique" pour l'appliquer à la suite de mon tableau dont la problématique s'allonge de réunion en réunion.

Merci encore pour le "coup de neurones" les miens ne sont pas entraînés à ça ;-)

A+