[CLOS]VBA pour récupérer des infos des autres feuilles pour synthèse

[ozzii]

Bonjour,
Fournis un fichier avec quelques explications visuelles.

Environnement:
-Un fichier excel (c'est l'évidence même ) avec plusieurs feuilles.
-Chaque feuille à un nom différent qui ne se suit pas (comme toto, titi, truc ...)

Ce que j'aimerais:
Une macro (car je compte la lancer avec un bouton) qui fait :
-efface la feuille synthèse (mise à blanc des valeurs)
-parcours toutes les autres feuilles pour récupérer le nom de la feuille, valeur de la cellule I3, valeur de la cellule J3.
-écriture de ces infos dans la feuille de synthèse (du style en A1, B1 et C1)
-rebelote pour chaque feuille.

Merci par avance pour votre aide.

 

[Marc L]

Re : VBA pour récupérer des infos des autres feuilles pour synthèse

Bonjour !

​

Sub Demo()
    With Worksheets
        ReDim VA(2 To .Count, 2)
        For N& = 2 To .Count
            With .Item(N)
                VA(N, 0) = .Name
                VA(N, 1) = .[I3].Value
                VA(N, 2) = .[J3].Value
            End With
        Next
        .Item(1).UsedRange.Clear
        .Item(1).Cells(1).Resize(.Count - 1, 3).Value = VA
    End With
End Sub

_______________________________________________________________________________
Merci de cliquer sur J'aime ce post en bas à gauche de chaque message ayant aidé …

_______________________________________________________________________________
Je suis Paris, Charlie, …


​

 

[gonz19]

Re : VBA pour récupérer des infos des autres feuilles pour synthèse

j'avais un début de réponse mais on a été plus vite que moi
bonne journée

 

[ozzii]

Re : VBA pour récupérer des infos des autres feuilles pour synthèse

Merci Marc L,
Cependant j'ai une question car j'y comprends pas grand-chose à cette belle macro !!
-comment faire pour commencer à écrire à une autre ligne/colonne que "A"
-comment faire pour ajouter une autre cellule à récupérer

j'ai essayé plusieurs trucs mais sans succès

 

[ozzii]

Re : VBA pour récupérer des infos des autres feuilles pour synthèse

Moi je suis arrivé à ça (je préfère avoir le nom de la feuille) :

Sub Test()

Dim ws As Worksheet, i As Integer
i = 2
Sheets("synthese").UsedRange.Clear
For Each ws In Application.Worksheets
   If ws.Name <> "synthese" Then
      Sheets("synthese").Range("A" & i) = ws.Name
      Sheets("synthese").Range("B" & i) = ws.[D4].Value
      Sheets("synthese").Range("C" & i) = ws.[E4].Value
      Sheets("synthese").Range("D" & i) = ws.[F4].Value
      i = i + 1
   End If
Next ws

End Sub

 

[Marc L]

Sub Demo()
    With Worksheets
        ReDim VA(2 To .Count, 1 To 4)
        For N& = 2 To .Count
            With .Item(N)
                VA(N, 1) = .Name
                VA(N, 2) = .[D4].Value
                VA(N, 3) = .[E4].Value
                VA(N, 4) = .[F4].Value
            End With
        Next
        Feuil1.UsedRange.Clear
        Feuil1.[A2].Resize(.Count - 1, 4).Value = VA
    End With
End Sub

_______________________________________________________________________________
Merci de cliquer sur J'aime ce post en bas à gauche de chaque message ayant aidé …
​

 

[Marc L]

Re : VBA pour récupérer des infos des autres feuilles pour synthèse

Sub Test2()
                       Dim oWs As Worksheet, R As Long
                                             R = 1
                    Application.ScreenUpdating = False
    With Feuil1
               .UsedRange.Clear
        For Each oWs In ThisWorkbook.Worksheets
              If oWs.Name <> .Name Then
                                             R = R + 1
                            .Cells(R, 1).Value = oWs.Name
                .Cells(R, 2).Resize(, 3).Value = oWs.[D4.F4].Value
              End If
        Next
    End With
                    Application.ScreenUpdating = True
End Sub

_______________________________________________________________________________
Merci de cliquer sur J'aime ce post en bas à gauche de chaque message ayant aidé …
​

 

[ozzii]

Re : VBA pour récupérer des infos des autres feuilles pour synthèse

Purée, encore plus compliqué mais ça fonctionne. Merci pour l'aide.