XL 2010 Colorier toute une ligne en VBA

[Scorpio]

Bonjour à tous,
Ce code que j'ai trouvé sur le net, j

'aimerais bien vous demander, s'il vous plaît, comment le corriger car je suis pas un as dans ce domaine.
En fait, ce code colorie une ou plusieurs cellules contenant le mot "ok" en colonne "N", et j'aimerais la couleur sur toute la ligne de "A à P".
Voilà, d'avance merci et à plus.
​

 

[laurent950]

Bonjour,

Sub StockInf50()
For Each Cell In Range("N2:N100")
If Cell.Value = "ok" Then
Range(Cell.Address, Cell.Resize.Offset(0, -13).Address).Select
With Selection.Interior
.ColorIndex = 15
.Pattern = xlSolid
End With
End If
Next
End Sub

 

[Scorpio]

Bonjour laurens950,
Impeccable, je vous remercie beaucoup, du coup de main
A bientôt et bon Week End à vous

 

[Scorpio]

Pardon, c'est laurent950, avec un t

 

[job75]

Bonjour Scorpio, laurent950,

Pour la n plus unième fois :

Même si l'enregistreur de macros les utilise, les Select et autres Activate sont en général inutiles et même nuisibles en VBA.

A+

 

[Scorpio]

Bonjour laurens950,
Impeccable, je vous remercie beaucoup, du coup de main
A bientôt et bon Week End à vous

Re laurent950,
Dite, serait-il possible de colorier la ligne jusqu'à la colonne "P"
Merci beaucoup laurent950

 

[Scorpio]

Bonjour job75,
D'accord, mais que mettre à la place de Select

 

[Staple1600]

Bonjour le fil, le forum

Une autre façon de faire ______________________(Edit:sans Select, Salut job75 )
(code à mettre dans le code de la feuille concernée
clic-droit sur l'onglet -> Visualiser le code)

Private Sub Worksheet_Change(ByVal T As Range)
If Not Intersect([N2:N100], T) Is Nothing Then
If T Like "ok" Then
Cells(T.Row, 1).Resize(, 16).Interior.Color = RGB(125, 241, 69)
Else
Cells(T.Row, 1).Resize(, 16).Interior.Color = xlNone
End If
End If
End Sub

 

[Scorpio]

Bonjour Staple1600,
Question, est-ce que je peux mettre ce code sur un bouton dans la feuille, cela m'arrangerais mieux.

 

[job75]

Re, salut JM (pas rafraîchi),

Sub StockInf50()
Dim Cell As Range
For Each Cell In [N2:N100]
If Cell = "ok" Then Cell.EntireRow.Resize(, 16).Interior.ColorIndex = 15
Next
End Sub

Prendre aussi l'habitude de déclarer les variables, cela évite beaucoup d'erreurs.

A+

 

[Scorpio]

Re,
Merci du conseil job75,
J'essaye ce code et reprend contact

 

[Scorpio]

Re job75,
C'est parfais, plus que parfais, voilà.
Un grand merci à vous tous, du Forum.
A bientôt

 

[job75]

Re,

Dans le même esprit que Staple1600, avec l'effacement de la couleur si Cell <> "ok" :

Sub StockInf50()
Dim Cell As Range
For Each Cell In [N2:N100]
Cell.EntireRow.Resize(, 16).Interior.ColorIndex = IIf(Cell = "ok", 15, xlNone)
Next
End Sub

S'il y a un bouton c'est simple : lui affecter la macro.

A+

 

[Staple1600]

Re

Histoire de faire mumuse et moins orthodoxe que job75

Sub sStockInf50()
Dim C As Range
For Each C In [N2:N100]
Cells(C.Row, 1).Resize(, 16).Interior.ColorIndex = 15 * (C.Value = "ok") * -1
Next
End Sub

 

[phlaurent55]

Bonjour à tous,

Une solution sans code, sans bouton (et sans besoin de cliquer dessus)
voir fichier joint

à+
Philippe