Comment supprimer une ligne si la premiere cellule est sélectionnée?

[TopNotch63]

Bonjour,

Je n'arrive pas à trouver de solution dans les autres sujets. Comment faire pour avoir une sub qui supprime une ligne entiere si la premiere cellule est sélectionnée.

Il peut y avoir plusieurs cellules de sélectionnées et pas nécessairement une à la suite de autres.

Merci.

 

[GIBI]

Re : Comment supprimer une ligne si la premiere cellule est sélectionnée?

Bonsoir,

si j'ai compris le besoin : une idée bestiale

Sub Sup()
Dim Ligne_A_Supprimer(20) As Long
Dim L As Long

'Reperer les lignes à supprimer
For Each Cellule In Selection
 If Cellule.Column = 1 Then
  Ligne_A_Supprimer(L) = Cellule.Row
  L = L + 1
 End If
Next
'Supprimer les lignes
For L = L - 1 To 0 Step -1
 Rows(Ligne_A_Supprimer(L)).Delete
Next
'enlever la selection
Cells(Ligne_A_Supprimer(0), 1).Select
End Sub

Bon courage

 

[job75]

Re : Comment supprimer une ligne si la premiere cellule est sélectionnée?

Bonsoir TopNotch63,

(...) si la premiere cellule est sélectionnée.

Ma boule de cristal me dit que la 1ère cellule est celle située en colonne A, astucieuse la guêpe non ?

Alors cette macro :

Sub SupprimeLigne()
Dim plage As Range
ActiveCell.Activate 'sécurité car un objet peut être sélectionné
Set plage = Intersect(Selection, [A:A])
If plage Is Nothing Then Exit Sub
plage.EntireRow.Delete
End Sub

Edit : salut GIBI, je ne vous avais pas vu

A+

 

[TopNotch63]

Re : Comment supprimer une ligne si la premiere cellule est sélectionnée?

Merci, tout fonctionne très bien.