XL 2016 Comment tester le Type d'Objet UserForm ?

[Dudu2]

Bonjour à tous,

Sub a()
    Dim Obj As Object
   
    Set Obj = ActiveSheet
    On Error Resume Next    'Instruction sans effet car l'erreur vient du compilateur.
    MsgBox TypeOf Obj Is UserForm
End Sub

Tant qu'on n'a pas créé un UserForm dans le Projet VBA l'instruction MsgBox TypeOf Obj Is UserForm génère cette erreur de compilation (pas d'exécution !):

Il suffit de créer un UserForm pour que le Type soit reconnu.
De plus, même après suppression du UserForm, le Type reste reconnu.

Comment tester le Type Userform sans UserForm dans le Projet VBA ?
Ou neutraliser ce test en vérifiant s'il y a 1 ou plusieurs UserForms dans le Projet VBA ?

Merci pour toute info.
D.

 

[dysorthographie]

MsgBox TypeName( Obj )

 

[Hasco]

Bonjour,

Tant qu'on n'a pas créé un UserForm dans le Projet VBA l'instruction MsgBox TypeOf Obj Is UserForm génère cette erreur de compilation (pas d'exécution !):
Il suffit de créer un UserForm pour que le Type soit reconnu.

Tant que vous n'avez pas créé un UserForm la librairie nommée Mictosoft Forms 2 Object Library n'est pas référencée dans votre projet.

Mais elle le reste après suppression du userform.

Cordialement

 

[patricktoulon]

re
bonjour a tous
je n'ai pas pu m'en empêcher

Sub a()
    Dim Obj As Object, typeouff As Boolean

    Set Obj = ActiveSheet
    'On Error Resume Next    'Instruction sans effet car l'erreur vient du compilateur.
    For Each usf In UserForms: typeouff = usf.Name = Obj.Name: Next
    MsgBox typeouff
End Sub

peut etre en faire une fonction

Sub a()
    Dim obj As Object
    Set obj = ActiveSheet
    MsgBox typeouff(obj, UserForms)
    MsgBox typeouff(obj, Worksheets)
End Sub
Function typeouff(obj, lacollection) As Boolean
    Dim truc
    For Each truc In lacollection
        If truc.Name = obj.Name Then typeouff = True
    Next
End Function

 

[Dudu2]

Merci à tous, vous êtes des As !

Sub a()
    Dim Obj As Object
    Dim Usf As Object
    Dim IsUserForm As Boolean
  
    Set Obj = ActiveSheet
    'Set Obj = UserForm1

    For Each Usf In UserForms
         If Usf.Name = Obj.Name Then IsUserForm = True
    Next Usf
    
    MsgBox IsUserForm
End Sub

 

[Dranreb]

Bonjour.

Comment tester le Type Userform sans UserForm dans le Projet VBA ?

C'est un type d'objet défini par la bibliothèque MSForms. Sa référence Microsoft Forms 2.0 Object Library doit par conséquent être cochée. Or elle se coche toute seule lorsqu'on demande l'insertion d'un nouvel UserForm.
Attention TypeName(Obj) renvoie le nom de l'UserForm et non "UserForm". C'est en réalité un module de classe avec une interface d'affichage. Cependant je pense qu'il implémente un UserForm et que c'est pourquoi TypeOf Obj Is MSForms.UserForm est vrai quand même aussi.

Sub Test()
   Dim Obj As Object
   Set Obj = New UserForm1
   MsgBox TypeOf Obj Is MSForms.UserForm _
      & vbLf & TypeOf Obj Is UserForm1 _
      & vbLf & TypeName(Obj)
   End Sub

(UserForm1 est un objet de la rubrique Feuilles que j'ai créé pour le test, bien sûr)
(Et il en existe toujours aussi un exemplaire Public portant pour nom d'objet son nom de type)

 

[patricktoulon]

re
en passant par la collection du type recherché(testé) on a pas besoins de la librairie

 

[Dudu2]

Enfin, y a quand même un schmilblick dans le code.
Si une feuille (ou tout autre objet) porte le même nom qu'un des UserForms ça ressort en type UserForm.

Ou alors il faut que je réserve ce test si aucun TypeOf n'a abouti avant.

 

[Dudu2]

Ou alors, tester si la bibliothèque fait partie des Références et si elle n'en fait pas partie, l'inclure.
Mais le compilateur va-t-il la voir si son inclusion résulte de l'exécution ?!

Edit: C'est pas impossible qu'il la voit. Car le compilateur est moitié compilo moitié interpréteur non ?
Sinon j'aurais l'erreur même sans passer dans le code concerné (la référence étant manquante), ce qui n'est pas le cas.

 

[Dranreb]

Ceci affiche aussi Vrai :

Sub test2()
   Dim Obj As Object, UFm As Object, CeLEst As Boolean
   Set Obj = UserForm1
   For Each UFm In VBA.UserForms
      CeLEst = UFm Is Obj
      If CeLEst Then Exit For
      Next UFm
   MsgBox CeLEst
   End Sub

Attention: l'opérateur Is utilisé comme ça marche rarement pour des objets Excel.

 

[Dudu2]

Oui mais Dranreb, si j'insers ton module dans un fichier Excel qui n'a jamais contenu de UserForm (la bibliothèque Microsoft Forms 2.0 Object Library n'est pas chargée dans les Références) ça plante direct sur Set Obj = UserForm1.

 

[Dranreb]

Oui mais cette instruction ne m'a servi qu'à initialiser Obj pour le test, elle n'en fait pas partie. En le remplaçant par Activesheet, affiche Faux.

 

[Dudu2]

Ok donc ton test
CeLEst = UFm Is Obj
permet un comparatif objet à objet ?
Si c'est la cas c'est magique !

 

[Dranreb]

Oui, mais attention, ça permet seulement de vérifier si deux expression désignent un même exemplaire d'objet, mais hélas pas si deux exemplaires différents représentent la même entité de l'application hôte.

 

[Dudu2]

En l'occurrence c'est bien ta première assertion qu'on veut vérifier.
Et donc le code:

Sub a()
    Dim Obj As Object
    Dim Usf As Object
    Dim IsUserForm As Boolean

    Set Obj = ActiveSheet
    'Set Obj = UserForm1

    For Each Usf In UserForms
         IsUserForm = Usf Is Obj
         If IsUserForm Then Exit For
    Next Usf
  
    MsgBox IsUserForm
End Sub

Edit: Et plus utilisable sous forme de fonction:

Function IsUserForm(Obj As Object) As Boolean
    Dim Usf As Object
    
    For Each Usf In UserForms
         If Usf Is Obj Then Exit For
    Next Usf
    
    If Not Usf Is Nothing Then IsUserForm = True
End Function

Franchement, vous êtes trop forts !
Merci.