Comparer deux colonnes

[Patrice2207]

Bonjour à tous et à toutes,

bien qu'il y ait déjà de nombreux post à ce sujet, je ne trouve pas mon bonheur, ce qui de fait, fait mon malheur !

Je souhaite comparer deux colonnes :

Colonne D
Colonne AN

ET dans la colonne AV, faire apparaître un OK ou KO en face de chaque nom de la colonne AN

Les colonnes de A à E sont un copié collé d'une requête d'un outil d'entreprise et je n'ai pas vraiment le choix que de conserver la forme.

Les colonnes de AN à AR: saisie pure

Je voudrais mettre en évidence : que certains noms de la colonne D ne sont pas saisis dans la colonne AN. Petite complication, dans la colonne D, je ne veux prendre que les noms et prénoms.
Exemple :

TEDDY
TEDDY
TEDDY
TEDDY
TEDDY
CAILLIERET TEDDY

Je ne veux prendre que : CAILLERET TEDDY.

Je joins mon petit fichier

Par avance un grand merci

Patrice

 

[herve62]

Re : Comparer deux colonnes

Pas évident à piger ce que tu veux faire ?
Si tu avais déjà mis en exemple à la main de ce que tu veux comme résultat
ce serait plus clair et parlant
Sinon , indice pour ne prendre que nom & prénom , je parle VBA : une boucle sur B et chaque fois que tu as "Total matricule" avec ta Cel en X+1 tu récupères le nom ensuite je vois plus ce que tu veux faire ?

 

[Victor21]

Re : Comparer deux colonnes

Bonjour Patrice2207, hervé62.

Essayez en AV2 :

=SI(NB.SI.ENS(C$2:C$258;"Total matricule";D$2$258;AN2);"OK";"KO")

Et dites-nous...

 

[BOISGONTIER]

Re : Comparer deux colonnes

Bonjour,

=SI(GAUCHE(C2;5)="Total";SI(ESTNA(EQUIV(D2;ColAN;0));"ko "&D2;"bon");"")

JB

 

[job75]

Re : Comparer deux colonnes

Bonjour Patrice2207, hello JB,

En AV2 :

=SI(SOMMEPROD(N(DECALER(C$1;;;NBVAL(C:C))&" "&DECALER(D$1;;;NBVAL(C:C))=AN2));"OK";"KO")

Ou si l'on craint des espaces superflus :

=SI(SOMMEPROD(N(SUPPRESPACE(DECALER(C$1;;;NBVAL(C:C))&" "&DECALER(D$1;;;NBVAL(C:C)))=SUPPRESPACE(AN2)));"OK";"KO")

Edit : pas vu hervé et patrick, salut à vous.

A+

 

[Patrice2207]

Re : Comparer deux colonnes

Re bonjour

Merci d'avoir répondu de manière aussi rapide
Toutes les solutions proposées fonctionnent, pas de soucis. Seulement, c'est quasi l'inverse que je souhaiterai. A savoir :
Je souhaiterai mettre en évidence que dans la colonne AN, je n'ai pas saisi un des noms de la colonne D.
Exemple si j'ajoute un nom en D, j'oubli de le saisir en AN, comment puis je le repérer !!
Merci pour votre patience

Au cas où, même si ca n'a pas d'influence, sur la deuxième page, j'ai un croisé dynamique qui me reprend toutes les infos saisies. Ai du "choutter" la page, le fichier était trop volumineux

 

[BOISGONTIER]

Re : Comparer deux colonnes


>Exemple si j'ajoute un nom en D, j'oubli de le saisir en AN, comment puis je le repérer !!

Si dans la colonne D il y a xxxxx yyyy qui n'existe pas en colonne AN, le message KO xxxxx yyyy apparait en colonne AV

JB

 

[job75]

Re : Comparer deux colonnes

Re,

Il faut sans doute compliquer un peu :

=SI(SOMMEPROD(N(DECALER(C$1;;;NBVAL(C:C))&" "&DECALER(D$1;;;NBVAL(C:C))=AN2))*SOMMEPROD(N(DECALER(D$1;;;NBVAL(C:C))=AN2));"OK";"KO")

ou :

=SI(SOMMEPROD(N(SUPPRESPACE(DECALER(C$1;;;NBVAL(C:C))&" "&DECALER(D$1;;;NBVAL(C:C)))=SUPPRESPACE(AN2)))*SOMMEPROD(N(SUPPRESPACE(DECALER(D$1;;;NBVAL(C:C)))=SUPPRESPACE(AN2)));"OK";"KO")

A+

 

[Victor21]

Re : Comparer deux colonnes

Re,

=SI(C2<>"Total matricule";"";SI(NB.SI($AN$2:AN$258;D2);"OK";"KO"))

renverra OK si la valeur de D2 est trouvée en AN2:AN258 et si C2 contient "Total matricule"
renverra KO si la valeur de D2 n'est pas trouvée en AN2:AN258 et si C2 contient "Total matricule"
ne renverra rien si C2 contient "Total matricule"

Edit : Pardon ! je manque à tous mes devoirs : Bonjour Gérard, Jacques

 

[job75]

Re : Comparer deux colonnes

Re,

Je souhaiterai mettre en évidence que dans la colonne AN, je n'ai pas saisi un des noms de la colonne D.

Toujours en AV2 :

=SI(C2<>"Total matricule";"";SI(SOMMEPROD(N(DECALER(AN$1;;;EQUIV("zzz";AN:AN))=D2));"OK";"KO"))

ou :

=SI(SUPPRESPACE(C2)<>"Total matricule";"";SI(SOMMEPROD(N(SUPPRESPACE(DECALER(AN$1;;;EQUIV("zzz";AN:AN)))=SUPPRESPACE(D2)));"OK";"KO"))

A+

 

[Patrice2207]

Re : Comparer deux colonnes

Yesssssss, Un grand merci à vous tous, j'ai trouvé mon bonheur. Comme quoi, il suffit de demander.

Merci pour vos réponses, votre patience et votre dévouement

 

[herve62]

Re : Comparer deux colonnes

Bon , bin .... je vois que tout le monde a compris ton Pb et que tu as ta solution c'est le principal, mais bon moi & les formules
même si Misange m'a aidé un peu autrefois mais j'arrive pas à me faire à toutes ces ((( )))) ((( !!!!!!

Bonsoir à ceux que j'ai pas salué auparavant , Jacques mes amitiés ( Lycée Gayole Boulogne s/mer 72-75)