Choisir un fichier pdf et l'envoyer par mail en VBA

[christian.bedere]

Bonjour

Je souhaiterai connaître une macro me permettant d'ouvrir une boîte de dialogue afin de chosir dans le dossier "mes documents", un fichier en pdf depuis excel et l'envoyer par mail.
Merci pour votre grande aide habituelle

Belle journée à vous
Christian

 

[kiki29]

Re : Choisir un fichier pdf et l'envoyer par mail en VBA

A adapter

Option Explicit

'================================================================================
'   Menu VBE Outils | Références : Cocher Microsoft CDO for Exchange xxxx Library
'================================================================================

Sub Envoi_01()
Dim CdoMessage As CDO.Message
Dim Fichier As Variant

    ChDir "C:\Documents and Settings\UserName\Mes documents\PdfOut"
    Fichier = Application.GetOpenFilename("Fichiers PDF (*.pdf), *.pdf")

    If Fichier = False Then Exit Sub

    Set CdoMessage = New CDO.Message
    With CdoMessage
        .Subject = "Exemple"
        .From = "xxxxx@wanadoo.fr"
        .To = "yyyyy@orange.fr"
        .CC = ""
        .BCC = ""
        .TextBody = "Texte dans le corps de message"
        .AddAttachment Fichier
        .Send
    End With

    Set CdoMessage = Nothing
End Sub


'================================================================================
'   Si l'on ne veut pas avoir à cocher Microsoft CDO for Exchange xxxx Library
'   dont la version varie suivant la version Excel
'   Mais plus d'accès par completion aux méthodes et propriétés de l'objet
'================================================================================

Sub Envoi_02()
Dim CdoMessage As Object
Dim Fichier As Variant

    ChDir "C:\Documents and Settings\UserName\Mes documents\PdfOut"
    Fichier = Application.GetOpenFilename("Fichiers PDF (*.pdf), *.pdf")
    
    If Fichier = False Then Exit Sub
        
    Set CdoMessage = CreateObject("CDO.Message")
    With CdoMessage
        .Subject = "Exemple"
        .From = "xxxxx@wanadoo.fr"
        .To = "yyyyy@orange.fr"
        .CC = ""
        .BCC = ""
        .TextBody = "Texte dans le corps de message"
        .AddAttachment Fichier
        .Send
    End With
    
    Set CdoMessage = Nothing
End Sub