Comment avec GetOpenFilename ne faire apparaître que les fichiers avec"Imputations"

Paritec

XLDnaute Barbatruc
Bonjour à tous
je cherche dans une macro à avoir à un moment donné l'ouverture avec GetOpenFilename ou autre je ne sais pas pour choisir dans un dossier précis
C:\documents and Settings\bureau\Imputations tous les fichiers dans le dossier Imputation commençant pas "Imputation *" et lors du choix l'ouverture de ce fichier?
je ne trouve pas comment le réaliser
dans l'attente de vos réponses
a+
papou :)
 

job75

XLDnaute Barbatruc
Re : Comment avec GetOpenFilename ne faire apparaître que les fichiers avec"Imputatio

Bonjour Papou,

Peut-être ceci, avec Dir :

Code:
Sub OuvreFichiers()
Dim chemin$, nomfich$
Application.ScreenUpdating = False
On Error Resume Next
chemin = "C:\documents and Settings\bureau\Imputations\"
nomfich = Dir(chemin & "Imputation*.xls") '1er fichier trouvé
While nomfich <> ""
  If IsError(Workbooks(nomfich).Name) Then _
    Workbooks.Open chemin & nomfich 'ouverture si le fichier n'est pas déjà ouvert
  Windows(nomfich).Visible = True 'au cas où la fenêtre serait masquée
  nomfich = Dir 'fichier suivant
Wend
ThisWorkbook.Activate
End Sub

A+
 

Paritec

XLDnaute Barbatruc
Re : Comment avec GetOpenFilename ne faire apparaître que les fichiers avec"Imputatio

Bonjour Job,
je vais tester tut de suite et je te redis mais peut-être pas avant midi peut-être cet après midi
a+
et un grand merci
a+
Papou :)
 

tototiti2008

XLDnaute Barbatruc
Re : Comment avec GetOpenFilename ne faire apparaître que les fichiers avec"Imputatio

Bonjour Job, Bonjour Paritec,

un essai :

Code:
Dim FD As FileDialog
    Set FD = Application.FileDialog(msoFileDialogOpen)
    With FD
        .InitialFileName = "C:\documents and Settings\bureau\Imputations\Imputations*"
        .Filters.Clear
        .Filters.Add "Fichier Excel", "*.xls"
        .AllowMultiSelect = False
        If .Show <> 0 Then
            Workbooks.Open .SelectedItems(1)
        End If
    End With
    ThisWorkbook.Activate
 

job75

XLDnaute Barbatruc
Re : Comment avec GetOpenFilename ne faire apparaître que les fichiers avec"Imputatio

Re Papou, salut tototiti :)

Une solution qui utilise bien GetOpenFilename :

Code:
Sub OuvreFichier()
Dim chemin$, nomfich
chemin = "C:\documents and Settings\bureau\Imputations"
ChDir chemin
1 nomfich = Application.GetOpenFilename("Fichiers Excel(*.xls),*.xls")
If nomfich = False Then Exit Sub
If Not nomfich Like chemin & "\" & "Imputation*.xls" Then GoTo 1
Workbooks.Open nomfich
End Sub

A+
 

Paritec

XLDnaute Barbatruc
Re : Comment avec GetOpenFilename ne faire apparaître que les fichiers avec"Imputatio

Re bonjour Tototiti :) Job:)
merci pour tout je vais essayer la troisième Version aussi
mais d'ors et déjà vous m'avez trouvé la solution
un grand merci à vous deux
a+
papou :)
 

tototiti2008

XLDnaute Barbatruc
Re : Comment avec GetOpenFilename ne faire apparaître que les fichiers avec"Imputatio

Re,

mais il faut dire que les FileDialog ne marchent pas sur les anciennes versions d'Excel, alors que GetOpenfileName existe depuis toujours (ou longtemps en tout cas)
 

Discussions similaires

Réponses
19
Affichages
2 K

Statistiques des forums

Discussions
311 716
Messages
2 081 848
Membres
101 826
dernier inscrit
dododu89