Comment avoir une plage_somme de plusieurs colonnes avec SOMME.SI.ENS ?

[ptidof]

Bonjour,
je cherche la formule qui me permet d'avoir une plage_somme de plusieurs colonnes ?!
Exemple:
Colonne A: Ref (580 lignes)
Colonne B: Qualités
Colonne C: Qualités

Le reste de colonnes étant chaque jour de l'année: 1 Janvier, 2 Janvier; 3 Janvier,.............31 Décembre.

Je souhaite faire la somme de tout un mois (donc 31 colonnes sur 580 lignes par exemple GF3:HJ580) a condition d'une qualité de la colonne B associé a une qualité de la colonne C.

Lorsque j'utilise la formule SOMME.SI.ENS et que je demande une plage_somme de plus d'une colonne j'ai l'erreur #VALEUR qui s'affiche....

Exemple de la formule utilisée:
=SOMME.SI.ENS(GF3:HJ580;B3:B580;="PAPIER";C3:C580;="20x40")

La formule fonctionne uniquement si j'utilise cette formule:
=SOMME.SI.ENS(GF3:GF580;B3:B580;="PAPIER";C3:C580;="20x40")

Comment faire pour avoir une plage_somme de plusieurs colonnes ?!

J espère être clair ?

Merci de votre aide !!

 

[MJ13]

Re : Comment avoir une plage_somme de plusieurs colonnes avec SOMME.SI.ENS ?

Bonjour Ptidof

J espère être clair ?

Avec un fichier, on pourrait voir pour mieux t'aider

 

[ptidof]

Re : Comment avoir une plage_somme de plusieurs colonnes avec SOMME.SI.ENS ?

Bien sur !!

 

[julberto]

Re : Comment avoir une plage_somme de plusieurs colonnes avec SOMME.SI.ENS ?

Bonjour Ptidof,

Dans l'aide d'Excel on peut lire :

dans la fonction SOMME.SI.ENS, chaque argument plage_critères doit contenir le même nombre de lignes et de colonnes que l’argument somme_plage.

cordialement

 

[Tibo]

Re : Comment avoir une plage_somme de plusieurs colonnes avec SOMME.SI.ENS ?

Bonjour,

Pour ma part, je préconise une solution avec SOMMEPROD, ce qui permet le cas échéant de reprendre le fichier sous Excel 2003.

Je te propose cette formule en B2 :

=SOMMEPROD(('Ref test'!$B$3:$B$585=$A2)*('Ref test'!$C$3:$C$585=$A$19)*(TEXTE('Ref test'!$E$2:$AI$2;"mmmm")=B$1)*'Ref test'!$E$3:$AI$585)

à recopier vers le bas et vers la droite

@+

 

[Tibo]

Re : Comment avoir une plage_somme de plusieurs colonnes avec SOMME.SI.ENS ?

Bonjour,

Pour faire suite à ton MP, je t'apporte quelques précisions :

La fonction SOMMEPROD présente l'avantage de retourner souvent les mêmes résultats que SOMME.SI.ENS

Et surtout présente l'avantage de pouvoir être utilisée sur des versions antérieures d'Excel.

Décomposition de la formule en B2 : on a pour chaque plage de cellules un test. Chaque test retourne une matrice de VRAI ou de FAUX (ou 1 et 0).

=SOMMEPROD(

('Ref test'!$B$3:$B$585=$A2)*

on teste pour voir si les éléments de B3:B585 sont égaux à $A2

('Ref test'!$C$3:$C$585=$A$19)*

même principe avec B3:B585 qu'on compare à A19

(TEXTE('Ref test'!$E$2:$AI$2;"mmmm")=B$1)*

Ici, on récupère les dates dans l'onglet Ref test en les mettant au format mmmm pour pourvoir les comparer à la ligne 1 de l'onglet test 01.


Une fois ces trois matrices de VRAI / FAUX ou 1/0 constituées, elles sont multipliées entre elles. Un seul 0 (ou FAUX) suffit à retourner 0 pour la ligne concernée. Reste ensuite à multiplier avec les données E3:AI585

'Ref test'!$E$3:$AI$585)

Bon, plus facile à faire qu'à expliquer.

Je t'invite à te familiariser avec cette formule en lisant l'aide d'Excel, mais aussi en utilisant la fonction Recherche sur le Forum pour découvrir de nombreux exemples d'utilisation de cette fonction.

@+

 

[ptidof]

Re : Comment avoir une plage_somme de plusieurs colonnes avec SOMME.SI.ENS ?

Excellent merci !!!!