Comment convertir Date et heure en texte ou nombre.

[Surfing Joe]

Bonsoir, à toutes et à tous,

Depuis quelques jours sur ce forum génial, je commence à connaitre pas mal d'entre vous!

Voilà oû je butte:

Par la fonction MAINTENANT() j'obtiens une date et heure (dans mon ex 17/01/2005 19:18),

Je voudrai convertir cette donnée en 50117-19h15.
5 étant l'année, 01 le mois , 17 le jour, 19h , et 15 un arrondi inferieur de 18 minutes.

A+, j'espère, Surfing Joe.

 

[C@thy]

quelquechose comme ça??? (je ne comprends pas bien ton histoire de inférieur 18mn vu l'exemple)

=DROITE(ANNEE(A1);1)&SI(MOIS(A1)<9;0&MOIS(A1);MOIS(A1))&JOUR(A1)&"-"&HEURE(A1)&"h"&ARRONDI.AU.MULTIPLE(MINUTE(A1);15)

C@thy

 

[C@thy]

si si, j'ai compris!

par exemple :

=DROITE(ANNEE(A6);1)&SI(MOIS(A6)<9;0&MOIS(A6);MOIS(A6))&JOUR(A6)&"-"&HEURE(A6)&"h"&PLANCHER(MINUTE(A6);15)

C@thy

 

[C@thy]

les 2 formules fonctionnent, mais la 1ère donne l'arrondi aux 15mn les plus proches (inférieur ou supérieur)
alors que la 2ème donne toujours l'arrondi inférieur (aux 15mn), comme ça tu as le choix.
J'ai mis A1 ou A6 à titre d'exemple, mais tu mets la référence que tu veux of course!!!

C@thy

 

[Surfing Joe]

Merci C@thy Coyotte, tu m'as enrhumé par la rapidité et la précision de ta réponse, je reste sans voix, et même frustré de ne pas avoir trouvé avant toi.
Je suis en train de mettre en place une fonction qui enregistre un fichier de commande avec une extension date et heure avec arrondie "comme tu as si bien compris". Cela permet de générer automatiquement des N° de commandes et de pouvoir les classer par chronologie et de les gérer.

Si j'arrive à mes fins, je mettrai un exemple sur le forum, ça peut servir à d'autre.

J'adore ton Gif ! Félicitaion et Sincèrement merci encore.

 

[Surfing Joe]

Heureux-Re: Comment convertir Date et heure en texte ou nombre.

Bonsoir le forum,

Chose promise chose due, voilà un exemple de fichiers enregistrant automatiquement le nom du fichier ici "Fiche" + la date et l'heure d'enregistrement. "Fiche_50118-18h28" ou "Fiche_50118-18h15" si on choisi l'option arrondi au 1/4h inférieur.

Les macro sont de "galopin01" fil http://www.excel-downloads.com/html/French/forum/read.php?f=1&i=141497&t=141303,

Les formules que j'ai modestement un peu modifiées sont de "C@thy", les bip bip aussi!

Maintenant j'aimerai en faire une macro complémentaire, c'est à dire tout mettre en VBA, Qui peut m'aider...

Génie es tu las, ou es tu là?

A+ S.J.

 

[C@thy]

Re: Heureux-Re: Comment convertir Date et heure en texte ou nombre.

juste une petite amélioration de formule pour éviter le test des mois et minutes <10 :

=("_")&DROITE(ANNEE($C$2);1)&TEXTE(MOIS(C2);"00")&JOUR($C$2)&"-"&HEURE($C$2)&"h"&TEXTE(MINUTE($C$2);"00")

même correction en A2 ... petit clin d'oeil à Monique ;-D)

C@thy

 

[C@thy]

Re: Heureux-Re: Comment convertir Date et heure en texte ou nombre.

en A2 :
=("_")&DROITE(ANNEE($C$2);1)&TEXTE(MOIS(C2);"00")&JOUR($C$2)&"-"&HEURE($C$2)&"h"&TEXTE(PLANCHER(MINUTE($C$2);15);"00")

C@thy

 

[C@thy]

Re: Heureux-Re: Comment convertir Date et heure en texte ou nombre.

P.S. je pense qu'il faut aussi mettre le 0 pour les jours <10 :

=("_")&DROITE(ANNEE($C$2);1)&TEXTE(MOIS($C$2);"00")&TEXTE(JOUR($C$2);"00")&"-"&HEURE($C$2)&"h"&TEXTE(MINUTE($C$2);"00")

et en A2 /

=("_")&DROITE(ANNEE($C$2);1)&TEXTE(MOIS(C2);"00")&TEXTE(JOUR($C$2);"00")&"-"&HEURE($C$2)&"h"&TEXTE(PLANCHER(MINUTE($C$2);15);"00")

C@thy

 

[Monique]

Bonjour,

Un raccourci pour la 1ère :
=("_")&DROITE(ANNEE(A$1))&TEXTE(A$1;"mmjj""-""h""h""mm")
(doubler les guillemets autour de - et de h)

Pour la 2ème :
=("_")&DROITE(ANNEE(A$1))&TEXTE(A$1;"mmjj""-""h""h""")&TEXTE(PLANCHER(MINUTE(A1);15);"00")

 

[C@thy]

Ah ben oui, comme ça c'est carrément nickel!!!

Merci Monique!!!

C@thy

 

[Surfing Joe]

Bonjour les formuleuses et merci tout plein.

Les formules de Monique marchent super aussi, quel est l'as de la VBA qui va nous mettre tou ça dans une macro?

A+, S.J.